; $VER: startup-maprom 39.8 (5.8.92)

C:SetPatch QUIET

IF EXISTS C:MapROM
  C:MapROM DEVS:Kickstart
EndIF

C:Version >NIL:
C:AddBuffers >NIL: DF0: 15
FailAt 21

C:MakeDir RAM:T RAM:Clipboards RAM:ENV RAM:ENV/Sys
C:Copy >NIL: ENVARC: RAM:ENV ALL NOREQ

C:Assign >NIL: ENV: RAM:ENV
C:Assign >NIL: T: RAM:T
C:Assign >NIL: CLIPS: RAM:Clipboards
C:Assign >NIL: REXX: S:
C:Assign >NIL: PRINTERS: DEVS:Printers
C:Assign >NIL: KEYMAPS: DEVS:Keymaps
C:Assign >NIL: LOCALE: SYS:Locale
C:Assign >NIL: LIBS: SYS:Classes ADD
C:Assign >NIL: HELP: LOCALE:Help DEFER

IF NOT EXISTS SYS:Fonts
  C:Assign FONTS:
EndIF

BindDrivers
C:Mount >NIL: DEVS:DOSDrivers/~(#?.info)

Resident >NIL: C:Execute PURE

IF EXISTS DEVS:Monitors/VGAOnly
  DEVS:Monitors/VGAOnly
EndIF

IF EXISTS DEVS:Monitors
  C:List >NIL: DEVS:Monitors/~(#?.info|VGAOnly) TO T:M LFORMAT "DEVS:Monitors/%s"
  Execute T:M
  C:Delete >NIL: T:M
EndIF

SetEnv Workbench $Workbench
SetEnv Kickstart $Kickstart
UnSet Workbench
UnSet Kickstart

C:IPrefs

C:ConClip

Path >NIL: RAM: C: SYS:Utilities SYS:Rexxc SYS:System S: SYS:Prefs SYS:WBStartup SYS:Tools SYS:Tools/Commodities

IF EXISTS S:User-Startup
  Execute S:User-Startup
EndIF

Resident Execute REMOVE

C:LoadWB
EndCLI >NIL: