.k ""
.bra {
.ket }

; Install Script Copyright (C) Cloanto Italia 1992, 1993
; Cloanto, Personal Fonts Maker, PFM  (R), (TM) Cloanto Italia
; All Rights Reserved - Reproduction Prohibited

; We know some of you prefer other installers. But this one is
; truly multilingual, works with all operating systems and fits
; on the disk. If you have any suggestions, please let us know.

If NOT EXISTS RAM:IPT
  MakeDir RAM:IPT
  EndIf

If NOT EXISTS RAM:t
  MakeDir RAM:t
  EndIf

If EXISTS C:Copy
  Copy >NIL: C:Copy RAM:IPT
  EndIf

CD RAM:IPT

If EXISTS C:If
  Copy >NIL: C:If RAM:IPT
  EndIf
If EXISTS C:EndIf
  Copy >NIL: C:EndIf RAM:IPT
  EndIf
If EXISTS C:Execute
  Copy >NIL: C:Execute RAM:IPT
  EndIf
If EXISTS C:Assign
  Copy >NIL: C:Assign RAM:IPT
  EndIf

Assign >NIL: PFM:

Assign >NIL: PFM: EXISTS
If WARN
   Assign >NIL: " PFM:" EXISTS
   If NOT WARN
      Assign PFM: " PFM:"
      EndIf
   Assign >NIL: "Copy of PFM:" EXISTS
   If NOT WARN
      Assign PFM: "Copy of PFM:"
      EndIf
   Assign >NIL: Copy_of_PFM: EXISTS
   If NOT WARN
      Assign PFM: Copy_of_PFM:
      EndIf
   EndIf

Assign >NIL: PFM: EXISTS
If WARN
   Echo "Error: InstallPFM can only be run from *"PFM*" disk."
   Wait 3 SECS
   Skip End2
   EndIf

Copy PFM:c/Print RAM:IPT

If NOT EXISTS PFM:PFM_Prefs/PFM_Locale/PFM_InstallSub
  Print "Disk is not configured: default configuration in progress."
  Execute PFM:English
  CD RAM:IPT
  EndIf

If EXISTS PFM:PFM_Prefs/PFM_Locale/PFM_InstallSub
  Execute PFM:PFM_Prefs/PFM_Locale/PFM_InstallSub
  EndIf

If NOT EXISTS PLT_trlkll
  Print "Error during install."
  Wait 3 SECS
  Skip End2
  EndIf

If EXISTS C:CD
  Copy >NIL: C:CD RAM:IPT
  EndIf
If EXISTS C:Else
  Copy >NIL: C:Else RAM:IPT
  EndIf
If EXISTS C:Lab
  Copy >NIL: C:Lab RAM:IPT
  EndIf
If EXISTS C:Skip
  Copy >NIL: C:Skip RAM:IPT
  EndIf
If EXISTS C:Delete
  Copy >NIL: C:Delete RAM:IPT
  Copy >NIL: C:Delete RAM:t
  EndIf
If EXISTS C:MakeDir
  Copy >NIL: C:MakeDir RAM:IPT
  EndIf
If EXISTS C:Wait
  Copy >NIL: C:Wait RAM:IPT
  EndIf

Copy PFM:c/CAsk RAM:IPT
Copy PFM:c/CopyIcon RAM:IPT
Copy PFM:c/ShowPath RAM:IPT
Copy PFM:PFM_Tools/AskAssign RAM:IPT
Copy PFM:PFM_Icons/def_Drawer.info RAM:IPT CLONE QUIET

Print PLT_title

; PWrite, C1-Text, PPAINT trademarks of Cloanto Italia
; DPaintV, DPaintIV, DeluxePaintIII, ADPRO trademarks of respective owners

Assign >NIL: PWrite: EXISTS
If NOT WARN
  Assign INTELLASSIGN: PWrite:
  EndIf
Assign >NIL: C1-Text: EXISTS
If NOT WARN
  Assign INTELLASSIGN: C1-Text:
  EndIf
Assign >NIL: PPAINT: EXISTS
If NOT WARN
  Assign INTELLASSIGN: PPAINT:
  EndIf
Assign >NIL: ADPRO: EXISTS
If NOT WARN
  Assign INTELLASSIGN: ADPRO:
  EndIf
Assign >NIL: DeluxePaintIII: EXISTS
If NOT WARN
  Assign INTELLASSIGN: DeluxePaintIII:
  EndIf
Assign >NIL: DPaintIV: EXISTS
If NOT WARN
  Assign INTELLASSIGN: DPaintIV:
  EndIf
Assign >NIL: DPaintV: EXISTS
If NOT WARN
  Assign INTELLASSIGN: DPaintV:
  EndIf

Assign >NIL: INTELLASSIGN: EXISTS
If NOT WARN
  CD INTELLASSIGN:
  CD >NIL: /
  Assign INTELLASSIGN:
Else
  Assign >NIL: Work: EXISTS
  If NOT WARN
    CD Work:
  Else
    Assign >NIL: DH1: EXISTS
    If NOT WARN
      CD DH1:
    Else
      CD PFM:
    EndIf
  EndIf
EndIf

Execute RAM:IPT/PLC_ipath

If NOT WARN

 CD RAM:IPT

 Lab Questions

 Print >PFM_WriteOK ";"

 Print PLT_askpf1
 CAsk -y "*e[31m ?"
 If WARN
   Print >MEMO_DEFDIRS ";"
   Print >MEMO_PF1 ";"
 EndIf

 Print PLT_askpf2
 CAsk -y "*e[31m ?"
 If WARN
   Print >MEMO_DEFDIRS ";"
   Print >MEMO_PF2 ";"
 EndIf

 If EXISTS MEMO_DEFDIRS
   Print PLT_askfn1
   CAsk "*e[31m ?"
   If WARN
     Assign >NIL: FONTS: EXISTS
     If NOT WARN
       Print > MEMO_FF ";1"
     EndIf
   Else
     Print PLT_askfn2
     CAsk "*e[31m ?"
     If WARN
       CD IPFM:
       Execute RAM:IPT/PLC_fpath
       If NOT WARN
         CD RAM:IPT
         Print > MEMO_FF ";2"
       EndIf
       CD RAM:IPT
     EndIf
   EndIf
 EndIf

 Print ""
 Print PLT_askok
 CAsk -y "*e[31m ?"
 If NOT WARN
   Print PLT_title
   Print PLT_askrep
   CAsk -y "*e[31m ?"
   If WARN
     If EXISTS MEMO_DEFDIRS
       Delete MEMO_DEFDIRS QUIET
     EndIf
     If EXISTS MEMO_PF1
       Delete MEMO_PF1 QUIET
     EndIf
     If EXISTS MEMO_PF2
       Delete MEMO_PF2 QUIET
     EndIf
      If EXISTS MEMO_FF
       Delete MEMO_FF QUIET
     EndIf
     Print PLT_title
     Skip Questions BACK
   Else
     Skip End1
   EndIf
 EndIf

 Print PLT_title
 Print PLT_infbeg
 ShowPath -f IPFM:
 Print "*e[33m"

 If Exists MEMO_DEFDIRS

   Copy PFM:PFM.man IPFM: CLONE

   If NOT EXISTS IPFM:PFM_Tools
     MakeDir IPFM:PFM_Tools
   EndIf
   Copy PFM:PFM_Tools IPFM:PFM_Tools ALL CLONE QUIET

   If NOT EXISTS IPFM:PFM_Prefs
     MakeDir IPFM:PFM_Prefs
   EndIf

   Copy PFM:PFM_Prefs/II0 IPFM: ALL CLONE QUIET

   If Exists MEMO_PF2
     Print PLT_infpf2

     If NOT EXISTS IPFM:PFM_Icons
       MakeDir IPFM:PFM_Icons
     EndIf
     Copy PFM:PFM_Icons IPFM:PFM_Icons ALL CLONE QUIET

     If NOT EXISTS IPFM:Pictures
       MakeDir IPFM:Pictures
     EndIf
     Copy PFM:Pictures IPFM:Pictures ALL CLONE QUIET

     If NOT EXISTS IPFM:Brushes
       MakeDir IPFM:Brushes
     EndIf
     Copy PFM:Brushes IPFM:Brushes ALL CLONE QUIET

     If NOT EXISTS IPFM:Colors
       MakeDir IPFM:Colors
     EndIf
     Copy PFM:Colors IPFM:Colors ALL CLONE QUIET

     If NOT EXISTS IPFM:Stencils
       MakeDir IPFM:Stencils
     EndIf
     Copy PFM:Stencils IPFM:Stencils ALL CLONE QUIET

     If NOT EXISTS IPFM:fonts
       MakeDir > NIL: IPFM:fonts
     EndIf
     Copy PFM:fonts/Personal.font IPFM:fonts CLONE
     Copy PFM:fonts/Personal IPFM:fonts/Personal ALL CLONE QUIET
     Copy >NIL: PFM:fonts/Personal.font FONTS: CLONE
     Copy >NIL: PFM:fonts/Personal FONTS:Personal ALL CLONE QUIET

     Copy PFM:PFM_Prefs/UIText.#? IPFM:PFM_Prefs CLONE QUIET
     Copy PFM:PFM_Prefs/Startup_#? IPFM:PFM_Prefs CLONE QUIET
     Copy PFM:PFM_Prefs/UIColors.#? IPFM:PFM_Prefs CLONE QUIET

     Copy PFM:PFM_PS IPFM: CLONE QUIET
     Copy PFM:PFM2 IPFM: CLONE QUIET

     Copy PFM:PFM_Prefs/II2 IPFM: ALL CLONE QUIET

     Print "OK"

     If Exists MEMO_FF
       Print PLT_inffnt
       Assign >NIL: IFONTS: EXISTS
       If NOT WARN
         Copy PFM:fonts/Kara#? IFONTS: ALL CLONE QUIET
       Else
         Copy PFM:fonts/Kara#? FONTS: ALL CLONE QUIET
       EndIf
       Print "OK"
     EndIf

   EndIf

   Copy >NIL: PFM:CloantoAudio DEVS: CLONE

   If Exists MEMO_PF1
     Print PLT_infp11

     If NOT EXISTS IPFM:PFM_Fonts
       MakeDir IPFM:PFM_Fonts
     EndIf
     Copy PFM:PFM_Fonts IPFM:PFM_Fonts ALL CLONE QUIET

     If NOT EXISTS IPFM:PRT_Fonts
       MakeDir IPFM:PRT_Fonts
     EndIf
     Copy PFM:PRT_Fonts IPFM:PRT_Fonts ALL CLONE QUIET

     If NOT EXISTS IPFM:PFM_CharSets
       MakeDir IPFM:PFM_CharSets
     EndIf
     Copy PFM:PFM_CharSets IPFM:PFM_CharSets ALL CLONE QUIET

     If NOT EXISTS IPFM:PFM_Macros
       MakeDir IPFM:PFM_Macros
     EndIf
     Copy PFM:PFM_Macros IPFM:PFM_Macros ALL CLONE QUIET

     If NOT EXISTS IPFM:PDM_Defs
       MakeDir IPFM:PDM_Defs
     EndIf

     If NOT EXISTS IPFM:PFM_Brush
       MakeDir IPFM:PFM_Brush
     EndIf

     Copy PFM:PFM_Gfx IPFM: CLONE

     Copy PFM:PFM_Prefs/StartupF#? IPFM:PFM_Prefs ALL CLONE QUIET

     Copy PFM:PFM IPFM: CLONE QUIET

     MakeDir RAM:IPT/II1
     Copy PFM:PFM_Prefs/II1 RAM:IPT/II1 ALL CLONE QUIET
     Print "OK"

     Print PLT_infp12

     If Exists PFM_2:PFM
       Copy PFM_2:PFM IPFM: CLONE
     EndIf

     If Exists PFM_2:IPT/Lharc
       Copy PFM_2:IPT/Lharc RAM:IPT
       RAM:IPT/Lharc >NIL: -a -m -n e PFM_2:PFM_2.lzh IPFM:
       Delete >NIL: IPFM:Disk.info
       Print "OK"

       Print PLT_infp13
       RAM:IPT/Lharc >NIL: -a -m -n e PFM_2:PFM_3.lzh IPFM:
       Delete >NIL: IPFM:Disk.info

       Copy PFM_2:II0 IPFM: ALL CLONE QUIET
     Else
       Copy PFM_2:PDM_Defs IPFM:PDM_Defs ALL CLONE QUIET
       Copy PFM_2:PFM_CharSets IPFM:PFM_CharSets ALL CLONE QUIET
       Copy PFM_2:PFM_Macros IPFM:PFM_Macros ALL CLONE QUIET
       Copy PFM_2:PFM_Prefs IPFM:PFM_Prefs ALL CLONE QUIET
       Print "OK"

       Print PLT_infp13
       Copy PFM_3:PFM_Fonts IPFM:PFM_Fonts ALL CLONE QUIET
     EndIf

     Copy RAM:IPT/II1 IPFM: ALL CLONE QUIET
     Print "OK"

     If Exists MEMO_FF
       Print PLT_inffnt
       Assign >NIL: IFONTS: EXISTS
       If NOT WARN
         If Exists RAM:IPT/Lharc
           RAM:IPT/Lharc >NIL: -a -m -n e PFM_2:PFM_3F.lzh IFONTS:
         Else
           Copy PFM_3:fonts IFONTS: ALL CLONE QUIET
         EndIf
       Else
         If Exists RAM:IPT/Lharc
           RAM:IPT/Lharc >NIL: -a -m -n e PFM_2:PFM_3F.lzh FONTS:
         Else
           Copy PFM_3:fonts FONTS: ALL CLONE QUIET
         EndIf
       EndIf
       Print "OK"
     EndIf

   EndIf

 EndIf

 If Exists MEMO_PF1
   Print > MEMO_FF ";3"
 EndIf

 If EXISTS MEMO_FF
   Copy >NIL: PFM_WriteOK FONTS:
   If EXISTS FONTS:PFM_WriteOK
     Delete >NIL: FONTS:PFM_WriteOK
     If EXISTS SYS:System/FixFonts
       Print PLT_inffix
       SYS:System/FixFonts
       Print "OK"
     EndIf
   EndIf
 EndIf

 CopyIcon >NIL: def_Drawer IPFM: 1 1 572 182

 Wait 1 SECS

 Print PLT_title
 Print N "*e[31;1m"
 Print PLT_infend
 Print "*e[0m*N"
 Print PLT_trladd
 Print N "*N*e[33m          Assign PFM: "
 ShowPath IPFM:
 Print "*e[31m"
 Print PLT_trlfl1
 Print PLT_trlfl2

 Assign >NIL: S: EXISTS
 If NOT WARN
   Print ""
   Print PLT_askust
   CAsk -y "*e[31m ?"
   If WARN
     Copy >NIL: PFM_WriteOK S:
     If EXISTS S:PFM_WriteOK
       If NOT EXISTS S:user-startup
         Print >S:user-startup "; BEGIN Personal Fonts Maker"
       Else
         Print >>S:user-startup "*N; BEGIN Personal Fonts Maker"
       EndIf
       Print >>S:user-startup "Assign >NIL: PFM: EXISTS"
       Print >>S:user-startup N "If NOT WARN*N  Failat 21*N  EndIf*NAssign >NIL: PFM: "
       ShowPath >>S:user-startup IPFM:
       Print >>S:user-startup "; END Personal Fonts Maker"
       Delete >NIL: S:PFM_WriteOK
     EndIf
   EndIf
 EndIf

 Assign >NIL: IFONTS: EXISTS
 If NOT WARN
   Print ""
   Print PLT_trlfnt
   ShowPath IFONTS:
   Print "*e[31m"
 EndIf

 Lab End1

 Assign IPFM:
 Assign IFONTS:

 Wait 1 SECS
 Print ""
 Print PLT_askend
 CAsk ""

Else
 CD RAM:IPT
 Print N "*e[31;1m"
 Print PLT_trlkll
 Wait 3 SECS
EndIf

Lab End2
CD RAM:t
Delete > NIL: RAM:IPT ALL QUIET
Delete > NIL: Delete