; *****************
	; *  SearchVirus  *
	; * gegen SCA und *
	; *  Byte Bandit  *
	; * written 1988  *
	; * by G.Glendown *
	; *****************

	move.l	4,a6		;Execbase
	move.l	46(a6),d0	;CoolCapture ?
	bne.s	SCA		;wird benutzt!
	move.w	148(a6),d0	;VBI Int
	cmp.w	#$fc,d0		; auf Kickstartbereich ?
	bne.s	BB		;wird benutzt!
	move.l	550(a6),d0	;KickTagPtr ?
	bne.s	BB		;wird benutzt!

;Platz für Erweiterungen

	moveq	#0,d0		; Ende
	rts
SCA:
	move.l	#0,46(a6)	; Virus löschen
	lea	alsca,a5	; TextAdresse
	bra.s	Alert
BB:
	move.l	#0,550(a6)	; Virus
	move.l	#0,554(a6)	;   löschen
	lea	albb,a5
Alert:
	lea	intuiname,a1	; Intuition
	moveq	#0,d0
	jsr	-552(a6)	; öffnen
	move.l	d0,intuibase
	beq.s	nointui		; kein Intuition
	move.l	d0,a6
	moveq	#0,d0		; alerttype
	move.l	a5,a0		; Text
	moveq	#40,d1		; Höhe
	jsr	-90(a6)		; DisplayAlert
	move.l	4,a6
	move.l	intuibase,a1
	jsr	-414(a6)	; CloseLibrary
e:
	moveq	#0,d0
	rts
nointui:
	or.b	#2,$bfe001	; LED dunkel
	bra.s	e

intuibase:	dc.l	0
aladr:	dc.l	0
intuiname:	dc.b	"intuition.library",0
alsca:	dc.b	0,100,20,"Achtung! SCA Virus war vermutlich"
	dc.b	" im System!",0,0
albb:	dc.b	0,100,20,"Byte Bandit Virus war vermutlich"
	dc.b	" im System!",0,0