; Install script for BriefDeluxe2

(welcome "Willkommen bei der Installation von BriefDeluxe2")


(set @abort-button	  "Installation Abbrechen")
(set @askoptions-help "Wählen Sie aus den zu Auswahl stehenden Optionen die die Sie möchten.")
(set @askchoice-help  "Wählen Sie aus den zu Auswahl stehenden Möglichkeiten eine aus.")
(set @askbool-help    "Sie müssen sich entscheiden.")
(set @asknumber-help  "Sie müssen eine Zahl eingeben.")
(set @askstring-help  "Sie müssen eine Zeichenkette eingeben.")
(set @askdisk-help 	  "Sie müssen eine Diskette einlegen.")
(set @askdir-help 	  "Sie müssen ein Verzeichnis auswählen.")
(set @askfile-help 	  "Sie müssen eine Datei auswählen.")
(set @copylib-help	  "Es sollen ein oder mehrere Dateien kopiert werden. Vor dem Kopieren wird überprüft ob sich nicht schon eine neuere Version dieser Datei im Zielverzeichnis befindet. Ist dem so, wird die zu instalierende ältere Version nicht installiert.")
(set @copyfiles-help  "Es sollen ein oder mehrere Dateien kopiert werden." )
(set @makedir-help	  "Es soll ein neues Verzeichnis angelegt werden.")

(set @reqtools-help	  "Durch \"reqtools.library\" können bestimmte Funktionen des Programms komfortabeler bedienen.")
(set @reqtoolsprefs-help	"Mit dem Voreinsteller der \"reqtools.library\" können Sie das Erscheinungsbild und die Bedienung der, durch diese Bibliothek erzeugten, Dialogfenster (für Dateien, Schriften etc.) Ihren eigenen Bedürfnissen anpassen.")
(set @catalogs-help   "Kataloge ermöglichen unter Workbench 2.1 die Bedienung von bestimmten Programmen (z.B MUI-Voreinsteller) in deutscher Sprache.")

;=============================================================================

(set Kick (/ (getversion) 65536))

(complete 0)

(set @default-dest
	(askdir
		(prompt "In welches Verzeichnis soll \"BriefDeluxe2\" installiert werden ?")
        (help @askdir-help)
        (default "SYS:Utilities")
	)
)


(set wantinstall
	(askoptions
		(prompt  "Welche Dateien möchten Sie installieren ?")

		(choices "BriefDeluxe2 - Hauptprogramm"
				 "Beispiel-Dateien"
				 "Demonstrations Grafiken (Cliparts)"
				 "Musterbriefe"
		)

		(help @copyfiles-help)
	)
)


(if (IN wantinstall 0)
	(copyfiles
		(source "BriefDeluxe2")
		(dest (tackon @default-dest "BriefDeluxe2"))
		(prompt "Kopiere Hauptprogramm")
		(infos)
		(noposition)
		(help @copyfiles-help)
	)
)

(complete 10)

(if (IN wantinstall 1)
	(
	(makedir (tackon @default-dest "BriefDeluxe2/Demos"))

	(copyfiles
		(source "BD2-Daten:Demos")
		(dest (tackon @default-dest "BriefDeluxe2/Demos"))
		(all)
		(infos)
		(noposition)
		(help @copyfiles-help)
	)

	(copyfiles
		(source "BD2-Daten:Demo.ac")
		(dest (tackon @default-dest "BriefDeluxe2"))
		(infos)
		(noposition)
		(help @copyfiles-help)
	)
	)
)

(complete 20)

(if (IN wantinstall 2)
	(
	(makedir (tackon @default-dest "BriefDeluxe2/Grafiken"))

	(copyfiles
		(source "BD2-Daten:Grafiken")
		(dest (tackon @default-dest "BriefDeluxe2/Grafiken"))
		(all)
		(infos)
		(noposition)
		(help @copyfiles-help)
	)
	)
)

(complete 30)

(if (IN wantinstall 3)
	(
	(makedir (tackon @default-dest "BriefDeluxe2/Musterbriefe"))

	(copyfiles
		(source "BD2-Daten:Musterbriefe")
		(dest (tackon @default-dest "BriefDeluxe2/Musterbriefe"))
		(all)
		(infos)
		(noposition)
		(help @copyfiles-help)
	)
	)
)


(complete 40)

(copylib
	(prompt "Kopiere reqtools.library ...")
	(source "libs/reqtools.library")
	(dest "LIBS:")
	(confirm)
	(help @reqtools-help)
)

(complete 50)

(copylib
	(prompt "Installiere den ReqTools-Voreinsteller ...")
	(source "Prefs/ReqTools")
	(confirm)
	(infos)
	(noposition)
	(dest "SYS:Prefs")
	(optional nofail)
	(help @reqtoolsprefs-help)
)

(complete 75)

(set VersionASL (getversion "LIBS:asl.library"))
(set VersionASL (/ VersionASL 65536))

(if (< VersionASL 38)
	(
		(makedir "LOCALE:Catalogs/Deutsch"
		(prompt "Erzeuge Schublade \"LOCALE:Catalogs/Deutsch\""))

		(foreach "Catalogs/Deutsch" "#?.catalog"
			(copylib
				(prompt @each-name)
				(source (tackon "Catalogs/Deutsch" @each-name))
				(help @catalogs-help)
				(dest "LOCALE:Catalogs/Deutsch")
				(optional nofail)
				(nofail)
			)
		)
	)
)

(complete 100)

(startup "BriefDeluxe2"
	(prompt "Ergänze Ihre Datei \"S:User-Startup\".")
	(command "assign BD2-Daten: " (tackon @default-dest "BriefDeluxe2"))
	(help "Damit BriefDeluxe2 gewisse Dateien auch findet, muß Ihre Datei \"S:User-Startup\" ergänzt werden.")
)

(user 2)
(message "Bitte starten Sie jetzt Ihr System neu\num die Änderungen wirksam werden zu lassen.")