;---------------------------------------------------------------
;
; Installer script for MailArchiver
; $VER: 36.0 (24.04.94)
; Written by Denis GOUNELLE
;
;---------------------------------------------------------------
;
(complete 0)
(set ProgVer  "38.2")
(set ProgName "MailArchiver")
(set KickVer  (/ (getversion) 65536))
(set SCFlag   (if (AND (> KickVer 35) (exists "S:.SoftConfig")) 1 0))
;
(set InstallOpt
	(askoptions (prompt "Which part of the program whould you like to install ?")
		    (help @askoptions-help)
		    (choices "Program" "Locales")
	)
)
;
;--------------------- Install the program --------------------
;
(complete 33)
(if (BITAND InstallOpt 1)
	((set ProgDir (askdir
		(prompt "Select the directory where to install MailArchiver")
		(help "The program will be copied in this directory. You may want to install MailArchiver in a directory which is in your default path.")
		(default "SYS:Utilities/")
		)
	 )
	 (copyfiles (prompt "Installing program")
		(help @copyfiles-help)
		(source ProgName)
		(newname "MailArchiver")
		(dest ProgDir)
		(infos)
	 )
	 (if SCFlag (run (cat "SoftConfig ADD MailArchiver " (tackon ProgDir "MailArchiver") " FILE " ProgVer)))
	)
)
;
;--------------------- Install the locale --------------------
;
(complete 66)
(if (BITAND InstallOpt 2)
	((set Langage (askchoice (prompt "Which locale do you want to install ?")
				(help @askchoice-help)
				(choices "français" "none")))
	 (if (= Langage 0)
		((set LocaleName "français")
		 (set LocaleSrc (tackon "catalogs" LocaleName))
		 (set LocaleDst (tackon "LOCALE:" LocaleSrc))
		 (set LocaleName "MailArchiver.catalog")
		 (if (NOT (exists LocaleDst)) (makedir LocaleDst (prompt "Creating locale directory") (help @makedir-help)))
		 (copyfiles (prompt "Installing locale")
			(help @copyfiles-help)
			(source (tackon LocaleSrc LocaleName))
			(dest LocaleDst)
		 )
		 (if SCFlag
			((run (cat "SoftConfig ADD " LocaleName " " (tackon LocaleDst LocaleName) " FILE " ProgVer))
			 (run (cat "SoftConfig ATTACH MailArchiver " LocaleName))
			)
		))
	))
)
;
(complete 100)
(set @default-dest ProgDir)