;****************************

(set #sub-dir "data")		;sub directory containing data files
(set #readme-file "VikingChild.readme") ;name of readme file

;----------------------------
; Checks if given program is reachable via the path
; if not abort install
; IN:  #program - to check
; OUT: -

(procedure P_chkrun
  (if
    (= 0 (run ("cd SYS:\nWhich %s" #program)))
    ("")
    (abort ("You must install \"%s\" first !\nIt must be accessible via the path.\nYou can find it in the whdload package." #program))
  )
)

(if
  (exists #readme-file)
  (if
    (= 0 (run ("SYS:Utilities/Multiview %s" #readme-file)))
    ("")
    (run ("SYS:Utilities/More %s" #readme-file))
  )
)

(set #program "WHDLoad")
(P_chkrun)

(set @default-dest
  (askdir
    (prompt ("Where should \"%s\" installed ?\nA drawer \"%s\" will automatically created." @app-name @app-name))
    (help @askdir-help)
    (default @default-dest)
    (disk)
  )
)
(set #dest (tackon @default-dest @app-name))
(if
  (exists #dest)
  (
    (set #choice
      (askbool
        (prompt ("\nDirectory \"%s\" already exists.\n Should it be deleted ?" #dest))
        (default 1)
        (choices "Delete" "Skip")
        (help @askbool-help)
      )
    )
    (if
      (= #choice 1)
      (run ("Delete \"%s\" \"%s.info\" All" #dest #dest))
    )
  )
)
(makedir #dest
  (help @makedir-help)
  (infos)
)

(copyfiles
  (help @copyfiles-help)
  (source ("%s.slave" @app-name))
  (dest #dest)
)


(if
  (exists ("%s.newicon" @app-name))
  (set #icon
    (askchoice
      (prompt "\nWhich icon do you like to install ?\n")
      (default 0)
      (choices "Normal" "NewIcon")
      (help @askchoice-help)
    )
  )
  (set #icon 0)
)
(select #icon
  (set #icon ("%s.inf" @app-name))
  (set #icon ("%s.newicon" @app-name))
)
(copyfiles
  (help @copyfiles-help)
  (source #icon)
  (newname ("%s.info" @app-name))
  (dest #dest)
)
(if
  (exists #readme-file)
  (copyfiles
    (help @copyfiles-help)
    (source #readme-file)
    (dest #dest)
    (infos)
  )
)

(if
  (exists ("%s.info" #readme-file))
  (copyfiles
    (help @copyfiles-help)
    (source ("%s.info" #readme-file))
    (dest #dest)
  )
)

(if
  (= #sub-dir "")
  ("")
  (
    (set #dest (tackon #dest #sub-dir))
    (makedir #dest
      (help @makedir-help)
    )
  )
)

(copyfiles
  (help @copyfiles-help)
  (source "RipVik1.slave")
  (dest #dest)
)

(copyfiles
  (help @copyfiles-help)
  (source "RipVik2.slave")
  (dest #dest)
)

(copyfiles
  (help @copyfiles-help)
  (source "RipVik3.slave")
  (dest #dest)
)

(copyfiles
  (help @copyfiles-help)
  (source "launcher.bin")
  (dest #dest)
)

(message "Please insert Viking Child Disk #1 in DF0:\nRipper will create and encrypt all needed data.")
(run ("cd \"%s\"\nwhdload RipVik1.slave WriteDelay=10 NOCACHE NOMMU\nDelete RipVik1.slave ALL QUIET FORCE" #dest))
(message "Please insert Viking Child Disk #2 in DF0:\nRipper will create and encrypt all needed data.")
(run ("cd \"%s\"\nwhdload RipVik2.slave WriteDelay=10 NOCACHE NOMMU\nDelete RipVik2.slave ALL QUIET FORCE" #dest))
(message "Please insert Viking Child Disk #3 in DF0:\nRipper will create and encrypt all needed data.")
(run ("cd \"%s\"\nwhdload RipVik3.slave WriteDelay=10 NOCACHE NOMMU\nDelete RipVik3.slave ALL QUIET FORCE" #dest))

(exit)