;Installer Install-Script für FTrans

(set picked_user-level @user-level)
(set @default-dest "")
(set ftrans-default_dest "WORK:")
(set ftrans "FTrans")
(set ftrans_guide "FTrans.guide")
(set ftrans_arexx "FTrans.rexx")
(set ftced_script "FTCed.ced")
(set rexx_dir "REXX:")
(set libs_dir "LIBS:")
(set rexxcedlib212 "CEDSupportLibs/ced212/rexxcedsupport.library")
(set rexxcedlib35  "CEDSupportLibs/ced35/rexxcedsupport.library")

;=============================================================================
; German strings

(set #bad-kick
 (cat "Sie müssen Kickstart 2.04 auf Ihrem Rechner installiert haben\num dieses Script zu verwenden.\nFTrans ist erst ab dieser Kickstart funktionsfähig!")
)

(set #where-ftrans "In welchem Verzeichnis soll FTrans installiert werden?\nAchtung, eine Schublade im angegebenen Verzeichnisspfad mit Namen FTrans wir noch automatisch angelegt.")
(set #demo_arexx   "\nSoll das Demo-Arexx-Script nach REXX: installiert werden?")

(set #help_demo_arexx_script "Ja   - installiert das ARexx-Script nach REXX:\nNein - überspringt diesen Teil, das ARexx-Script\n       wird nicht installiert.")

(set #copying-ftrans     "Kopiere FTrans...")
(set #copying-dicts      "Kopiere Wörterbuch/Wörterbücher...")

(set #copying-ced212lib  "\nKopiere rexxcedsupport.library für CED 2.12 nach Libs:...")
(set #copying-ced35lib   "\nKopiere rexxcedsupport.library für CED 3.5 nach Libs:...")

(set #copying-ftrans_guide "\nKopiere FTrans.guide...")

(set #copying-ced_arexx-script  "\nKopiere ARexx-Script FTCed.ced nach REXX:...")
(set #copying-ftrans_arexx-script  "\nKopiere ARexx-Script FTrans.rexx nach REXX:...")

(set #install-msg
(cat "\n\nFTrans Installations-Script.\n"
     "Dieses Script installiert FTrans auf Ihrem Amiga.\n\n"
     "Lesen Sie die Dokumentation zur genaueren Information.\n\n"
     "FTrans © 1992-1994 Rainer Hess\n"
     "Alle Rechte vorbehalten."
))

;=============================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
(
    (abort #bad-kick)
))

;=============================================================================

(complete 0)

(message #install-msg)

(complete 1)

(set ftransdir
	(tackon
		(askdir
			(prompt #where-ftrans)
			(help @askdir-help)
			(default ftrans-default_dest)
		)
	"FTrans"
	)
)

(complete 10)

; Schublade anlegen
(makedir ftransdir (infos))

(copyfiles
	(prompt #copying-ftrans)
	(source ftrans)
	(dest ftransdir)
	(infos)
	(noposition)
)

(complete 25)

(copyfiles
	(prompt #copying-ftrans_guide)
	(source ftrans_guide)
	(dest ftransdir)
	(infos)
	(noposition)
)

(complete 35)

(copyfiles
	(prompt #copying-dicts)
	(help @copyfiles-help)
	(source "")
	(dest ftransdir)
	(pattern "#?.dic")
	(files)
	(confirm)
)

(complete 50)

(set which_ced
	(askchoice
		(prompt "Soll die rexxcedsupport.library und das ARexx-Script für CygnusEd installiert werden?\n\nWelche CygnusEd-Version verwenden Sie?")
		(help @askchoice-help)
		(choices "Keinen" "CED 2.12" "CED 3.5")
		(default 0)
	)
)

(complete 75)

(debug "Choice was " which_ced)

( if (> which_ced 0)
	(copyfiles
		(prompt #copying-ced_arexx-script)
		(source ftced_script)
		(dest rexx_dir)
		(infos)
		(noposition)
	)
)

(complete 80)

( if (= which_ced 1)
	(copyfiles
		(prompt #copying-ced212lib)
		(source rexxcedlib212)
		(dest libs_dir)
		(infos)
		(noposition)
	)
)

( if (= which_ced 2)
	(copyfiles
		(prompt #copying-ced35lib)
		(source rexxcedlib35)
		(dest libs_dir)
		(infos)
		(noposition)
	)
)

(complete 95)

(set demo_arexx-script
	(askbool
		(prompt #demo_arexx)
		(help #help_demo_arexx_script)
		;(choices "Yes" "No" )
		(default 0)
	)
)

( if (= demo_arexx-script 1)
	(copyfiles
		(prompt #copying-ftrans_arexx-script)
		(source ftrans_arexx)
		(dest rexx_dir)
		(infos)
		(noposition)
	)
)

(complete 100)

(exit)