SECTION	MadDoctorStrange,Code_C
	OPT	C-,W+,O+

	JMP	LETS.GO.FOR.IT

	INCLUDE	"INCLUDE/HARDWARE/CUSTOM.I"
	INCLUDE	"INCLUDE/EXEC/EXEC_LIB.I"
	INCLUDE	"MAHONEY&KAKTUS"

	EVEN
LETS.GO.FOR.IT:
	MOVE.L	4,A6
	JSR	_LVOFORBID(A6)

	MOVE.L	4,A6
	CLR.L	D0
	LEA	GFXPOINTER,A1
	JSR	_LVOOPENLIBRARY(A6)
	MOVE.L	D0,A1
	MOVE.L	38(A1),OLD.CLIST
	MOVE.L	4,A6
	JSR	_LVOCLOSELIBRARY(A6)

	MOVE.L	#CLIST,$DFF080

	JSR	MT_INIT

	MOVE.L	#PICCY-2-(44*16),D0
	MOVE.W	D0,PL2L
	SWAP	D0
	MOVE.W	D0,PL2H

	MOVE.L	#PICCY+((290*44)*1)-2-(44*16),D0
	MOVE.W	D0,PL4L
	SWAP	D0
	MOVE.W	D0,PL4H

	MOVE.L	#PICCY+((290*44)*2)-2-(44*16),D0
	MOVE.W	D0,PL6L
	SWAP	D0
	MOVE.W	D0,PL6H

	MOVE.L	#BLANK.PLANE,D0
	MOVE.W	D0,PL1L
	SWAP	D0
	MOVE.W	D0,PL1H

	MOVE.L	#BLANK.PLANE,D0
	MOVE.W	D0,PL3L
	SWAP	D0
	MOVE.W	D0,PL3H

	MOVE.L	#BLANK.PLANE,D0
	MOVE.W	D0,PL5L
	SWAP	D0
	MOVE.W	D0,PL5H

	MOVE.L	#SPRITE1,D0
	MOVE.W	D0,SPR1L
	SWAP	D0
	MOVE.W	D0,SPR1H

	MOVE.L	#SPRITE2,D0
	MOVE.W	D0,SPR2L
	SWAP	D0
	MOVE.W	D0,SPR2H

	MOVE.L	#PICCY+(3*(290*44)),A0
	MOVE.L	#COLS+2+(8*4),A1

	REPT	8
	MOVE.W	(A0)+,(A1)
	ADD.L	#4,A1
	ENDR	

	BSET	#1,$BFE001

;------------------------------------------------------------------

	JSR	MAIN.BIT

;------------------------------------------------------------------

	JSR	MT_END

	MOVE.L	OLD.CLIST,$DFF080

	MOVE.L	#0,A0
	MOVE.L	#0,A1
	MOVE.L	#0,A2
	MOVE.L	#0,A3
	MOVE.L	#0,A4
	MOVE.L	#0,A5
	MOVE.L	#0,A6

	MOVE.L	4,A6
	JSR	_LVOPERMIT(A6)

	CLR.L	D0
	CLR.L	D1
	RTS

;------------------------------------------------------------------

MAIN.BIT:
	JSR	WAIT.RASTER
	JSR	SCROLLY
	JSR	VERTICAL.SCROLLER
	JSR	MT_MUSIC
	
	BTST	#6,$BFE001
	BNE.S	MAIN.BIT

	RTS

;------------------------------------------------------------------

VERTICAL.SCROLLER:
	LEA	$DFF000,A0
VERT.BLIT:
	BTST	#14,DMACONR(A0)
	BNE.S	VERT.BLIT

	MOVE.L	#$FFFFFFFF,BLTAFWM(A0)
	MOVE.W	#%0000100111110000,BLTCON0(A0)
	CLR.W	BLTCON1(A0)
	
	MOVE.W	#0,BLTAMOD(A0)
	MOVE.W	#0,BLTDMOD(A0)

	MOVE.L	#SPRITE1+4,BLTDPT(A0)
	MOVE.L	#SPRITE1+8,BLTAPT(A0)

	MOVE.W	#%0100000000000010,BLTSIZE(A0)

VERT.BLIT2:
	BTST	#14,DMACONR(A0)
	BNE.S	VERT.BLIT2

	MOVE.L	#SPRITE2+4,BLTDPT(A0)
	MOVE.L	#SPRITE2+8,BLTAPT(A0)

	MOVE.W	#%0100000000000010,BLTSIZE(A0)

	ADD.L	#40,CHAR.LINE
	CMP.L	#40*32,CHAR.LINE
	BNE	JUST.PLACE

	MOVE.L	#0,CHAR.LINE
	ADD.L	#1,VERT.TEXT.POINTER
RE.READ.TEXT:
	MOVE.L	VERT.TEXT.POINTER,A2
	CMP.B	#$FF,(A2)
	BNE	NO.TEXT.RESTART

	MOVE.L	#LARGETEXT,VERT.TEXT.POINTER
	JMP	RE.READ.TEXT

NO.TEXT.RESTART:
	CLR.L	D0
	MOVE.B	(A2),D0

	SUB.B	#$20,D0
	CLR.L	D2
	MOVE.B	D0,D2

	DIVU	#10,D2
	MULU	#40*32,D2
	MOVE.L	D2,A2

	ADD.L	#OTHERFONT,A2

	CLR.L	D3
	MOVE.B	D0,D3

	DIVU	#10,D0
	MULU	#10,D0

	SUB.W	D0,D3
	MOVE.L	D3,D0
	
	MULU	#4,D0
	ADD.L	D0,A2

	MOVE.L	A2,CHAR.ADDR

JUST.PLACE:
	MOVE.L	CHAR.ADDR,A1
	ADD.L	CHAR.LINE,A1
	MOVE.W	(A1),SPRITE1+4+(256*4)
	MOVE.W	2(A1),SPRITE2+4+(256*4)
	ADD.L	#10240,A1
	MOVE.W	(A1),SPRITE1+6+(256*4)
	MOVE.W	2(A1),SPRITE2+6+(256*4)

	RTS

;------------------------------------------------------------------

SCROLLY:
	CLR.L	D0
NEXT.SCROLLER:
	MOVE.L	#DIRECTION,A0
	ADD.L	D0,A0
	CMP.L	#1,(A0)

	BEQ	BACKWARDS

	MOVE.L	#XSCR.TABLE,A0
	ADD.L	D0,A0
	MOVE.L	(A0),A0

	MOVE.L	#SCRSPEED.TABLE,A1
	ADD.L	D0,A1

	MOVE.W	(A1),D1
	SUB.W	D1,(A0)

	BTST	#15,(A0)
	BEQ	NO.PROBLEM

	ADD.W	#16,(A0)

	MOVE.L	#XSCR.POINT.TABLE,A2
	ADD.L	D0,A2
	
	ADD.L	#2,(A2)

	CMP.L	#52,(A2)
	BNE	CHARACTER.CHECK

	MOVE.L	#4,(A2)
CHARACTER.CHECK:
	MOVE.L	#SCROLL.PLANE,D4

	MOVE.L	#SCROLL.LOCS,A5
	ADD.L	D0,A5
	ADD.L	(A5),D4

	MOVE.L	#XSCR.POINT.TABLE,A5
	ADD.L	D0,A5
	ADD.L	(A5),D4

	ADD.L	#4,D4

	MOVE.W	D4,8(A0)
	SWAP	D4
	MOVE.W	D4,4(A0)
	SWAP	D4

	MOVE.L	(A2),D1
	AND.L	#0,D1
	CMP.L	#0,D1
	BNE	NO.PROBLEM

	MOVE.L	#FONT,A5
	JSR	DROP.CHAR
	JMP	NO.PROBLEM

BACKWARDS:
	MOVE.L	#XSCR.TABLE,A0
	ADD.L	D0,A0
	MOVE.L	(A0),A0

	MOVE.L	#SCRSPEED.TABLE,A1
	ADD.L	D0,A1

	MOVE.W	(A1),D1
	ADD.W	D1,(A0)

	MOVE.W	(A0),D2
	AND.W	#$FFF0,D2
	CMP.W	#0,D2
	BEQ	NO.PROBLEM

	SUB.W	#16,(A0)

	MOVE.L	#XSCR.POINT.TABLE,A2
	ADD.L	D0,A2
	
	SUB.L	#2,(A2)

	CMP.L	#-2,(A2)
	BNE	CHARACTER.CHECK2

	MOVE.L	#46,(A2)
CHARACTER.CHECK2:
	MOVE.L	#SCROLL.PLANE,D4

	MOVE.L	#SCROLL.LOCS,A5
	ADD.L	D0,A5
	ADD.L	(A5),D4

	MOVE.L	#XSCR.POINT.TABLE,A5
	ADD.L	D0,A5
	ADD.L	(A5),D4

	ADD.L	#4,D4

	MOVE.W	D4,8(A0)
	SWAP	D4
	MOVE.W	D4,4(A0)
	SWAP	D4

	MOVE.L	(A2),D1
	AND.L	#0,D1
	CMP.L	#0,D1
	BNE.S	NO.PROBLEM

	MOVE.L	#FONT+40*40,A5
	JSR	DROP.CHAR
	JMP	NO.PROBLEM


NO.PROBLEM:
	ADD.L	#4,D0
	CMP.L	#4*32,D0
	BNE	NEXT.SCROLLER

	RTS

;------------------------------------------------------------------

DROP.CHAR:
	MOVE.L	#TEXTPOINTERS,A3
	ADD.L	D0,A3
	MOVE.L	(A3),A4

	CLR.L	D2
	MOVE.B	(A4),D2
	
	CMP.B	#$FF,D2
	BNE.S	NOT.SCROLL.RESET

	MOVE.L	#$20,D2
	MOVE.L	#SCROLLTEXT-1,(A3)
NOT.SCROLL.RESET:
	CMP.L	#$0A,D2
	BNE	NOT.RETURN

	MOVE.L	#$20,D2
NOT.RETURN:
	ADD.L	#1,(A3)
	SUB.B	#32,D2	

	CLR.L	D3
	MOVE.B	D2,D3	

	DIVU	#20,D3
	MULU	#40*8,D3

	CLR.L	D4
	MOVE.B	D2,D4
	
	DIVU	#20,D4
	MULU	#20,D4
	SUB.L	D4,D2

	MULU	#2,D2

	ADD.L	D2,D3

	ADD.L	D3,A5

	MOVE.L	#SCROLL.PLANE,D5

	MOVE.L	#SCROLL.LOCS,A4
	ADD.L	D0,A4
	ADD.L	(A4),D5

	MOVE.L	#XSCR.POINT.TABLE,A4
	ADD.L	D0,A4
	ADD.L	(A4),D5

	LEA	$DFF000,A6
BLIT.WAIT:
	BTST	#14,DMACONR(A6)
	BNE.S	BLIT.WAIT

	MOVE.L	#$FFFFFFFF,BLTAFWM(A6)

	MOVE.L	A5,BLTAPT(A6)
	MOVE.L	D5,BLTDPT(A6)
	;MOVE.L	#FONT+4,BLTAPT(A6)
	;MOVE.L	#SCROLL.PLANE+10,BLTDPT(A6)

	MOVE.W	#%0000100111110000,BLTCON0(A6)
	MOVE.W	#0,BLTCON1(A6)

	MOVE.W	#40-2,BLTAMOD(A6)
	MOVE.W	#94-2,BLTDMOD(A6)

	MOVE.W	#%0000001000000001,BLTSIZE(A6)

	ADD.L	#48,D5
BLIT.WAIT1:
	BTST	#14,DMACONR(A6)
	BNE.S	BLIT.WAIT1

	MOVE.L	#$FFFFFFFF,BLTAFWM(A6)

	MOVE.L	A5,BLTAPT(A6)
	MOVE.L	D5,BLTDPT(A6)
	;MOVE.L	#FONT+4,BLTAPT(A6)
	;MOVE.L	#SCROLL.PLANE+10,BLTDPT(A6)

	MOVE.W	#%0000100111110000,BLTCON0(A6)
	MOVE.W	#0,BLTCON1(A6)

	MOVE.W	#40-2,BLTAMOD(A6)
	MOVE.W	#94-2,BLTDMOD(A6)

	MOVE.W	#%0000001000000001,BLTSIZE(A6)

	RTS

;------------------------------------------------------------------

WAIT.RASTER:
	;MOVE.W	#$000,$DFF180

	MOVE.W	$DFF006,D0
	AND.W	#$FF00,D0
	CMP.W	#$FF00,D0
	BNE.S	WAIT.RASTER
WAIT.RASTER2:
	;MOVE.W	$DFF006,D0
	;AND.W	#$FF00,D0
	;CMP.W	#$1000,D0
	;BNE.S	WAIT.RASTER2

	;MOVE.W	#$888,$DFF180
	RTS
	
;------------------------------------------------------------------

	EVEN
MT_DATA:	INCBIN	"MOD.harleymusic"
	EVEN
		
	EVEN
		DCB.B	16*44,$0
PICCY:		INCBIN	"CALVIN.FRIGHT.RAW"
FONT:		INCBIN	"SMALL.FONT.RAW"
OTHERFONT:	INCBIN	"PARADROIDFONT.RAW"
SCROLL.PLANE:	DCB.B	(48*3)*256,$0
BLANK.PLANE:	DCB.B	(48*256)*2,$0

;------------------------------------------------------------------

	EVEN
GFXPOINTER:	DC.B	"graphics.library",0
SCROLLTEXT:	INCBIN	"Calvin.Intro.Text"
		DC.B	$FF
LARGETEXT:	INCBIN	"Calvin.Large.Text"
		DC.B	$FF

;------------------------------------------------------------------

	EVEN
OLD.CLIST:		DC.L	0
CHAR.LINE:		DC.L	0
CHAR.ADDR:		DC.L	0
VERT.TEXT.POINTER:	DC.L	LARGETEXT

;------------------------------------------------------------------

	EVEN
SCROLL.LOCS:		DC.L	(48*16)*0,(48*16)*1,(48*16)*2,(48*16)*3,(48*16)*4,(48*16)*5,(48*16)*6,(48*16)*7,(48*16)*8,(48*16)*9,(48*16)*10,(48*16)*11,(48*16)*12,(48*16)*13,(48*16)*14,(48*16)*15
			DC.L	(48*16)*16,(48*16)*17,(48*16)*18,(48*16)*19,(48*16)*20,(48*16)*21,(48*16)*22,(48*16)*23,(48*16)*24,(48*16)*25,(48*16)*26,(48*16)*27,(48*16)*28,(48*16)*29,(48*16)*30,(48*16)*31
XSCR.POINT.TABLE:	DC.L	0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
XSCR.TABLE:		DC.L	XSCR1,XSCR2,XSCR3,XSCR4,XSCR5,XSCR6,XSCR7,XSCR8,XSCR9,XSCR10,XSCR11,XSCR12,XSCR13,XSCR14,XSCR15,XSCR16
			DC.L	XSCR17,XSCR18,XSCR19,XSCR20,XSCR21,XSCR22,XSCR23,XSCR24,XSCR25,XSCR26,XSCR27,XSCR28,XSCR29,XSCR30,XSCR31,XSCR32
TEXTPOINTERS:		DC.L	SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT
			DC.L	SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT,SCROLLTEXT
SCRSPEED.TABLE:		DC.W	9,0,8,0,7,0,6,0,5,0,4,0,3,0,2,0,1,0,2,0,3,0,4,0,5,0,6,0,7,0,8,0,9,0,8,0,7,0
			DC.W	6,0,5,0,4,0,3,0,2,0,1,0,2,0,3,0,4,0,6,0,7,0,8,0,9,0,8,0,7,0,6,0,5,0,4,0
DIRECTION:		DC.L	0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
			DC.L	1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1

;------------------------------------------------------------------

	EVEN
CLIST:
	DC.W	$0120,$0000,$0122,$0000,$0124,$0000,$0126,$0000,$0128,$0000,$012A,$0000,$012C,$0000,$012E,$0000
	DC.W	$0130,$0000,$0132,$0000,$0134,$0000,$0136,$0000,$0138,$0000,$013A,$0000,$013C,$0000,$013E,$0000

COLS:	DC.W	$0190,$0444,$0182,$0444,$0184,$0444,$0186,$0444,$0188,$0444,$018A,$0444,$018C,$0444,$018E,$0444
	DC.W	$0180,$0444,$0192,$0444,$0194,$0444,$0196,$0444,$0198,$0444,$019A,$0444,$019C,$0444,$019E,$0444

	DC.W	$01A0,$0444,$01A2,$0FFF,$01A4,$0444,$01A6,$0444,$01A8,$0444,$01AA,$0444,$01AC,$0444,$01AE,$0444
	DC.W	$01B0,$0444,$01B2,$0444,$01B4,$0444,$01B6,$0444,$01B8,$0444,$01BA,$0444,$01BC,$0444,$01BE,$0444

	DC.W	DIWSTRT,$2871,DIWSTOP,$2CC1,DDFSTRT,$28,DDFSTOP,$FF

	DC.W	$108,48,$10A,-2,$180,$AAA

	DC.W	SPRPT
SPR1H:	DC.W	0,SPRPT+2
SPR1L:	DC.W	0,SPRPT+4
SPR2H:	DC.W	0,SPRPT+6
SPR2L:	DC.W	0
	
	DC.W	BPLCON2,9,BPLCON0,$0200,BPLCON1
	DC.W	0

	DC.W	BPLPT
PL1H:	DC.W	0,BPLPT+2
PL1L:	DC.W	0,BPLPT+4
PL2H:	DC.W	0,BPLPT+6
PL2L:	DC.W	0,BPLPT+8
PL3H:	DC.W	0,BPLPT+10
PL3L:	DC.W	0,BPLPT+12
PL4H:	DC.W	0,BPLPT+14
PL4L:	DC.W	0,BPLPT+16
PL5H:	DC.W	0,BPLPT+18
PL5L:	DC.W	0,BPLPT+20
PL6H:	DC.W	0,BPLPT+22
PL6L:	DC.W	0

	DC.W	$2809,$FFFE,BPLCON2,$41,BPLCON0,$6600,BPLCON1
XSCR1:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$FFF,$180,$999
	DC.W	$3009,$FFFE,BPLCON1
XSCR2:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$EEE,$180,$888
	DC.W	$3809,$FFFE,BPLCON1
XSCR3:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$DDD,$180,$777
	DC.W	$4009,$FFFE,BPLCON1
XSCR4:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$CCC,$180,$666
	DC.W	$4809,$FFFE,BPLCON1
XSCR5:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$BBB,$180,$555
	DC.W	$5009,$FFFE,BPLCON1
XSCR6:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$AAA,$180,$444
	DC.W	$5809,$FFFE,BPLCON1
XSCR7:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$999,$180,$333
	DC.W	$6009,$FFFE,BPLCON1
XSCR8:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$888,$180,$222
	DC.W	$6809,$FFFE,BPLCON1
XSCR9:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$999,$180,$333
	DC.W	$7009,$FFFE,BPLCON1
XSCR10:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$AAA,$180,$444
	DC.W	$7809,$FFFE,BPLCON1
XSCR11:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$BBB,$180,$555
	DC.W	$8009,$FFFE,BPLCON1
XSCR12:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$CCC,$180,$666
	DC.W	$8809,$FFFE,BPLCON1
XSCR13:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$DDD,$180,$777
	DC.W	$9009,$FFFE,BPLCON1
XSCR14:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$EEE,$180,$888
	DC.W	$9809,$FFFE,BPLCON1
XSCR15:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$EEE,$180,$888
	DC.W	$A009,$FFFE,BPLCON1
XSCR16:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$DDD,$180,$777
	DC.W	$A809,$FFFE,BPLCON1
XSCR17:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$CCC,$180,$666
	DC.W	$B009,$FFFE,BPLCON1
XSCR18:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$BBB,$180,$555
	DC.W	$B809,$FFFE,BPLCON1
XSCR19:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$AAA,$180,$444
	DC.W	$C009,$FFFE,BPLCON1
XSCR20:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$999,$180,$333
	DC.W	$C809,$FFFE,BPLCON1
XSCR21:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$888,$180,$222
	DC.W	$D009,$FFFE,BPLCON1
XSCR22:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$999,$180,$333
	DC.W	$D809,$FFFE,BPLCON1
XSCR23:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$AAA,$180,$444
	DC.W	$E009,$FFFE,BPLCON1
XSCR24:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$BBB,$180,$555
	DC.W	$E809,$FFFE,BPLCON1
XSCR25:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$CCC,$180,$666
	DC.W	$F009,$FFFE,BPLCON1
XSCR26:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$DDD,$180,$777
	DC.W	$F809,$FFFE,BPLCON1
XSCR27:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$EEE,$180,$888

	DC.W	$FF09,$FFFE,$FFDD,$FFFE,$0009,$FFFE

	DC.W	BPLCON1
XSCR28:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$FFF,$180,$999
	DC.W	$0809,$FFFE,BPLCON1
XSCR29:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$EEE,$180,$888
	DC.W	$1009,$FFFE,BPLCON1
XSCR30:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$DDD,$180,$777
	DC.W	$1809,$FFFE,BPLCON1
XSCR31:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$CCC,$180,$666
	DC.W	$2009,$FFFE,BPLCON1
XSCR32:	DC.W	0,BPLPT+0,$0,BPLPT+2,$0,$182,$BBB,$180,$555
	DC.W	$2809,$FFFE,BPLCON0,$0200

	DC.W	$FFFF,$FFFE

;-----------------------------------------------------------------

SPRITE1:
	DC.W	$283C,$FF02
	REPT	512
	DC.W	$0000,$0000
	ENDR
	DC.W	$0000,$0000
SPRITE2:
	DC.W	$2844,$FF02
	REPT	512
	DC.W	$0000,$0000
	ENDR
	DC.W	$0000,$0000