; Autotrader Installer script © by sLAC/dCN!

;$VER: Autotrader install v1.0 (7.5.95)

(welcome "    Welcome to the " @app-name " 1.0 demo version installation.\n")

(set need-version 36)

(complete 0)

 (set exec-version (/ (getversion) 65536))
 (transcript "Running on exec version " exec-version ".")
 (if (< exec-version need-version) ; check operating system version
     ((abort "The " @app-name " needs at least Exec version " need-version
        " to run.\nYou have only version " exec-version ". Please upgrade"
        " to use " @app-name " !")
 ))

(complete 2)

(set Trader-dest
 (tackon
  (askdir @default-dest
      (prompt "Where should I install the Trader program?\n"
              "(A directory named \"AutoTrader\" will be created)")
      (help @askdir-help)
      (default @default-dest)
  )
 "AutoTrader"
 )
)

(makedir Trader-dest (infos))

(set Trader-dest (expandpath Trader-dest))

(complete 5)

(copyfiles
  (prompt "Copying mainprogram files...")
  (source "Data/")
  (dest Trader-dest)
	(help @copyfiles-help)
  (pattern "#?")
  (infos)
  (confirm)
	(files)
)

(complete 50)

(set Doc-dest
  (askdir Trader-dest
      (prompt "Where should I install the Documentations?")
      (help @askdir-help)
      (default Trader-dest)
  )
)

(complete 55)

(copyfiles
  (prompt "Copying Docs...")
  (source "Data/Doc")
  (dest Doc-dest)
	(help @copyfiles-help)
  (pattern "#?")
  (infos)
  (confirm)
	(files)
)

(complete 70)

(set Script-dest
  (askdir Script-dest
      (prompt "Where should I install the Script for NComm?")
      (help @askdir-help)
      (default @default-dest)
  )
)

(complete 75)

(copyfiles
  (prompt "Copying NComm script...")
  (source "Data/Other/Trader.script")
  (dest Script-dest)
  (help @copyfiles-help)
  (infos)
  (confirm)
  (files)
)

(complete 80)

(copylib
	(prompt "Copying Reqtools library")
	(help @copylib-help)
	(source "Data/Other/reqtools.library")
	(dest "LIBS:")
  (confirm)
)

(complete 85)

(startup "AutoTrader"
 (prompt
  "The following instructions will added to your "
  "\"S:User-Startup\" so that your system will be properly "
  "configured to use AutoTrader.\n\n"
  "PATH \"" Trader-dest "\" Add\n"
  "Assign AT-DOC: \"" Doc-dest "\"\n")
  (help "This will add commands to your S:user-startup file to "
        "allow to correct operation of Autotrader")
  (command "PATH \"" Trader-dest "\" Add\n")
  (command "Assign AT-DOC: \"" Doc-dest "\"\n")
)

(makeassign "AT-DOC" Doc-dest)

(complete 100)

(set @default-dest Trader-dest)

(exit
 "I which you much fun!\n\n"
 "BUT DON`T FORGET: THIS PICE OF SOFTWARE IS SHAREWARE, SO REGISTER TO GET THE"
 " UNCRIPPELED VERSION!!"
)