/* lFinger v3.00 - by Rick Taylor, 9-16-94  */
/* Script to make frequent fingering easier */

options results
call addlib("rexxreqtools.library",0,-30,0)
lf = '0a'x
cr = '0d'x
fonttag=""
whofin = ""
L = "|"
address command

/* Who are we gonna finger? */

everyone = envar('LFINGER')
parse var everyone b.1 a.1 b.2 a.2 b.3 a.3 b.4 a.4 b.5 a.5 b.6 a.6 . rest .
mfflag = 0
msg = "Who do you want to get finger information for?  Select a button"

/* Construct a button list for reqtools... */

buttonlist = b.1

do i = 2 to 6
     if ((b.i~="")&(a.i~="")) then buttonlist = buttonlist||L||b.i
     end

buttonlist = buttonlist||L||"Cancel!"

mfflag = rtezrequest(msg,buttonlist, "lFinger v3.00 - By Rick Taylor",fonttag)
if mfflag = 0 then exit
whofin = a.mfflag

msg = "***Finger info for "||whofin||"***"||lf
/* Launch the finger command */

'dnet:finger >t:finger_out' whofin

/* Process finger input to fit in a requestor */

call open .fin,'t:finger_out',read
beginline = readln(.fin)
currpos = seek(.fin,0,'C')
endfile = seek(.fin,0,'E')
startpos = seek(.fin,currpos,'B')

lcount = 0

do while (currpos < endfile)&(lcount < 13)
     restofmsg = readln(.fin)
     msg = msg||strip(left(restofmsg,80))||lf
     lcount = lcount +1
     currpos = seek(.fin,0,'C')
     end
call close .fin
'delete t:finger_out QUIET'
msg = msg||"***End of finger info for "||whofin||"***"

call rtezrequest msg,"_Ok","lFinger Information",fonttag

/* We're outta here */
exit

envar: procedure
     arg evname
     epath = "ENV:"||evname
     evalue = ""
     if exists(epath) then do
          call open .envar,epath,read
          evalue = readln(.envar)
          call close .envar
          end
     return evalue