;***********************
	;* BootBlock AntiVirus *
	;* gegen SCA und       *
	;* ByteBandit          *
	;* written 1988 by     *
	;* Garry Glendown      *
	;***********************	


	move.l	4,a6				; Standardvorbereitung
	lea.l	dosname(pc),a1			; vor dem Booten
	jsr	-96(a6)
	move.l	d0,a0
	tst.l	d0
	beq.L	err
	move.l	22(a0),a0
	movem.l	d0-d7/a0-a6,-(a7)		; Register retten

	move.w	#0,$dff180			; Bildschirm schwarz
	move.l	4,a6				; ExecBase
	move.l	46(a6),d0			; CoolCapture ?
	bne.s	scavir				; wird benutzt !
	move.w	148(a6),d0			; IntVek[5] = VBI Int.
	cmp.w	#$fc,d0				; auf Kickstartbereich ?
	bne.s	vir1				; nein
	move.l	550(a6),d0			; KickTagPtr ?
	beq.s	ende				; nicht benutzt !
	vir1:
	move.l	#0,550(a6)			; KickTagPtr löschen
	move.l	#0,554(a6)			; KickCheck löschen
	bra.s	l				; Bildschirm flimmern
	scavir:
	move.w	#$f00,$dff180			; Bildschirm rot
	move.l	$7ecc4,d0
	cmp.l	#$444f5300,d0			; noch aktiv ?
	bne.s	ende				; nein
	move.l	#$01020304,$7ecc4		; deaktivieren
	l:					; Bildschirm flimmern
	move.w	#$f0,$dff180
	btst	#6,$bfe001			; bis Maustaste
	beq.s	ende
	move.w	#$f,$dff180
	btst	#6,$bfe001
	bne.s	l
	
	ende:
	movem.l	(a7)+,d0-d7/a0-a6		; Register zurückholen
	clr.l	d0
	rts
	err:
	moveq	#-1,d0
	rts
	dosname:
		dc.b	'dos.library',0