/* Arexx-Script für MicroDot und MailFilter */

/*
** $VER: Userfilter.mdmrexx 1.7 (26.5.94)
**
** Übernimmt den Absender der aktuellen Mail in den Userfilter,
** im Usernamen vorkommende Jokerzeichen werden durch Voranstellen
** eines Hochkommas ausgeschaltet. Nach erfolgreicher Übernahme
** in den Filter öffnet sich das Fenster und der gerade übernommene
** Username ist selektiert.
**
** Userfilter.mdmrexx muß nach 'MicroDot/Rexx' kopiert werden
*/

/* Ergebnisse anfordern */

OPTIONS RESULTS



/* Name des Screens auslesen */

GETMDPUBSCREENNAME
screenname = result



/* Absender auslesen */

GETCURRENTMAILHEADER ABS

IF rc ~= 0 THEN EXIT

absender.pattern    = result
absender.emppattern = ''
absender.newsgroup  = ''
absender.mailtype   = ''
absender.action     = ''



/* Testen, ob MailFilter gestartet ist. Wenn nicht, dann jetzt starten */

IF ~SHOW(PORTS,'MAILFILTER') THEN DO
   ADDRESS COMMAND
   'run >NIL: <NIL: MAILFILTER:MailFilter'

   DO 3 WHILE ~SHOW(PORTS,'MAILFILTER')
      'WaitForPort MAILFILTER'
   END

   IF rc = 5 THEN DO
      SAY 'Kann MailFilter nicht starten!'
      EXIT
   END
END



/* Adresse in den Userfilter übernehmen und das */
/* Fenster auf dem aktuellen MicroDot-Screen öffnen */

ADDRESS MAILFILTER

DEACTIVATE
SETATTR screen screenname
ADDITEM TO user STEM absender CONVERT POPUP



/* Prefs speichern */

IF rc = 0 THEN
   SAVE



/* Beenden */

EXIT(0)