; VARARGS.A
		;
		; Assembler tags for 'varargs' style functions I need.
		;
		; Since	I'm using -mRR in DCC the standard amiga.lib isn't
		; brought in --	only the amigasr20.lib which was generated
		; from the fd's.

		section	text,code

		xref	_GadToolsBase
		xdef	_LayoutMenus
		xref	_LVOLayoutMenusA
		xdef	_GetVisualInfo
		xref	_LVOGetVisualInfoA
		xdef	_CreateMenus
		xref	_LVOCreateMenusA

_LayoutMenus:
		movem.l	a2/a6,-(sp)
		movem.l	12(sp),a0-a1
		lea	20(sp),a2
		move.l	_GadToolsBase(a4),a6
		jsr	_LVOLayoutMenusA(a6)
		movem.l	(sp)+,a2/a6
		rts
_GetVisualInfo:
		move.l	a6,-(sp)
		move.l	8(sp),a0
		lea	12(sp),a1
		move.l	_GadToolsBase(a4),a6
		jsr	_LVOGetVisualInfoA(a6)
		move.l	(sp)+,a6
		rts
_CreateMenus:
		move.l	a6,-(sp)
		move.l	8(sp),a0
		lea	12(sp),a1
		move.l	_GadToolsBase(a4),a6
		jsr	_LVOCreateMenusA(a6)
		move.l	(sp)+,a6
		rts


		xref	_DOSBase
;		xdef	_AllocDosObjectTags
;		xref	_LVOAllocDosObject
		xdef	_SystemTags
		xref	_LVOSystemTagList
		xdef	_Printf
		xref	_LVOVPrintf
		xdef	_FPrintf
		xref	_LVOVFPrintf

;_AllocDosObjectTags:
;		movem.l	d2/a6,-(sp)
;		move.l	12(sp),d1
;		lea	16(sp),a0
;		move.l	a0,d2
;		move.l	_DOSBase(a4),a6
;		jsr	_LVOAllocDosObject(a6)
;		movem.l	(sp)+,d2/a6
;		rts

_SystemTags:
		movem.l	d2/a6,-(sp)
		move.l	12(sp),d1
		lea	16(sp),a0
		move.l	a0,d2
		move.l	_DOSBase(a4),a6
		jsr	_LVOSystemTagList(a6)
		movem.l	(sp)+,d2/a6
		rts
_Printf:
		movem.l	d2/a6,-(sp)
		move.l	12(sp),d1
		lea	16(sp),a0
		move.l	a0,d2
		move.l	_DOSBase(a4),a6
		jsr	_LVOVPrintf(a6)
		movem.l	(sp)+,d2/a6
		rts
_FPrintf:
		movem.l	d2-d3/a6,-(sp)
		movem.l	16(sp),d1-d2
		lea	24(sp),a0
		move.l	a0,d3
		move.l	_DOSBase(a4),a6
		jsr	_LVOVFPrintf(a6)
		movem.l	(sp)+,d2-d3/a6
		rts


		xref	_AslBase
		xdef	_AllocAslRequestTags
		xref	_LVOAllocAslRequest
		xdef	_AslRequestTags
		xref	_LVOAslRequest

_AllocAslRequestTags:
		move.l	a6,-(sp)
		move.l	8(sp),d0
		lea	12(sp),a0
		move.l	_AslBase(a4),a6
		jsr	_LVOAllocAslRequest(a6)
		move.l	(sp)+,a6
		rts
_AslRequestTags:
		move.l	a6,-(sp)
		move.l	8(sp),a0
		lea	12(sp),a1
		move.l	_AslBase(a4),a6
		jsr	_LVOAslRequest(a6)
		move.l	(sp)+,a6
		rts


		xref	_IntuitionBase
		xdef	_OpenWindowTags
		xref	_LVOOpenWindowTagList

_OpenWindowTags:
		move.l	a6,-(sp)
		move.l	8(sp),a0
		lea	12(sp),a1
		move.l	_IntuitionBase(a4),a6
		jsr	_LVOOpenWindowTagList(a6)
		move.l	(sp)+,a6
		rts