/* $VER: CfgFIDO.thor 1.4 (11.12.95)
 *
 * External configuration for the FIDO bbstype.
 *
 * Script by: Magne Østlyngen, Ultima Thule Software.
 */

parse arg argument
options results

template = 'BBSNAME/A,CONFNAME/K,PUBSCREEN/K'

p=address()||' '||show('P',,);if pos('THOR.',p)>0 then thorport=word(,
substr(p,pos('THOR.',p)),1);else do;say 'No THOR port found!';exit 10;end

if ~show('p', 'BBSREAD') then do
	address command
		"run >nil: `GetEnv THOR/THORPath`bin/LoadBBSRead"
		"WaitForPort BBSREAD"
end

address "BBSREAD"

READARGS template ARGS CMDLINE argument
if rc ~= 0 then do
	address(thorport)
	REQUESTNOTIFY TEXT '"'BBSREAD.LASTERROR'"' BT '"_Ok"'
	exit 5
end

GETBBSDATA bbsname '"'ARGS.BBSNAME'"' stem BBSDATA
if rc ~= 0 then do
	address(thorport)
	REQUESTNOTIFY TEXT '"'BBSREAD.LASTERROR'"' BT '"_Ok"'
	exit 5
end

address(thorport)

origin = ""
uucpaddr = ""
uucpname = ""
password = ""
forceintl = "NO"
packnetmail = "NO"
afname = ""
afpasswd = ""
showorigin = "NO"

if open(fil, BBSDATA.BBSPATH||'fido.config', R) then do
	do while ~eof(fil)
		ln = readln(fil)
		if upper(word(ln, 1)) = "ORIGIN:" then origin = strip(delstr(ln, 1, 7))
		if upper(word(ln, 1)) = "PASSWORD:" then password = strip(delstr(ln, 1, 9))
		if upper(word(ln, 1)) = "FORCEINTL:" then forceintl = strip(delstr(ln, 1, 10))
		if upper(word(ln, 1)) = "PACKNETMAIL:" then packnetmail = strip(delstr(ln, 1, 12))
		if upper(word(ln, 1)) = "UUCPADDRESS:" then uucpaddr = strip(delstr(ln, 1, 12))
		if upper(word(ln, 1)) = "UUCPNAME:" then uucpname = strip(delstr(ln, 1, 9))
		if upper(word(ln, 1)) = "AREAFIXNAME:" then afname = strip(delstr(ln, 1, 12))
		if upper(word(ln, 1)) = "AREAFIXPASSWORD:" then afpasswd = strip(delstr(ln, 1, 16))
		if upper(word(ln, 1)) = "SHOWORIGIN:" then showorigin = strip(delstr(ln, 1, 11))
	end
	call close(fil)
end

if forceintl ~= "YES" & forceintl ~= "NO" then do
	REQUESTNOTIFY TEXT '"Error in config: FORCEINTL neither YES nor NO.\n"' BT '"_Ok"'
end

REQUESTSTRING TITLE '"Enter Origin:"' BODY '"The origin line is on the format:\n\n ** Origin <text> (<address>)\n\nWhere <text> is this text, and <address> is your fido-address."' BT '"_Ok|_Abort"' ID '"'||origin||'"' MAXCHARS 256
if rc=30 then exit 10
if rc=0 then origin = result

REQUESTNOTIFY TEXT '"Show origin lines?\n\nIf you enable this option, origin lines are added to\nthe message body.  If this option is disabled, the\norigin lines are added to the comment-text."' BT '"_Yes|_No"'
if rc~=0 then exit 10
if result = 1 then showorigin = "YES"; else showorigin = "NO"

REQUESTSTRING TITLE '"Enter Password:"' BODY '"This is the password that is\nput into the reply-packets\n(NOT the password in areafix messages!)"' BT '"_Ok|_Abort"' ID '"'||password||'"' MAXCHARS 8
if rc=30 then exit 10
if rc=0 then password = result

REQUESTNOTIFY TEXT '"Force INTL lines?\n\nIf you experience problems with your netmail\nnot coming to the receiver, try setting \nthis to yes."' BT '"_Yes|_No"'
if rc~=0 then exit 10
if result = 1 then forceintl = "YES"; else forceintl = "NO"

REQUESTNOTIFY TEXT '"Pack netmail?\n\nShould messages written in NetMail.#? also be archived?"' BT '"_Yes|_No"'
if rc~=0 then exit 10
if result = 1 then packnetmail = "YES"; else packnetmail = "NO"

REQUESTSTRING TITLE '"Enter UUCP address:"' BODY '"This is the address of the gateway to send internet messages through"' BT '"_Ok|_Abort"' ID '"'||uucpaddr||'"' MAXCHARS 256
if rc=30 then exit 10
if rc=0 then uucpaddr = result

REQUESTSTRING TITLE '"Enter UUCP name:"' BODY '"This is the name of the UUCP gateway"' BT '"_Ok|_Abort"' ID '"'||uucpname||'"' MAXCHARS 256
if rc=30 then exit 10
if rc=0 then uucpname = result

REQUESTSTRING TITLE '"Enter areafix name:"' BODY '"This is the name of Areafix\nDefault is '||"'"||'areafix'||"'"||'"' BT '"_Ok|_Abort"' ID '"'||afname||'"' MAXCHARS 70
if rc=30 then exit 10
if rc=0 then afname = result

REQUESTSTRING TITLE '"Enter areafix password:"' BODY '"This is the password to put in areafix messages"' BT '"_Ok|_Abort"' ID '"'||afpasswd||'"' MAXCHARS 31
if rc=30 then exit 10
if rc=0 then afpasswd = result


if open(fil, BBSDATA.BBSPATH||'fido.config', W) then do
	if origin ~= "" then call writeln(fil, "ORIGIN: "||origin)
	if password ~= "" then call writeln(fil, "PASSWORD: "||password)
	if forceintl ~= "NO" then call writeln(fil, "FORCEINTL: "||forceintl)
	if showorigin ~= "NO" then call writeln(fil, "SHOWORIGIN: "||showorigin)
	if packnetmail ~= "NO" then call writeln(fil, "PACKNETMAIL: "||packnetmail)
	if uucpaddr ~= "" then call writeln(fil, "UUCPADDRESS: "||uucpaddr)
	if uucpname ~= "" then call writeln(fil, "UUCPNAME: "||uucpname)
	if afname ~= "" then call writeln(fil, "AREAFIXNAME: "||afname)
	if afpasswd ~= "" then call writeln(fil, "AREAFIXPASSWORD: "||afpasswd)
	call close(fil)
end

exit 0