;
;   $VER: CheckBootDate 1.1 (09.01.94)
;
;   Written 20. September 1993 by J.Matern
;   This file is part of the 'UpTime'-package © by Jürgen Matern.
;   The package may be redistributed under limitations discribed
;   in the file 'UpTime.doc' which should have come with this
;   distribution. Read this file for more information!
;
;   Last changed: 9. January 1994
;
set newyear 0
set LastBoot `date`
if exists ENV:UpTime/LastBoot
   set LastBoot `getenv UpTime/LastBoot`
endif
set NowBoot `date`
set LogBoot $NowBoot
set LastTime 0
if exists ENV:UpTime/UpTime
   set LastTime `getenv UpTime/UpTime`
endif
set UpFileName S:UpTime.++
if exists ENV:UpTime/UpFileName
   set UpFileName `getenv UpTime/UpFileName`
endif

set LastBoot `S:CutArg $LastBoot`
set NowBoot `S:CutArg $NowBoot`

S:OnOff
if "$LastBoot" not eq "$NowBoot"
   set LastTime 0
   if exists ENV:UpTime/UpTime
      set LastTime `getenv UpTime/UpTime`
   endif

   set hours `eval $LastTime / 60`
   set minutes `eval $LastTime - ($hours * 60)`
   set LastTime `echo SystemUpTime: $hours h $minutes min.`

   echo >> $UpFileName $LastBoot $LastTime

   if $newyear eq "1"
      S:NewFileNames
      type >> $OnOffFileName T:OnOff.temp
      delete T:OnOff.temp quiet
   endif

   setenv UpTime/UpTime 0
   copy ENV:UpTime/UpTime ENVARC:UpTime/UpTime
   run > nil: < nil: updatedb ; Remove this line, if you don't use 'FIND'.
endif

set LogFileName S:LogFile.++
if exists ENV:UpTime/LogFileName
   set LogFileName `getenv UpTime/LogFileName`
endif

echo >> $LogFileName $LogBoot
echo > ENVARC:UpTime/LastBoot $LogBoot
echo > ENV:UpTime/LastBoot $LogBoot

unset LastBoot
unset NowBoot
unset LogBoot
unset LastTime
unset UpFileName
unset hours
unset minutes
unset newyear
unset LogFileName
unset OnOffFileName