;$VER: Ami2D Installer © 1994

(set cpu (database "cpu"))
(set @default-dest "RAM:")

(set #adir 
    (askdir 
        (prompt "Where do you wish to install Ami2D?\n(A drawer will be created called \"Ami2D\" at this location)")
        (help @askdir-help)
        (default "Work:")
    )
)

(set @default-dest (tackon #adir "Ami2D"))
(makedir @default-dest (infos) (safe))
(if (= (exists (tackon #adir "Ami2D.info")) 0)
    (copyfiles (source "Ami2D.info") (dest #adir))
)
(makeassign 'Ami2D' @default-dest (safe))
(complete 10)

(foreach "Ami2D/rexx" "#?.rexx" 
    (protect (tackon "Ami2D/rexx" @each-name) "+s")
)
(foreach "Ami2D/test" "#?.rexx" 
    (protect (tackon "Ami2D/test" @each-name) "+s")
)
(foreach "Files/wshell" "#?.rexx" 
    (protect (tackon "Files/wshell" @each-name) "+s")
)
(foreach "Files/nowshell" "#?.rexx" 
    (protect (tackon "Files/nowshell" @each-name) "+s")
)
(complete 20)

(copyfiles (source "README") (infos) (dest "Ami2D:"))
(copyfiles (source "ABSTRACT") (infos) (dest "Ami2D:"))
(copyfiles (source "COPYRIGHT") (infos) (dest "Ami2D:"))
(copyfiles (source "DISCLAIMER") (infos) (dest "Ami2D:"))
(complete 30)

(copyfiles 
    (prompt "Installing Ami2D...")
    (source "Ami2D")
    (all)
    (infos)
	(dest "Ami2D:")
    (optional)
)
(complete 50)

(copylib
	(help @copylib-help)
	(prompt "Copying rexxarplib.library...")
	(confirm)
	(source "Files/libs/rexxarplib.library")
	(dest "LIBS:")
)
(complete 60)

(copylib
	(help @copylib-help)
	(prompt "Copying rexxmathlib.library...")
	(confirm)
	(source "Files/libs/rexxmathlib.library")
	(dest "LIBS:")
)
(complete 70)

(if (askbool 
        (help @askbool-help) 
        (prompt "Which set of icons do you prefer?")
        (default 0)
		(choices "UGLY" "MAGICWB")
    )
    (
        (copyfiles (source "Files/noMagic.info") (dest #adir) (newname "Ami2D.info"))
        (copyfiles (source "Files/noMagic") (pattern "#?.info") (dest "Ami2D:"))
        (copyfiles (source "Files/noMagic/doc") (pattern "#?.info") (dest "Ami2D:doc"))
        (copyfiles (source "Files/noMagic/tutorials") (pattern "#?.info") (dest "Ami2D:tutorials"))
    )
)
(complete 80)

(set #bdir "Files/noWShell")
(if (exists "libs:wshell.library")
	(if (askbool (help @askbool-help) (prompt "Do you wish to use WShell specific features (highly recommended)?"))
        (set #bdir "Files/WShell")
	)
)

(copyfiles 
    (prompt "Installing ami2d.rexx...")
    (source #bdir)
    (all)
    (dest "Ami2D:rexx")
    (optional)
)
(complete 90)

(if (exists "sys:Names")
    (textfile
        (prompt "Creating assignment in sys:Names...")
        (help "Since it appears you are using Dave Haynie's 'BindNames' the assignment will be made in 'sys:Names' in a file called 'Ami2D'")
        (dest "sys:Names/Ami2D")
        (append "Ami2D: " @default-dest)
        (confirm)
    )
    (startup "Ami2D"
        (prompt "Inserting assignment into s:user-startup...")
        (help @startup-help)
        (command "assign Ami2D: " @default-dest)
    )
)
(complete 100)

(exit)