; Ask-Befehl über Requester
; Returncode WARN bei Bestätigung
; V1.0 ©1994 by Menne

execbase = 4
OpenLib	 = -552
CloseLib = -414

Write	= -48
Output	= -60

AutoRequest = -348


	move.l	d0,argc		; Parameter retten

	cmp.l	#1,d0
	ble	errmsg		; keine Parameter ?

	move.l	argc,d0
	and.l	#$3F,d0		; maximal 62 Zeichen	

	lea bodytext,a1		; Übergebenen Text 
	sub.l	#2,d0		; in den Requesterbody
getstring:
	move.b	(a0)+,d1
	move.b	d1,(a1)+
	dbra	d0,getstring


	move.l	execbase,a6
	lea	intuiname,a1
	moveq	#0,d0
	jsr	OpenLib(a6)
	tst.l	d0
	beq	_nointuition

	move.l	d0,a6

requ:
	move.l	#0,a0		; WBSCREEN
	lea	btext,a1	; Bodytext
	lea	ltext,a2	; Lefttext
	lea	rtext,a3	; Righttext
	move.l	#0,d0		; IDCMP left
	move.l	#0,d1		; IDCMP right
	move.l	#180,d2
	move.l	#80,d3
	jsr	AutoRequest(a6)

auswertung:
	move.l	d0,argc		; Antwort sichern (1=ja)

	move.l	a6,a1
	move.l	execbase,a6
	jsr	CloseLib(a6)
	
_nointuition:
	move.l	argc,d0
	mulu	#5,d0		; Returncode 
	rts


errmsg:
	move.l	execbase,a6
	lea	dosname,a1
	moveq	#0,d0
	jsr	OpenLib(a6)

	tst.l	d0
	beq	_ndos
	move.l	d0,a6
	jsr	Output(a6)

	move.l	d0,d1
	move.l	#errtxt,d2
	move.l	#errtxt2-errtxt,d3
	jsr	Write(a6)

	move.l	a6,a1
	move.l	execbase,a6
	jsr	CloseLib(a6)
_ndos:
	move.l	#20,d0
	rts




intuiname:
	dc.b "intuition.library",0
	even
intuibase:
	dc.l 0

btext:
	dc.b	0,1	; Farben
	dc.b	0	; Modus
	even
	dc.w	10,10	; Text-Position
	dc.l	0	; topaz
	dc.l	bodytext
	dc.l	0	; kein weiterer Text
bodytext:
	dc.l 0
	dc.b "ReqAsk V1.00 ©1994 by Manfred Klier",0
        ds.b 24
	even


ltext:
	dc.b	0,1	; Farben
	dc.b	0	; Modus
	even
	dc.w	5,3	; Text-Position
	dc.l	0	; topaz
	dc.l	lefttext
	dc.l	0	; kein weiterer Text
lefttext:
	dc.b "Ja",0
	even

rtext:
	dc.b	0,1	; Farben
	dc.b	0	; Modus
	even
	dc.w	5,3	; Text-Position
	dc.l	0	; topaz
	dc.l	righttext
	dc.l	0	; kein weiterer Text
righttext:
	dc.b "Nein",0
	even

argc:
	dc.l	0
dosname:
	dc.b "dos.library",0
	even
errtxt:
	dc.b "Benutze: ReqAsk <Text>",10,0
errtxt2:
 END