/*
$AUTHOR:  Manuel Lemos (UpperDesign@zeus.ci.ua.pt)
$VER: EditarCoordenadasDeGrupos 1.00 (3.10.94)
      Descrição:  Macro em ARexx para o FinalWriter que seleciona todos os
      objectos gráficos.
*/

options results

GraphicTool

OBJECTO_GRUPO = 8

selecionados = 0
FirstObject SELECTED
do until result = 0
  selecionados = selecionados + 1
  objectid.selecionados = result
  NextObject objectid.selecionados SELECTED
end

if selecionados >= 1 then
do

  call addlib("rexxreqtools.library", 0, -30, 0)

  COORDENADA_OK       = 1
  COORDENADA_PAGINA   = 2
  COORDENADA_ESQUERDA = 3
  COORDENADA_CIMA     = 4
  COORDENADA_LARGURA  = 5
  COORDENADA_ALTURA   = 6

  do objecto = 1 to selecionados
    GetObjectType objectid.objecto
    tipo = result
    if tipo = OBJECTO_GRUPO then
      do
        GetObjectCoords objectid.objecto
        coords = RESULT
        PARSE VAR coords pagina esquerda cima largura altura
        do until coordenadas = COORDENADA_OK
          do
            coordenadas = rtezrequest( "Coordenadas de grupo",,
                               "_Ok|_Página|_Esquerda|_Cima|_Largura|_Altura|_Cancelar",,
                               "" )
            select
              when coordenadas = COORDENADA_OK then
                do
                  SetObjectCoords objectid.objecto pagina esquerda cima largura altura
                  redraw
                  break
                end
  
              when coordenadas = COORDENADA_PAGINA then
                do
                  nova_pagina = rtgetlong( pagina,,
                                        "Página",,
                                        "Coordenadas de grupo",,
                                        "_Ok|_Cancelar")
                  if rtresult = 1 then
                    pagina = nova_pagina
                end
              when coordenadas = COORDENADA_ESQUERDA then
                do
                  nova_esquerda = rtgetstring( esquerda,,
                                        "Esquerda",,
                                        "Coordenadas de grupo",,
                                        "_Ok|_Cancelar")
                  if rtresult = 1 then
                    esquerda = nova_esquerda
                end
              when coordenadas = COORDENADA_CIMA then
                do
                  nova_cima = rtgetstring( cima,,
                                        "Cima",,
                                        "Coordenadas de grupo",,
                                        "_Ok|_Cancelar")
                  if rtresult = 1 then
                    cima = nova_cima
                end
              when coordenadas = COORDENADA_ALTURA then
                do
                  nova_altura = rtgetstring( altura,,
                                        "Altura",,
                                        "Coordenadas de grupo",,
                                        "_Ok|_Cancelar")
                  if rtresult = 1 then
                    altura = nova_altura
                end
              when coordenadas = COORDENADA_LARGURA then
                do
                  nova_largura = rtgetstring( largura,,
                                        "Largura",,
                                        "Coordenadas de grupo",,
                                        "_Ok|_Cancelar")
                  if rtresult = 1 then
                    largura = nova_largura
                end
              otherwise
                break
            end
          end
        end
      end
  end

  /* voltar a selecionar todos os objectos selecionados antes */
  do objecto = 1 to selecionados
    SelectObject objectid.objecto MULTIPLE
  end
  redraw
end