'**************************************
'                                     *
'     IntuiExtend.Lib 2.0/@1995-98    *
'                                     *
'          by CIERP Philippe.         *
'                                     *
'          from AMIGAzette 83         *
'                                     *
'**************************************
'
'  Command 
'  -Wb Wind Open     
'  -Wb Wind Base   
'  -Wb Wind Rastport   
'  -Str Store    
'  -Wb Wind Title    
'  -Wb Gfx Mode    
'  -Wb Gfx Text    
'  -Wb Bevel Box     
'  -Wb Gfx Ink     
'  -Wb Init Bool Gadget    
'  -Wb Bevel Gadget    
'  -Wb Insert Gadget     
'  -Wb Refresh Gadget    
'  -Get Msg    
'  -Get Msg Iadr   
'  -Wb Locker    
'  -Wb Wind Close  
'  -Str Free   
'  -Wb Gfx Text  
'
Amos To Back 
Wb Locker 1
'
Wb Wind Open SCR To 164,56,300,66,2+4+8+$2000000
W=Wb Wind Base : R=Wb Wind Rastport(W)
S0=Str Store("CIERP Philippe presente...")
S1=Str Store(" Copyright 1994-98 * AmigaZETTE 83")
Wb Wind Title W To S0,S1
'
Wb Gfx Mode R,1 : Wb Gfx Ink R To 2,0
Wb Gfx Text "IntuiExtend.Lib v2.0 ©1994",47,24 To R
Wb Gfx Text "Selectionnez un bouton S.V.P...",23,36 To R
'
Wb Bevel Box R To 1,2,11,13,285,43
'
Wb Gfx Ink R To 1,0
'
BOUT[R,10,48,88,2,1,"Ok"]
BGAD0=Wb Init Bool Gadget(0,11,49,86,11,2) : Wb Bevel Gadget BGAD0
Wb Insert Gadget W To BGAD0 : Wb Refresh Gadget W,BGAD0
'
BOUT[R,105,48,88,2,1,"Bell"]
BGAD1=Wb Init Bool Gadget(1,106,49,86,11,2) : Wb Bevel Gadget BGAD1
Wb Insert Gadget W To BGAD1 : Wb Refresh Gadget W,BGAD1
'
BOUT[R,200,48,88,2,1,"Annuler"]
BGAD2=Wb Init Bool Gadget(2,201,49,86,11,2) : Wb Bevel Gadget BGAD2
Wb Insert Gadget W To BGAD2 : Wb Refresh Gadget W,BGAD2
'
Do 
   '
   Z=Get Msg(W)
   Z1=Get Msg Iadr
   '
   If Z1=BGAD0
      G=1
      Exit 
   End If 
   If Z1=BGAD1
      Bell 
   End If 
   If Z1=BGAD2 or Z=$200
      G=-1
      Exit 
   End If 
   '
Loop 
'
RR:
Wb Locker 0
Default 
Print G
Amos To Front 
Wb Wind Close W
Str Free S0
Str Free S1
Wait Key 
'
Procedure BOUT[R,X,Y,W,C0,C1,T$]
   X1=(X+44)-(Len(T$)*4)
   Wb Gfx Text T$,X1,Y+9 To R
End Proc