; Install Harddisk script for ABank
; $VER: ABank_Install 1.1

(set @default-dest "")

(set P1 "/")
(set P2 "/")

(if (< (/ (getversion) 65536) 37)
    (
    (set reqtoolslib (cat P1 "Libs/13/reqtools.library"))
    (set defguide 0)
    )
    (
    (set reqtoolslib (cat P1 "Libs/20/reqtools.library"))
    (set defguide 1)
    )
)
(set pplib (cat P1 "Libs/powerpacker.library"))
(set amoslib (cat P1 "Libs/amos.library"))
(set modpath (cat P1 "AGUI/Mod/ABank/"))
(set devpath (cat P2 "AGUI/Development/ABank/"))
(set docpath (cat P2 "Documentation"))
(set datapath (cat P1 "Datas"))
(set expath (cat P2 "Examples"))
(set prog (cat P1 "ABank"))
(set prefs "Prefs")

(set #prog "ABank 1.1")
(set #copyright "\nABank ฉ 1994-1955 David Gaussinel\n")
(set #address "\nDavid Gaussinel\n18 rue F้nelon\n24200 Sarlat\nFRANCE")

;***************************************************************************
; English strings
;
; Translation: Native
;***************************************************************************

(set default_lang 1)
(set def_lang 0)

(set #copying-reqtoolslib "Copying reqtools.library to Libs:...")
(set #copying-pplib "Copying powerpacker.library to Libs:...")
(set #copying-amoslib "Do you want to copy amos.library to Libs:...")
(set #copying-mod "Select interface(s) to install...")
(set #copying-dev "Select development file(s) to copy...")
(set #copying-doc "Select documentation(s) to copy...")
(set #copying-abank "Copying ABank to ABank drawer...")
(set #select-agui "Please select a place for the AGUI drawer")
(set #select-abank "Please select a place for the ABank drawer")
(set #select-mod "Please select your default interface for ABank")
(set #select-logo "Please select bank logos to install...")
(set #select-ex "Please select examples to install...")
(set #assign-agui "Now the AGUI assignement will be included into your user-startup file.")
(set #create-prefs "Saving preferences file.")
(set #header-prefs (cat #prog " preferences file."))
(set #copy-format "What file format do you want to copy ?")
(set #copy-example "Do you want to copy Examples ?")
(set #copy-dev "Do you want to copy Development files ?")
(set #copy "Yes")
(set #cancel "No")

(set #aguidir-help
(cat "Select the directory where you want to install AGUI. Installer will create a drawer named AGUI.\n\n" @askdir-help))
(set #aguistartup-help
(cat "Installer will modify your user-startup to create a AGUI assignement line. It's indispensable to ABank runs.\n\n" @startup-help))
(set #abankdir-help
(cat "Select the directory where you want to install ABank. Installer will create a drawer named ABank.\n\n" @askdir-help))
(set #copyabank-help
(cat "ABank will be copied in the ABank drawer.\n\n" @copyfiles-help))
(set #asklogo-help
(cat "Tick the bank logo that you want install on your harddisk. Choose your country.\n\n" @askoptions-help))
(set #askdoc-help
(cat "Tick the language of the documentation files that you want to install.\n\n" @askoptions-help))
(set #askformat-help
(cat "Ascii files can be read with More. Guide files need AmigaGuide or MultiView.\n\n" @askoptions-help))
(set #askex-help
"If you want to install examples on your harddisk, choose Yes else No.")
(set #selectex-help
(cat "Tick the example(s) that you want install on your harddisk. You can choose your language.\n\n" @askoptions-help))
(set #selectmod-help
(cat "Tick the interface(s) that you want install on your harddisk. You can choose your language.\n\n" @askoptions-help))
(set #askdev-help
"If you want to install Development AGUI files on your harddisk, choose Yes else No.\n\n Only advanced users can use Development AGUI files, and you must have AGUI Editor.")
(set #selectdev-help
(cat "Tick the Development file(s) that you want install on your harddisk.\n\n" @askoptions-help))
(set #prefsmod-help
(cat "Tick the default interface that ABank must load at startup. You can choose your language, but you MUST choose a interface installed on your harddisk.\n\n" @askoptions-help))
(set #prefs-help
"ABank preferences file will be created. If you don't want (?), choose No.")
(set #amos-help
(cat "Amos.library hasn't a version number. So you must copy amos.library if Installer says. Version of Amos.library included is 2.00\n\n" @copyfiles-help))

(set #install-choice "Choose mode installation")
(set #install-help 
(cat "Choose an installation mode.\n"
     "Simple installation will copy some files ABank needed on your system disc. It's the installation you must choose if you have a floppy based system.\n\n"
     "Complete installation will install all the distribution of ABank on your hard disk.\n\n"
     "Simple or complete, think to boot your Amiga from the system disc where you want to install ABank.\n\n"
     "If you was already registered user for ABank, before to proceed installation, select option Update keyfile. It'll copy your keyfile from your original ABank disc."
))
(set #install-complete "Complete installation")
(set #install-simple "Simple installation")
(set #install-update "Update keyfile")
(set #original "\nInsert your orignal ABank disc\nand then click on Yes.\n\nIf you don't have this disc, click on No.")
(set #original-help "If you was already registered user, Installer will update ABank after you insert the original ABank disc.")

(set #install-msg
(cat "\n\n" #prog " installation script.\n"
     "This script installs " #prog " on your Amiga.\n\n"
     "Read the documentation file for\n"
     "more information on the distribution,\n"
     "shareware and usage of ABank.\n"
     #copyright
     "All rights reserved."
))
(set #quit-msg
(cat    "\nABank is now installed on your Amiga.\n\n"
        "ABank is shareware. In this demo version,\n"
        "you  can't  enter  more  than  50 operations.\n"
        "To  own  the complete version of this product,\n"
        "you must send a contribution, at less than\n"
        "20$ or 12 ฃ or 25 DM or 100 FF to the author :\n"
        #address
))
(set #reg-msg
(cat    "\nABank is now installed on your Amiga.\n\n"
        "You are a ABank's registered user.\n"
        "Please do not copy your version.\n"
        "ABank is protected against piracy.\n"
        "Your name and address have been crypted\n"
        "and will be displayed in ABank.\n\n"
        #address
))
;***************************************************************************
; Fran็ais strings
;
; Translation: David Gaussinel (07.01.95)
;***************************************************************************
(if (= @language "fran็ais")
(
(set default_lang 2)
(set def_lang 1)

(set #copying-reqtoolslib "Copions reqtools.library en Libs:...")
(set #copying-pplib "Copions powerpacker.library en Libs:...")
(set #copying-amoslib "Voulez-vous copier amos.library en Libs:...")
(set #copying-mod "Choisissez les interfaces เ installer...")
(set #copying-dev "Choisissez les fichiers Development เ copier...")
(set #copying-doc "Choisissez les documentations เ copier...")
(set #copying-abank "Copions ABank dans le r้pertoire ABank...")
(set #select-agui "Veuillez choisir un endroit pour le r้pertoire AGUI")
(set #select-abank "Veuillez choisir un endroit pour le r้pertoire ABank")
(set #select-mod "Veuillez choisir votre interface par d้faut pour ABank")
(set #select-logo "Veuillez choisir les logos de banque เ installer...")
(set #select-ex "Veuillez choisir les exemples เ installer...")
(set #assign-agui "Maintenant l'assignation AGUI va ๊tre ajout้e เ votre fichier user-startup.")
(set #create-prefs "Sauvons le fichier pr้f้rences.")
(set #header-prefs (cat #prog " preferences file."))
(set #copy-format "Quel format de documentation copier ?")
(set #copy-example "Voulez-vous copier les exemples ?")
(set #copy-dev "Voulez-vous copier les fichiers Development ?")
(set #copy "Oui")
(set #cancel "Non")

(set #aguidir-help
(cat "Choisissez le r้pertoire o๙ vous voulez installer AGUI. Installer va cr้er un tiroir nomm้ AGUI.\n\n" @askdir-help))
(set #aguistartup-help
(cat "Installer va modifier votre user-startup pour cr้er une ligne d'assignation AGUI. Ceci est indispensable au lancement d'ABank.\n\n" @startup-help))
(set #abankdir-help
(cat "Choisissez le r้pertoire o๙ vous voulez installer ABank. Installer va cr้er un tiroir nomm้ ABank.\n\n" @askdir-help))
(set #copyabank-help
(cat "ABank va ๊tre copi้ dans le tiroir ABank.\n\n" @copyfiles-help))
(set #asklogo-help
(cat "Cochez les logos de banque que vous voulez installer sur votre disque dur. Choisissez votre pays.\n\n" @askoptions-help))
(set #askdoc-help
(cat "Cochez la langue des fichiers documentation que vous voulez installer.\n\n" @askoptions-help))
(set #askformat-help
(cat "Les fichiers Ascii sont lisibles avec More. Les fichiers Guide ont besoin d'AmigaGuide ou de MultiView.\n\n" @askoptions-help))
(set #askex-help
"Si vous voulez installer les exemples sur votre disque dur, choisissez Oui sinon Non.")
(set #selectex-help
(cat "Cochez les exemples que vous voulez installer sur votre disque dur. Vous pouvez choisir votre langue.\n\n" @askoptions-help))
(set #selectmod-help
(cat "Cochez les interfaces que vous voulez installer sur votre disque dur. Vous pouvez choisir votre langue.\n\n" @askoptions-help))
(set #askdev-help
"Si vous voulez installer les fichiers AGUI Development sur votre disque dur, choisissez Oui sinon Non.\n\n Seuls les utilisateurs avanc้s peuvent utiliser les fichiers AGUI Development, et vous devez avoir AGUI Editor.")
(set #selectdev-help
(cat "Cochez les fichiers Development que vous voulez installer sur votre disque dur.\n\n" @askoptions-help))
(set #prefsmod-help
(cat "Cochez l'interface par d้faut que ABank doit charger au d้marrage. Vous pouvez choisir votre langue, mais vous DEVEZ choisir une interface install้e sur votre disque dur.\n\n" @askoptions-help))
(set #prefs-help
"Le fichier ABank pr้f้rences va ๊tre cr้้. Si vous ne voulez pas (?), choisissez Non.")
(set #amos-help
(cat "Amos.library n'a pas de num้ro de Version. Aussi vous devez copier amos.library si Installer le dit. La version d'Amos.library incluse est 2.00\n\n" @copyfiles-help))

(set #install-choice "Quelle installation voulez-vous effectuer ?")
(set #install-help 
(cat "Choisissez un des deux modes d'installations.\n"
     "Installation simple va copier quelques fichiers n้cessaires เ ABank sur votre disque syst่me. C'est l'installation que vous devez choisir si vous avez un syst่me bas้ sur disquettes.\n\n"
     "Installation compl่te va installer tous les fichiers d'ABank sur votre disque dur.\n\n"
     "Dans les deux cas, veillez เ avoir d้marrer votre Amiga depuis le disque syst่me sur lequel vous voulez installer ABank.\n\n"
     "Si vous ๊tes d้jเ utilisateur enregitr้ ABank, avant de proc้der เ une installation, s้lectionnez l'option Mise เ jour fichier cl้ qui va copier votre fichier cl้ depuis votre disquette originale ABank."
))
(set #install-complete "Installation compl่te")
(set #install-simple "Installation simple")
(set #install-update "Mise เ jour fichier cl้")
(set #original "\nIns้rez votre disquette ABank originale\npuis cliquez sur Oui.\n\nSi vous n'avez pas cette disquette, cliquez sur Non.")
(set #original-help "Si vous ๊tes utilisateur enregistr้, Installer va mettre เ jour ABank apr่s que vous ayez ins้r้ la disquette originale ABank.")

(set #install-msg
(cat "\n\nScript d'installation d'" #prog ".\n"
     "Ce script installe " #prog " sur votre Amiga.\n\n"
     "Lisez les fichiers documentations pour\n"
     "plus d'informations sur la distribution,\n"
     "le shareware and l'utilisation d'ABank.\n"
     #copyright
     "Tous droits r้serv้s."
))
(set #quit-msg
(cat    "\nABank est maintenant install้ sur votre Amiga.\n\n"
        "ABank est shareware. Dans cette version demo,\n"
        "vous ne pouvez entrer plus de 50 op้rations.\n"
        "Pour recevoir la version compl่te de ce produit,\n"
        "vous devez envoyer une contribution, d'au moins\n"
        "20$ ou 12 ฃ ou 25 DM ou 100 FF เ l'auteur :\n"
        #address
))
(set #reg-msg
(cat    "\nABank est maintenant install้ sur votre Amiga.\n\n"
        "Vous ๊tes un utilisateur enregistr้ d'ABank.\n"
        "Merci de ne pas copier votre version.\n"
        "ABank est prot้g้ contre le piratage.\n"
        "Votre nom et adresse ont ้t้ crypt้s\n"
        "et vont ๊tre affich้s dans ABank.\n\n"
        #address
))
))

;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; PROC quit
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(procedure quit
(if (exists "L:ABank.key")
(message #reg-msg)
(message #quit-msg)
)
(exit (quiet))
)

;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; PROC copy library & copy keyfile on Hard or Floppy
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(Procedure install_lib
    (copylib
            (prompt "\n" #copying-reqtoolslib)
            (help @copylib-help)
            (source reqtoolslib)
            (newname "reqtools.library")
            (dest "Libs:")
            (confirm)
    )
    (copylib
            (prompt "\n" #copying-pplib)
            (help @copylib-help)
            (source pplib)
            (dest "Libs:")
            (confirm)
    )
    (if (<> (getsize "LIBS:amos.library") (getsize amoslib)) (
        (copyfiles
            (prompt "\n" #copying-amoslib)
            (help #amos-help)
            (source amoslib)
            (dest "Libs:")
            (confirm)
        )
    ))
  (if (exists (cat P1 "L/ABank.key"))
      (copyfiles (source (cat P1 "L/ABank.key")) (dest "L:"))
  )
)

;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; PROC install complete ABank distribution
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(Procedure install_complete
(complete 0)
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; Install AGUI directory
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(if (NOT (exists "AGUI:" (noreq)))
    (
    (set AGUIdir
    (tackon
        (askdir
            (prompt #select-agui)
            (default "")
            (help #aguidir-help)
        )
        "AGUI"
    ))

    (makedir AGUIdir (infos))
    (makeassign "AGUI" AGUIdir)
    (makedir "AGUI:Development" (infos))
    (makedir "AGUI:Mod" (infos))
    (makedir "AGUI:Prefs" (infos))
    (startup "AGUI"
        (prompt #assign-agui)
        (help #aguistartup-help)
        (command 'Assign AGUI: "' AGUIdir '"\n')
    )
    )
)
(complete 10)
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; install ABank files
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(set ABANKdir
(tackon
    (askdir
        (prompt #select-abank)
        (default "")
        (help #abankdir-help)
    )
    "ABank"
))
(makedir ABANKdir (infos))
; ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญcopy ABank
(copyfiles
        (prompt "\n" #copying-abank)
        (help #copyabank-help)
        (source prog)
        (dest ABANKdir)
        (infos)
        (confirm)
)
(complete 15)
; ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญcopy datas (icons & logos)
(set ABANKdata (cat ABANKdir "/Datas"))
(copyfiles
    (source (cat datapath "/DefIcon.info"))
    (dest ABANKdata)
    (files)
)

(copyfiles
    (source (cat datapath "/Accounts"))
    (dest (cat ABANKdata "/Accounts"))
    (all)
)
(set bank
    (askoptions
        (prompt "\n" #select-logo)
        (help #asklogo-help)
        (choices "Suisse" "France" "Germany")
    )
)
(makedir (cat ABANKdata "/Banks") (infos))
(if (IN bank 0) (
    (makedir (cat ABANKdata "/Banks/Suisse"))
    (copyfiles (source (cat datapath "/Banks/Suisse")) (dest (cat ABANKdata "/Banks/Suisse")) (all))
))
(if (IN bank 1) (                                                                         
    (makedir (cat ABANKdata "/Banks/France"))
    (copyfiles (source (cat datapath "/Banks/France")) (dest (cat ABANKdata "/Banks/France")) (all))
))
(if (IN bank 2) (
    (makedir (cat ABANKdata "/Banks/Germany"))
    (copyfiles (source (cat datapath "/Banks/Germany")) (dest (cat ABANKdata "/Banks/Germany")) (all))
))
(complete 35)
; ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญcopy documentations
(set ABANKdoc (cat ABANKdir "/Documentation"))
(if (NOT (exists ABANKdoc)) (makedir ABANKdoc (infos)))
(set lang
    (askoptions
        (prompt "\n" #copying-doc)
        (help #askdoc-help)
        (choices "English" "Fran็ais" "Deutsch")
        (default default_lang)
    )
)
(if (<> 0 lang) (
    (set format (askoptions (prompt "\n" #copy-format) (help #askformat-help) (choices "Ascii" "AmigaGuide")))

(if (<> 0 format) (
    (if (AND (IN lang 0) (IN format 0)) (copyfiles (source (cat docpath "/English.doc")) (dest ABANKdoc) (files) (infos)))
    (if (AND (IN lang 1) (IN format 0)) (copyfiles (source (cat docpath "/Fran็ais.doc")) (dest ABANKdoc) (files) (infos)))
    (if (AND (IN lang 2) (IN format 0)) (copyfiles (source (cat docpath "/Deutsch.doc")) (dest ABANKdoc) (files) (infos)))
    (if (AND (IN lang 0) (IN format 1)) (copyfiles (source (cat docpath "/English.guide")) (dest ABANKdoc) (files) (infos)))
    (if (AND (IN lang 1) (IN format 1)) (copyfiles (source (cat docpath "/Fran็ais.guide")) (dest ABANKdoc) (files) (infos)))
    (if (AND (IN lang 2) (IN format 1)) (copyfiles (source (cat docpath "/Deutsch.guide")) (dest ABANKdoc) (files) (infos)))
))
))
(complete 50)
; ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญcopy examples
(if
    (= 1
    (askbool
        (prompt #copy-example)
        (help #askex-help)
        (choices #copy #cancel)
        (default 1)
    ))
(
    (set ABANKex (cat ABANKdir "/Examples"))
    (copyfiles
        (prompt #select-ex)
        (help #selectex-help)
        (source expath)
        (dest ABANKex)
        (all)
        (infos)
        (confirm)
    )
))
(complete 60)
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; install module files of ABank
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(if (NOT (exists "AGUI:Mod/ABank/")) (makedir "AGUI:Mod/ABank" (infos)))
(set lang
    (askoptions
        (prompt "\n" #copying-mod)
        (help #selectmod-help)
        (choices "English" "Fran็ais" "Deutsch")
        (default default_lang)
    )
)
(if (IN lang 0) (copyfiles (source (cat modpath "English")) (dest "AGUI:Mod/ABank/") (infos)))
(if (IN lang 1) (copyfiles (source (cat modpath "Fran็ais")) (dest "AGUI:Mod/ABank/") (infos)))
(if (IN lang 2) (copyfiles (source (cat modpath "Deutsch")) (dest "AGUI:Mod/ABank/") (infos)))
(complete 70)
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; install development files of ABank
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(if
    (= 1
    (askbool
        (prompt #copy-dev)
        (help #askdev-help)
        (choices #copy #cancel)
        (default 0)
    ))
(
(if (NOT (exists "AGUI:Development/ABank/")) (makedir "AGUI:Development/ABank" (infos)))
(copyfiles
        (prompt "\n" #copying-dev)
        (help #selectdev-help)
        (source devpath)
        (all)
        (dest "AGUI:Development/ABank/")
        (confirm)
)
))
(complete 85)
(create_prefs)
(complete 90)
(install_lib)
(complete 100)
(quit)
)
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; PROC create prefs file
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(Procedure create_prefs
(set modname
    (select
        (askchoice
            (prompt #select-mod)
            (help #prefsmod-help)
            (choices "English" "Fran็ais" "Deutsch")
            (default def_lang)
        )
    "English" "Fran็ais" "Deutsch"
    )
)
(textfile
        (prompt #create-prefs)
        (help #prefs-help)
        (dest "AGUI:Prefs/ABank.prefs")
        (append #header-prefs "\n")
        (append "\n")
        (append "MODULE=" modname "\n")
        (include prefs)
        (confirm)
)
)
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; PROC install simple
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(Procedure install_simple
(complete 0)
(install_lib)
(complete 50)
(if (NOT (exists "AGUI:" (noreq)))
    (makeassign "AGUI" "/AGUI")
)
(complete 60)
(create_prefs)
(complete 100)
(quit)
)
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; PROC update key
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(Procedure update
(if
    (= 1 (askbool (prompt #original) (help #original-help) (choices #copy #cancel) (default 0)))
(
    (if (exists "df0:L/ABank.key")
        (
        (copyfiles (source "df0:L/ABank.key") (dest (cat P1 "L/")))
    ))
))
)
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
; main loop
;ญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญญ
(message #install-msg)
(welcome)

(until (< 2 menu)

(set menu
    (askchoice
        (prompt #install-choice)
        (help #install-help)
        (choices #install-simple #install-complete #install-update)
    )
)

(if (= 0 menu) (install_simple))
(if (= 1 menu) (install_complete))
(if (= 2 menu) (update))

)