(set vernum-DeftII (getversion "/Deft II"))
(set version-DeftII (/ vernum-DeftII 65536))
(set revision-DeftII (- vernum-DeftII (* version-DeftII 65536)))

(set @default-dest "")
(set #sources_wanted 0)
(set #rexx_wanted 0)

;-------------------------------------------------
;-------------------------------------------------
; English strings

(if	(= @language "english")
	(
     
		(set default_lang 1)

		(set default_doc 0)

		(set #bad-wb-msg "Deft II needs Workbench 2.0 (V37) or higher !")

		(set #install-msg (cat "This script installs Deft II v" version-DeftII "." revision-DeftII " on your Amiga."))

		(set #install-DeftII-prompt "Choose the directory where to put Deft II and its documentation (create it if needed) :")

		(set #doc-prompt "Choose the documentation to install :")

		(set #locale-prompt "Choose the different languages to install :")

		(set #locale-help "Deft II uses the .catalog files to speak your language. Only the files you're going to select will be available next.")

		(set #sources-request "Do you want to install a directory with DeftII sources inside ?")

		(set #sources_prompt "Choose the directory where to put the DeftII sources (create it if needed) :")

		(set #arexx-request "Do you want to copy Deft II ARexx scripts to REXX: ?")

	)
)

;-------------------------------------------------
;-------------------------------------------------
; French strings

(if	(= @language "français")
	(

		(set default_lang 2)

		(set default_doc 1)

		(set #bad-wb-msg "Deft II nécessite un Workbench 2.0 (V37) ou supérieur !")

		(set #install-msg (cat "Ce script installe Deft II v" version-DeftII "." revision-DeftII " sur votre Amiga."))

		(set #install-DeftII-prompt "Choisissez le répertoire qui contiendra DeftII et sa documentation (créez-le si nécessaire) :")

		(set #doc-prompt "Choisissez la documentation à installer :")

		(set #locale-prompt "Choisissez les différents langages à installer :")

		(set #locale-help "Deft II utilise les fichiers catalog pour parler votre langue. Seuls les fichiers que vous allez sélectionner seront accessibles par la suite.")

		(set #sources-request "Voulez-vous installer un répertoire avec les sources de DeftII ?")

		(set #sources-prompt "Choisissez le répertoire qui contiendra les sources de DeftII (créez-le si nécessaire) :")

		(set #arexx-request "Voulez-vous copier les scripts ARexx de Deft II dans REXX: ?")

	)
)

;-------------------------------------------------
;-------------------------------------------------
; Installation

; GET WORKBENCH RELEASE. V37 AT LEAST NEEDED

(if (< (/ (getversion "LIBS:version.library") 65536) 37)
	(
		(abort #bad-wb-msg)
	)
)

(message #install-msg)

; ASK WHERE TO INSTALL DeftII

(set @default-dest
	(askdir
		(prompt #install-DeftII-prompt)
		(help @askdir-help)
		(default "work:")
		(disk)
	)
)

; AND COPY IT !

(copyfiles
	(source "/Deft II")
	(dest @default-dest)
)

(copyfiles
	(source "/Deft II.info")
	(dest @default-dest)
)

(if (not (exists (tackon @default-dest "Deft II.prefs") (noreq)))
	(copyfiles
		(source "/Deft II.prefs")
		(dest @default-dest)
	)
)

; ASK WHICH DOC FILE TO INSTALL

(set doc
	(askchoice
		(prompt #doc-prompt)
		(help @askchoice-help)
		(choices
			"English"
			"Français"
		)
		(default default_doc)
	)
)

; AND COPY IT !

(set doc-dir
	(select doc "English" "Français")
)

(copyfiles
	(source (cat "/Docs/" doc-dir))
	(dest @default-dest)
	(all)
)

; LOCALE FILE INSTALLATION

(if (>= (/ (getversion "LIBS:version.library") 65536) 38)

	(

; ASK WHICH LOCALE FILES TO INSTALL

		(set lang
			(askoptions
				(prompt #locale-prompt)
				(help #locale-help)
				(choices
					"English (built-in)"
					"Français"
				)
				(default default_lang)
			)
		)


; AND COPY THEM !

		(set n 0)

		(while
			(set language
				(select n "english" "français" "")
			)

			(if (IN lang n)
				(if (<> n 0)
					(
						(if (= 0 (exists (cat "LOCALE:Catalogs/" language) (noreq)))
							(makedir (cat "LOCALE:Catalogs/" language) (help @makedir-help))
						)

						(if (<> 1 @pretend)
							(copyfiles
								(source (cat "/catalogs/" language))
								(dest (cat "LOCALE:Catalogs/" language))
								(all)
							)
						)
					)
				)

			)

			(set n (+ n 1))
		)
	)

)

; ASK WHERE TO INSTALL SOURCES IF WANTED

(if (= 2 @user-level)
	(if (askbool
			(help @askbool-help)
			(prompt #sources-request)
		)
		(
			(set #sources_wanted 1)
			(set sources-dir
				(askdir
					(prompt #sources_prompt)
					(help @askdir-help)
					(default @default-dest)
					(disk)
				)
			)
		)
	)
)

; AND COPY THEM IF WANTED

(if #sources_wanted
	(copyfiles
		(source "/Sources")
		(dest sources-dir)
		(all)
	)
)

; ASK IF Deft II AREXX SCRIPTS MUST BE COPIED AND COPY THEM IF WANTED

(if (= 2 @user-level)
	(if (askbool
			(help @askbool-help)
			(prompt #arexx-request)
		)
		(copyfiles
			(source "/ARexx")
			(dest "REXX:")
			(all)
		)
	)
)