;------------------------------------------------------------------------
;
; The Amiga Quake Manager V1.01
;
; $VER: QuakeManger-Install 1.01 (12.9.98)
;
; (C)1998 Marco Fabain
;
; http://www.goigoi.com/      The Home Of Quake Manager
;
;------------------------------------------------------------------------


(complete 0)
(set @default-dest "SYS:")
(set @app-name "TAQM-Install")
(set @user-level 2)

;/*----------------------------------------------------*/
;/*                                                    */
;/*                                                    */
;/*                   Main                             */
;/*                                                    */
;/*                                                    */
;/*----------------------------------------------------*/

;-> Show Info Text
(message
     (cat "\nWelcome to \n"
	  "The Amiga QuakeManager V1.01\n compiled 12-Sep-1998\n\n"
	  "For updates please visit\nhttp://www.goigoi.com/\n\n"
	  "Attention:\n"
	  "TAQM requires 1.2 MB on your HD\n\n"
	  "Make sure you enough free!")
)
;-> Assign Archive Dir
(set #installfrom
     (expandpath
       (tackon "" "")
))
;-> Ask for Directory
(set #installdir
     (expandpath
       (askdir
	 (default "SYS:")
	 (prompt  (cat "Select the target directory. A directory QManager will "
		       "be created there."))
	 (help #Path-Help)
	 (disk)
       )
     )
)
(complete 10)
;-> Create Variable to create Dir
(set #copyto (tackon #installdir "QManager")
)
;-> Make the Directory
(makedir #copyto
	(prompt (cat "Creating now the QManager directory\nin the following specified directory\n\n" #copyto))
	(help (cat "QManager will be installed to the specified directory!"))
	(infos)
	(confirm)
)
(complete 30)
;-> Copy Files To New Dir
(copyfiles
	(prompt (cat "Copying now all files+dirs to " #copyto))
	(help (cat "Moving all files to you specified directory!"))
	(source #installfrom)
	(dest #copyto)
	(all)
	(confirm)
)
;-> Copying Fonts to FONTS:
;-> from
(set #fonts_from
     (expandpath
       (tackon #installfrom "fonts")
     )
)
;-> to
(set #fonts_to
     (expandpath
	(tackon "SYS:" "FONTS")
     )
)
(complete 50)
;-> Ask
(copyfiles
	(prompt (cat "Installing now the necessary fonts to\n your SYS:FONTS (FONTS:) directory"))
	(help (cat "You need at least the QuakeManager.font in FONTS:!\n"
		   "If you allready have Xen.Font & Helvetica.Font installed\n"
		   "you can simply untag them!"))
	(source #fonts_from)
	(dest #fonts_to)
	(all)
	(confirm)
)
;-> Ask for QuakeDir
(set #qdir
     (expandpath
	(askdir
	   (default "SYS:")
	   (prompt (cat "Select now your Quake-Directory"))
	   (help (cat "Necessary! Please select a directory!"))
	   (disk)
	)
     )
)
(complete 60)
;-> Creating Script In QuakeDir:
(set #make_scriptdir (tackon #qdir "Scripts"))
(makedir #make_scriptdir
    (prompt (cat "Creating now the directory\n\n \"Scripts\"\n\n in your Quake-Directory!"))
    (help (cat "Please dont skip this"))
    (infos)
    (confirm)
)
;-> Put Assigns to user-startup
(set #add_assigns_to_file
     (expandpath
       (tackon "S:" "USER-STARTUP")
     )
)
(complete 70)
;-> Set StartUp Command
(set append_to_startup
    (cat "assign QManager: " #copyto "\n"
	 "assign QuakeDir: " #qdir   "\n")
)
;-> append assigns to user-startup
(startup "QuakeManager"
      (prompt (cat "Appending following to your USER-STARTUP\n\n"
		   append_to_startup "\n\n Please do not skip this part!"))

      (help (cat "DON'T SKIP THIS PART!"))
      (command append_to_startup)
      (confirm)
)
(set @default-dest #copyto)
;-> makeassigns
(makeassign "QManager" #copyto)
(makeassign "QuakeDir" #qdir)
;-> last message
(complete 99.99)
(message
    (cat "Installation successfully ended\n\n\nHave a nice day!\n\n"
	 "Come, frag some...\n\nhttp://www.goigoi.com/")
)
(message
    (cat "\n\nDon't forget to read\n\nSerial-ID.txt\n\n for the Serial-Number to be\n entered at first-startup of TAQM!\n")
)
(complete 100)