;(c) Copyright 1995 HiSoft
;DiskMAGIC Installation script - R. Kiernan
;*catch any errors and pass dos errors to a message screen
;*if a dos problem occured
(onerror
(user 2)
(if (> @ioerr 0)
(Message ("\n\nA Dos Error %ld has occured" @ioerr)
"\n\n\n\nPlease consult Workbench manual"
" for further details."))
)
(set default-user @user-level)
;*set version - true if greater than version 37 (needed for the 2.0 editor)
(set WBVer (< 2424832 (getversion "exec.library" (resident))))
(if (or (= (getassign "sys") "RAM DISK:") (= (getassign "sys") "Ram Disk:"))
   (set default-media 0)
   (set default-media 1)
)

(PROCEDURE CHECKOS
(IF (= WBVER 0)
(
(MESSAGE "DiskMAGIC will not run on your Amiga as it requires Workbench 2.x or higher")
(EXIT)
)
)
)

(Procedure MAIN
(USER 2)
(SET DMDIR_DEST
(Askdir
(prompt "Select the location for the DiskMagic drawer")
(help @askdir-help)
(default @default-dest)
)
)

(USER default-user)


(if (= (substr DMDIR_DEST (- (strlen DMDIR_DEST) 1) ) ":")
(
(IF (<> (exists ("%sDiskMAGIC" DMDIR_DEST)) 2)
(
(Makedir ("%sDiskMAGIC" DMDIR_DEST) (infos))
(SET DMDIR_DEST ("%sDiskMAGIC" DMDIR_DEST))
)
(SET DMDIR_DEST ("%sDiskMAGIC" DMDIR_DEST))
)
)

( 

(IF (<> (exists ("%s/DiskMAGIC" DMDIR_DEST)) 2)
(
(Makedir ("%s/DiskMAGIC" DMDIR_DEST) (infos))
(SET DMDIR_DEST ("%s/DiskMAGIC" DMDIR_DEST))
)
(SET DMDIR_DEST ("%s/DiskMAGIC" DMDIR_DEST))
)

)
)


(debug DMDIR_DEST)
(copyfiles
(source "DiskMAGIC:")
(dest DMDIR_DEST)
(all)
)

(startup "DiskMAGIC"
(prompt "Add neccessary Assigns/paths to the user startup?")
(help @startup-help)
(command ("IF EXISTS \"%s/DiskMAGIC\"\n" DMDIR_DEST))
(command ("SETENV MTPATH=\"%s\"\n" DMDIR_DEST))
(command "ENDIF\n")
(command ("IF EXISTS \"%s/C/Lha\"\n" DMDIR_DEST))
(command ("ASSIGN C: \"%s/C\" ADD\n" DMDIR_DEST))
(command "ENDIF\n")
)

(run ("SETENV MTPATH=\"%s\"" DMDIR_DEST))
(run ("ASSIGN C: \"%s/C\" ADD" DMDIR_DEST))

(DELETE ("%s/Install-DiskMAGICHD" DMDIR_DEST))
(DELETE ("%s/Install-DiskMAGICHD.info" DMDIR_DEST))

(Working "Extracting archived files,\n\nplease wait...")
(run ("\"%s/C/Lha\" x %s/archives/#?.lha %s/" DMDIR_DEST DMDIR_DEST DMDIR_DEST))

)


(CHECKOS)
(MAIN)
(run ("run %s/more %s/ReadMe" DMDIR_DEST DMDIR_DEST))
(EXIT)