(if	(exists "Games:" (noreq) )
	(set @default-dest "Games:")
	(if	(exists "SYS:Games" (noreq) )
		(set @default-dest "SYS:Games")
		(if	(exists "Work:Games" (noreq) )
			(set @default-dest "Work:Games")
			(if	(exists "JEUX:" (noreq) )
				(set @default-dest "JEUX:")
				(set @default-dest "SYS:")
			)
		)
	)
)
(set #readme-file "Readme") ;name of readme file

;---
; Checks if given program is reachable via the path
; if not abort install
; IN:  #program - to check
; OUT: -

(procedure P_chkrun
 (if (= 0 (run ("cd SYS:\nWhich %s" #program)))
     ("")
     (abort ("You must install \"%s\" first !\nIt must be accessible via the path.\nYou can find it in the whdload package." #program))
))

(if (exists #readme-file)
    (if	(= 0 (run ("SYS:Utilities/Multiview %s" #readme-file)))
	("")
	(run ("SYS:Utilities/More %s" #readme-file))
    )
)
(set #program "WHDLoad")
(P_chkrun)

; in expert mode ask for source drive
(if (= @user-level 2)
    ((set #CI_drive
      (askchoice
	(prompt "\nSelect source drive to install from\n")
	(default 0)
	(choices "DF0:" "DF1:" "RAD:" "Enter Device")
	(help @askchoice-help)
      ))
      (select #CI_drive
	(set #CI_drive "DF0:")
	(set #CI_drive "DF1:")
	(set #CI_drive "RAD:")
	(set #CI_drive
	 (askstring
		(prompt "\nEnter source drive to install from")
		(default "DF0:")
		(help @askstring-help)
	))
     ))
     (set #CI_drive "DF0:")
)


;---

(set #dest
  (askdir
    (prompt ("Where should \"%s\" installed ?\nA drawer \"%s\" will automatically created." @app-name @app-name))
    (help @askdir-help)
    (default @default-dest)
    (disk)
  )
)
(set @default-dest (tackon #dest @app-name))

(set #dest @default-dest)
(if (exists #dest)
    ((set #choice
      (askbool
	(prompt ("\nDirectory \"%s\" already exists.\n Should it be deleted ?" #dest))
	(default 1)
	(choices "Delete" "Skip")
	(help @askbool-help)
      ))
      (if (= #choice 1)
	  (run ("Delete \"%s\" \"%s.info\" All" #dest #dest))
     ))
)
(makedir #dest
	(help @makedir-help)
	(infos)
)

;---

(copyfiles
	(help @copyfiles-help)
	(source ("%s.slave" @app-name))
	(dest #dest)
)
(if (exists ("%s.newicon" @app-name))
    (set #icon
	(askchoice
		(prompt "\nWhich icon would you like to install ?\n")
		(default 0)
		(choices "RomIcon" "NewIcon")
		(help @askchoice-help)
	)
    )
    (set #icon 0)
)
(select #icon
	(set #icon ("%s.inf" @app-name))
	(set #icon ("%s.newicon" @app-name))
)
(copyfiles
	(help @copyfiles-help)
	(source #icon)
	(newname ("%s.info" @app-name))
	(dest #dest)
)
(if (exists #readme-file)
    (copyfiles
	(help @copyfiles-help)
	(source #readme-file)
	(dest #dest)
	(infos)
    )
)

;---

(copyfiles
	(help @copyfiles-help)
	(source "OSEmu.400")
	(dest #dest)
)
(copyfiles
	(help @copyfiles-help)
	(source @app-name)
	(dest #dest)
)

;---

(message ("\n\n\nPlease insert %s disk into drive %s !!!" @app-name #CI_drive))

(copyfiles
	(help @copyfiles-help)
	(source #CI_drive)
	(dest #dest)
	(pattern "(#?.spr|#?.pi1|#?.dat)")
	(files)
)
(exit)