key Ziel/A

;**********************************************
;*                                            *
;* Festplatten-Installation von MaxonPLP V2.0 *
;*                                            *
;* (c)1993 bei Peter Jack                     *
;*                                            *
;**********************************************

Echo "Diese Befehlsdatei installiert MaxonPLP V2.0 auf Ihre Festplatte"
Echo "Dafür müssen Sie von Ihrer Festplatte gebootet haben!*N"

ask "Wollen Sie MaxonPLP V2.0 auf Ihrer Festplatte installieren ? (Y/N)"

if WARN
 cd <Ziel>

 if EXISTS MaxonPLP
  Echo "Es existiert schon ein 'MaxonPLP'-Verzeichnis"
  ask "Soll das Verzeichnis gelöscht werden ? (Y/N)"
  if WARN
   delete MaxonPLP ALL QUIET
  ELSE
   ask "Soll das Verzeichnis in 'OldMaxonPLP' umbenannt werden ? (Y/N)"
   if WARN
    rename MaxonPLP OldMaxonPLP
    if EXISTS MaxonPLP.info
     rename MaxonPLP.info OldMaxonPLP.info
    endif     
   endif
  endif
 endif  

 if NOT EXISTS MaxonPLP
  Echo "Erzeuge Schublade 'MaxonPLP'"
  makedir MaxonPLP
 endif

 copy MaxonPLP_Disk2:info.MaxonPLP TO MaxonPLP.info QUIET CLONE

 Echo "Kopiere Dateien in Schublade 'MaxonPLP'"

 copy MaxonPLP_Disk1:PLP#? to MaxonPLP ALL QUIET CLONE 
 copy MaxonPLP_Disk2:PLP#? to MaxonPLP ALL QUIET CLONE 

 copy MaxonPLP_Disk2:PLP_Bibliotheken to MaxonPLP/PLP_Bibliotheken ALL QUIET CLONE 
 copy MaxonPLP_Disk2:PLP_Macros to MaxonPLP/PLP_Macros ALL QUIET CLONE 
 copy MaxonPLP_Disk2:PLP_Netzlisten to MaxonPLP/PLP_Netzlisten ALL QUIET CLONE 
 copy MaxonPLP_Disk2:PLP_Platinen to MaxonPLP/PLP_Platinen ALL QUIET CLONE 
 copy MaxonPLP_Disk2:PLPAusgabe_Treiber to MaxonPLP/PLPAusgabe_Treiber ALL QUIET CLONE 

 copy MaxonPLP_Disk2:HD-Data to MaxonPLP ALL QUIET CLONE

 ask "RCT.LIBRARY in LIBS:-Ordner kopieren ? (Y/N)"
 if WARN
  copy MaxonPLP_Disk1:libs/rct.library TO LIBS: QUIET CLONE
 endif

 Echo "*NNun fehlt noch ein assign auf das MaxonPLP-Verzeichnis"
 Echo "(Assign MaxonPLP: 'MaxonPLP-Verzeichniss')"

 cd MaxonPLP
 Echo >T:plp_a1 "*N;BEGIN MaxonPLP*Nassign MaxonPLP: " NOLINE
 cd >T:plp_a2
 Echo >T:plp_a3 ";END MaxonPLP*N"
 join T:plp_a1 T:plp_a2 T:plp_a3 AS T:plp_assign
 delete >nil: T:plp_a1
 delete >nil: T:plp_a2
 delete >nil: T:plp_a3

 if EXISTS S:User-Startup
  ask "Soll der Assign-Befehl an die User-Startup angehängt werden ? (Y/N)"
  if warn
   join S:User-Startup T:plp_assign AS T:User-Startup
   copy T:User-Startup S:User-Startup
   delete >nil: T:User-Startup
  else
   if EXISTS S:User-Startup
    ask "Soll der Assign-Befehl am Begin der Startup-Sequence eingefügt werden ? (Y/N)"
    if warn
     join T:plp_assign S:Startup-Sequence AS T:Startup-Sequence
     copy T:Startup-Sequence S:Startup-Sequence
     delete >nil: T:Startup-Sequence
    else
     Echo "Ok, Sie erzeugen den Assign selber*N"
    endif
   else
    Echo "Kann S:Startup-Sequence nicht finden ! Bitte erzeugen Sie den Assign selber*N"
   endif
  endif
 else
  if EXISTS S:User-Startup
   ask "Soll der Assign-Befehl am Begin der Startup-Sequence eingefügt werden ? (Y/N)"
   if warn
    join T:plp_assign S:Startup-Sequence AS T:Startup-Sequence
    copy T:Startup-Sequence S:Startup-Sequence
    delete >nil: T:Startup-Sequence
   else
    Echo "Ok, Sie erzeugen den Assign selber*N"
   endif
  else
   Echo "Kann S:Startup-Sequence nicht finden ! Bitte erzeugen Sie den Assign selber*N"
  endif
 endif

 delete >nil: T:plp_assign

 Echo "MaxonPLP V2.0 ist nun auf Ihrer Festplatte installiert"

 Wait 5 SECS
endif