.bra {
.ket }

FAILAT 50

IF EXISTS SYS:RAP!/Test
   TYPE "Anleit"
   ASK "Bitte <RETURN> drücken."
   SKIP End
ENDIF

Echo "*NDie Installation von *e[1mRAP!*e[0m läuft ...*N"

; Prefs Programm kopieren
Copy >NIL: Prefs/RAP!#?  SYS:Prefs/
IF WARN
  Echo "Fehler beim Kopieren von 'RAP!' nach 'SYS:Prefs/'!"
  Skip Error
ENDIF

; Libs kopieren
MakeDir >NIL: LIBS:Pack
Copy >NIL: Libs/Pack/#?  LIBS:Pack/
IF WARN
  Echo "Fehler beim Kopieren der Packer-Libraries!"
  Skip Error
ENDIF

MakeDir >NIL: LIBS:Crypt
Copy >NIL: Libs/Crypt/#?  LIBS:Crypt/
IF WARN
  Echo "Fehler beim Kopieren der Crypter-Libraries!"
  Skip Error
ENDIF

; Handler kopieren
Copy >NIL: L/RAP-Handler  L:
IF WARN
  Echo "Fehler beim Kopieren des 'RAP-Handlers' nach 'L:'!"
  Skip Error
ENDIF

; Get-Key kopieren
Copy >NIL: C/RAP-GetKey  C:
IF WARN
  Echo "Fehler beim Kopieren von 'RAP-GetKey' nach 'C:'!"
  Skip Error
ENDIF

; S:Startup-sequence ändern ?
":c/GASK" "*NRAP-Mount in die *e[1mStartup-Sequence*e[0m einsetzen (j/n) ?"
IF WARN
  :c/MSS TEXT "; RAP! starten*NC:RAP-Mount*N"
  IF WARN
    Echo "Fehler beim Ändern der 'Startup-Sequence'!"
    Skip Error
  ENDIF
  Copy >NIL: RAP-Mount#? C:
  IF WARN
    Echo "Fehler beim Kopieren von 'RAP-Mount' nach 'C:'!"
    Skip Error
  ENDIF
ELSE
  Version >NIL: exec.library 36
  IF WARN
    Echo "Sie müssen RAP-Mount nun immer selbst starten."
  ELSE
    ":c/GASK" "*NRAP-Mount in das Verzeichnis *e[1mWbstartup*e[0m kopieren (j/n) ?"
    IF WARN
      Copy RAP-Mount#? SYS:WBStartup/
    ELSE
      Echo "Sie müssen RAP-Mount nun immer selbst starten."
    ENDIF
  ENDIF  
ENDIF

Echo "*N*NDie Installation von *e[1mRAP!*e[0m ist beendet!"

Skip End

LAB Error
Echo "*N*NDie Installation von *e[1mRAP!*e[0m ist abgebrochen!"

LAB End
Wait 5
FAILAT 10