;--------------------------- StartUp.SUB ----------------------------

sub StartUp

TextPalette 0,0,0,0 ; set all pens to black
TextPalette 1,0,0,0
TextPalette 2,0,0,0
TextPalette 3,0,0,0

scrollbar off ; also prevents front/back gadgets from being seen
menus off ; prevents right mouse button from switching to text screen

 $filename := "buttons.pic"
 load screen 2, $filename
 call LoadingError

 $filename := "scenes.pic"
 load screen 1, $filename
 call LoadingError

 $filename := "opening.snd"
 load sound 0, $filename
 call LoadingError

 $filename := "window.pic"
 load screen 0, $filename
 call LoadingError

 $filename := "artesian.font"
 load font 0, "artesian.font",8
 call LoadingError
 font 0,0 ; use font 0 on screen 0

 $filename := "ocean.snd"
 load sound 1, $filename
 call LoadingError

 $filename := "birds.snd"
 load sound 2, $filename
 call LoadingError

 color 0,blue
 $tx := "     Copyright @1991  by John Olsen"
 call print
 call BlankLine
 $tx := "            THE MAGIC POTION"
 call print
 $tx := "             by  John Olsen"
 call print
 call BlankLine

 click 0,270,10,283,22,GoNorth
 click 1,270,37,283,49,GoSouth
 click 2,285,24,298,36,GoEast
 click 3,255,24,268,36,GoWest
 click 4,302,3,315,15,GoUp
 click 5,302,45,315,57,GoDown
 click 6,255,68,315,80,Inv
 click 7,255,86,315,98,Get
 click 8,255,103,315,115,Help
 click 9,255,135,315,147,Load
 click 10,255,152,315,164,Save
 click 11,255,169,315,181,Quit

 placeobj 1nothing, thisroom
 grab 1nothing
 directions ByTree, w

 play sound 0, 0,1,64,0
 pause 50
 DOS "CloseScreen title.pic"

 show screen 0
 ScreenMode graphics

 create screen 24, 100, 100, 5, lores ; for overlays
 mask 24

endsub

;--------------------------------------------------------------------

sub StartUp2

 set ByTree, started
 set ByTree, visited
 $tx := "A glowing green scorpion stings you on"
 call print
 $tx := "the ankle, and then skitters off.  You"
 call print
 $tx := "hear it's tiny voice laughing, \34 Drink"
 call print
 $tx := "the magic potion before it's too late.\34"
 call print
 unload sound 0
 call MainLoop

endsub

;-------------------------------------------------------------------

sub LoadingError

if error > 0 then
 t \027[32m ; select pen 2
 TextPalette 2,15,15,15 ; set pen 2 to white
 t \f
 t
 t
 t
 t
 t
 t
 t
 t
 t
 t        ERROR: can't load file "@$filename "!  Press RETURN to abort.
 t \027[31m ; switch back to pen 1
 ScreenMode text
 getstring $temp
 quit
endif

endsub

;-------------------------------------------------------------------