/* $VER: Import_Excel.adm 1.0 (24.5.95)

   Importiert Daten z.B. von Microsoft Excel.

   Dabei werden die Daten im Format
      Firma;Anrede;Briefanrede;Vorname;Nachname;Adresse;PLZ;Ort;Telefon;Fax
   erwartet, d.h. sie müssen mit Excel als CSV-Datei abgespeichert worden
   sein.

   Die "Briefanrede" (siehe Export_Winword.adm) wird dabe nicht übernommen.

   von Jan Geißler.
*/

OPTIONS RESULTS

ACTIVATEFIRST
ADDRINMEM
anzahl = RESULT


/* RexxReqTools-Library öffnen */

reqname = "rexxreqtools.library"
if ~show("L", reqname) then
  if ~addlib(reqname, 0, -30, 0) then do
     say reqname "not found!"
     EXIT
  end


/* Filename-Filerequester */

dir   = "ram:"
title = "Excel-Importdatei laden"
file  = "Adressen.csv"
ok    = "Laden"
rqflags = "rtfi_flags=freqf_save"

filename = rtfilerequest(dir,file,title,ok,rqflags,)
if filename = "" then do
  call rtezrequest("Keine Datei ausgewählt", "Abbruch")
  EXIT
end

IF ~OPEN(file,filename,"R") THEN DO   /* Ausgabedatei öffnen     */
   SAY "Kann Ausgabedatei nicht öffnen!"
   EXIT
END

DO WHILE ~EOF(file)

  text = ""; salute = ""
  text = READLN(file)

  IF text ~= "" THEN DO
    PARSE VAR text ADM.company ";" ADM.salutation ";" salute ";" ADM.firstname ";" ADM.lastname ";" ADM.address1 ";" ADM.postcode ";" ADM.city ";" ADM.telephone ";" ADM.fax

    ADM.SORT = "COMPANY"
    IF ADM.SALUTATION = "H" THEN ADM.SALUTATION = "Herrn"
    IF ADM.SALUTATION = "F" THEN ADM.SALUTATION = "Frau"
    NEWADDRESS ADM
  END;
END

ok = Close(file)