(if	(exists "Games:" (noreq) )
	(set @default-dest "Games:")
	(if	(exists "SYS:Games" (noreq) )
		(set @default-dest "SYS:Games")
		(if	(exists "Work:Games" (noreq) )
			(set @default-dest "Work:Games")
			(if 	(exists "JEUX:" (noreq) )
				(set @default-dest "JEUX:")
				(set @default-dest "SYS:")
			)
		)
	)
)
(set #readme-file "README") ;name of readme file
(set #last-disk 4)          ;amount of disks

;---
; Checks if given program is reachable via the path
; if not abort install
; IN:  #program - to check
; OUT: -

(procedure P_chkrun
 (if (= 0 (run ("cd SYS:\nWhich %s" #program)))
     ("")
     (abort ("You must install \"%s\" first !\nIt must be accessible via the path.\nYou can find it in the whdload package." #program))
))

(procedure P_disk
 ((askdisk
	(prompt	("\n\n\nPlease insert %s in any drive" #CI_diskname))
	(dest #CI_diskname)
	(help ("Insert %s in any floppy drive\nor you'll wait for a while!" #CI_diskname))
	(assigns)
  )
  (copyfiles
	(source ("%s:" #CI_diskname ))
	(dest #dest)
	(pattern "(F#?|Cine|Data|Music|Sound)")
)))

;---
(if (exists #readme-file)
    (if	(= 0 (run ("SYS:Utilities/Multiview %s" #readme-file)))
	("")
	(run ("SYS:Utilities/More %s" #readme-file))
    )
)
(set #program "WHDLoad")
(P_chkrun)

(set #program "DIC")
(P_chkrun)

(set #dest
 (askdir
	(prompt ("Where should \"%s\" installed ?\nA drawer \"%s\" will automatically created." @app-name @app-name))
	(help @askdir-help)
	(default @default-dest)
	(disk)
))
(set @default-dest (tackon #dest @app-name))

(set #dest @default-dest)
(if (exists #dest)
    ((set #choice
      (askbool
	(prompt ("\nDirectory \"%s\" already exists.\n Should it be deleted ?" #dest))
	(default 1)
	(choices "Delete" "Skip")
	(help @askbool-help)
     ))
     (if (= #choice 1)
	 (run ("Delete \"%s\" \"%s.info\" All" #dest #dest))
    )
  )
)
(makedir #dest
	(help @makedir-help)
	(infos)
)
;---

(copyfiles
	(help @copyfiles-help)
	(source ("%s.slave" @app-name))
	(dest #dest)
)
(if (exists ("%s.newicon" @app-name))
    (set #icon
	(askchoice
		(prompt "\nWhich icon would you like to install ?\n")
		(default 0)
		(choices "RomIcon" "NewIcon")
		(help @askchoice-help)
	)
    )
    (set #icon 0)
)
(select #icon
	(set #icon ("%s.inf" @app-name))
	(set #icon ("%s.newicon" @app-name))
)
(copyfiles
	(help @copyfiles-help)
	(source #icon)
	(newname ("%s.info" @app-name))
	(dest #dest)
)
(copyfiles
	(help @copyfiles-help)
	(source "OSEmu.400")
	(dest #dest)
)
(if (exists #readme-file)
    (copyfiles
	(help @copyfiles-help)
	(source #readme-file)
	(dest #dest)
	(infos)
    )
)
(set #CI_diskno 1)
(while
  (<= #CI_diskno #last-disk)
  ( (set #CI_diskname ("%s Disk %ld" @app-name #CI_diskno))
    (P_disk)
    (set #CI_diskno (+ #CI_diskno 1))
  )
)
(if	(= 0 (run ("patchexe %s" (tackon #dest "Flashback"))))
	("")
	(if	(= 0 (run ("xfddecrunch >NIL: %s" (tackon #dest "Flashback"))))
		(if	(= 0 (run ("patchexe %s" (tackon #dest "Flashback"))))
			("")
			(abort "Could not patch executable!")
		)
		(abort "Could not patch executable!")
	)
)
(exit)