opt	l-			;nicht linken!

* F2 Funktionstasten lesen und agieren 


	include  OpenDos.i

_LVOOpen        equ  -30
_LVOClose       equ  -36

        move.l  #name,d1		;Name von RAW:
        move.l  #1005,d2		;Status = gibt es
        jsr     _LVOOpen(a6)		;nun oeffnen
	move.l	d0,d5			;Handle merken
        tst.l   d0			;Fehler?
        beq     fini			;wenn ja, abbrechen

        lea.l   buffer,a3		;Adresse des Puffers

loop	jsr     GetKey			;Lese Taste
	cmp.b   #$9B,(a3)		;Funktionstaste?
        bne     loop			;wenn nicht
	jsr	GetKey			;sonst lese Code
 
        cmp.b   #$30,(a3)		;Taste F1 ?
	beq     F1 			;wenn ja
        cmp.b   #$31,(a3)		;      F2 ?
	beq     F2 			;wenn ja
        cmp.b   #$32,(a3)		;      F3 ?
	beq     F3 			;wenn ja
        cmp.b   #$33,(a3)		;Taste F4
	beq     F4			;wenn ja, fertig
	bra     loop

F1	lea.l    f1_text,a0     	;Adresse Text
        bsr      print			;drucken
        bra      loop			;auf ein Neues

F2	lea.l    f2_text,a0     	;Adresse Text
        bsr      print			;drucken
        bra      loop			;auf ein Neues

F3	lea.l    f3_text,a0     	;Adresse Text
        bsr      print			;drucken
        bra      loop			;auf ein Neues

F4	move.l	d5,d1			;RAW wieder schliessen
        jsr     _LVOClose(a6)

* Zum Schluss immer die Lib schliessen!
        move.l  a6,a1                   ;DOS-Lib-Basis
	move.l  _SysBase,a6		;Basis Exec
        jsr     _LVOCloseLibrary(a6)	;Funktion "Schliessen"

fini	rts				;Return zum CLI

GetKey  move.l  d5,d1			;von RAW lesen
        move.l  a3,d2			;in diesen Puffer
        move.l  #1,d3			;1 Zeichen
        jsr     _LVORead(a6)		;Lesen aufrufen
	rts

print	clr.l   d3
        move.b  (a0)+,d3		;Laenge
        move.l  d5,d1
        move.l  a0,d2
        jsr	_LVOWrite(a6)		;Funktion "Schreiben"
	rts

* Datenbereich:

dosname	 dc.b	'dos.library',0
	 cnop	0,2
name	 dc.b   'RAW:40/100/580/80/Stop mit F4',0
         cnop   0,2

f1_text	 dc.b	8,'Hier F1',10
	 cnop   0,2
f2_text	 dc.b	8,'Hier F2',10
	 cnop   0,2
f3_text	 dc.b	8,'Hier F3',10
	 cnop   0,2

buffer   ds.b   8
         cnop   0,4

hbuf     ds.b   10