.
; SplitGEDConfs
;
; $VER: SplitGEDConfs 1.00 (22.10.94)
;
; (c) 1994 by Wolfgang Küting <wolfi@pit.owl.de>
;
.KEY hilfe/S,quiet/S,ask/S,from/K,to/K
.BRA {
.KET }

;If NOT "{hilfe}" EQ ""
If {hilfe}
  Echo "*N*E[1;32mSplitGEDConfs V1.00*E[28;22m (22.10.94)"
  Echo "(c) 1994 by Wolfgang Küting <wolfi@pit.owl.de>*N"
  Echo "Splitte alle Config-Dateien von *E[3mGoldEd*E[23m in *E[1m<ENVARC:GoldEd/>*E[22m auf"
  Echo "und schreibt die Einzeldateien nach *E[1m<GoldEd:Configs/>*E[22m."
  Echo "Dazu wird *E[1m<SplitConfig>*E[22m aus dem *E[3mGoldEd*E[23m-Archiv in *E[1m<GoldEd:>*E[22m"
  Echo "benötigt.*N"
  Echo "  SplitGEDConfs hilfe/S,quiet/S,ask/S,from/K,to/K*N"
  Echo "    *E[32mhilfe/S*E[0m    Diese Info :-)"
  Echo "    *E[32mquiet/S*E[0m    Keine Ausgaben im Shell-Fenster"
  Echo "    *E[32mask/S*E[0m    Frage nach Verzeichnissen"
  Echo "    *E[32mfrom/K*E[0m   Quellverzeichnis   (Vorgabe: <ENVARC:GoldEd/>)"
  Echo "    *E[32mto/K*E[0m   Zielverzeichnis  (Vorgabe: <GoldEd:Configs/>)*N"
  Quit
EndIf

If "{from}" EQ ""
  Set source "ENVARC:GoldEd/"
Else
  Set source {from}
EndIf
If "{to}" EQ ""
  if NOT EXISTS GoldED:Configs
      makedir GoldED:Configs
  EndIf
  Set target "GoldEd:Configs/"
Else
  Set target {to}
EndIf

If {ask}
  Set source `RequestFile TITLE "Wähle Quellverz. ..." DRAWER $source DRAWERSONLY`
  Set target `RequestFile TITLE "Wähle Zielverz. ..." DRAWER $target DRAWERSONLY`
EndIf

If NOT EXISTS SplitConfig
  If {quiet}
    RequestChoice TITLE "SplitGEDConfs 1.00" BODY "Kann*N<GoldEd:SplitConfig>*Nnicht finden!" GADGETS "*Okay" >NIL:
  Else
    Echo "Kann *E[1m<GoldEd:SplitConfig>*E[22m nicht finden!"
  EndIf
  Quit 20
EndIf

LAB CheckSource
If NOT EXISTS "$source"
  Set source `RequestFile TITLE "Verz. exestiert nicht..." DRAWER $source DRAWERSONLY`
  If "$source" EQ ""
    Quit 5
  EndIf
  Skip CheckSource BACK
EndIf
If NOT EXISTS "$target"
  MakeDir "$target"
EndIf

If {quiet}
  List "$source#?.prefs" FILES LFORMAT "SplitConfig *"%P%N*" *"$target*" *"%M*" >NIL:" >T:SGEDC_{$$}.BAT
Else
  Echo "Echo *"Splitte von *E[32m$source*E[0m nach *E[32m$target*E[0m*"" >T:SGEDC_{$$}.BAT
  List "$source#?.prefs" FILES LFORMAT "Echo *" » *E[32m%N*E[0m...*"*NSplitConfig *"%P%N*" *"$target*" *"%M*" >NIL:" >> T:SGEDC_{$$}.BAT
EndIf

Echo "$target" >$target.list
List "$source#?.prefs" FILES LFORMAT "%M" >>$target.list

If EXISTS T:SGEDC_{$$}.BAT
  Execute T:SGEDC_{$$}.BAT
  Delete >NIL: T:SGEDC_{$$}.BAT QUIET
EndIf

UnSet target
UnSet source

Quit