' ***************************************
' * PSEUDO-PLASMA AMOS                  *
' *                                     *
' * CODAGE      Pierre Philippe Launay  *
' * GRAPHISME   Cathy Lardy             *
' * COPYRIGHT   © 04 avril 1984         *
' *                                     *
' * Cyclage des couleurs sur un dégradé *
' ***************************************
'
Dim COULEUR(16) : Rem Liste de 17x1 éléments 
Global COULEUR()
Proc CYCLAMEN
Procedure CYCLAMEN
   Rem Plan du programme
   Proc AERATION : Rem Monopolisation du système
   Proc BIFFURE : Rem Les yeux 
   Proc CORNE : Rem Le nez   
   Proc DEVOTION : Rem La bouche
   Proc EFFLORESCENCE : Rem Le chatoiement des couleurs
   Proc DISPLAY_ON : Rem L'image  
   Proc FACILE : Rem Le plasma
   Proc GLYPHE : Rem Sur AmigaNews, on se culture.
End Proc
Procedure AERATION
   Rem Je prépare l'Amiga 
   Screen Open 0,640,256,16,Hires : Rem Ouvre un écran 640x256 
   Wind Open 1,0,0,70,30,0 : Rem Et une fenêtre 
   Curs Off 
   Flash Off 
   Change Mouse 3 : Rem Le viseur
   Proc DISPLAY_OFF : Rem Déconnection de l'image  
   ' Hide                       : Rem Suppression de la souris
End Proc
Procedure BIFFURE
   Rem Je trace 
   For X=0 To 126
      Ink(X mod 14)+2 : Rem Changement de couleur
      Bar X,X To 640-X*2,256-X
   Next X
   Degree 
   For X=10 To 630 : Rem De haut en bas 
      Ink(X mod 14)+2 : Rem Changement de couleur
      Draw 640-X,120 To 640-X,256-X/5 : Rem Met une ligne
   Next X
Gr Writing 0
   For Y=1 To 100 : Rem De haut en bas 
      Ink(Y mod 14)+2 : Rem Changement de couleur
      Circle 320,120,Y : Rem To 320,256-Sin(Y)*100 : Rem Met une ligne
   Next Y
End Proc
Procedure CORNE
   Rem Je cercle
   Degree 
   For X=320 To 8 Step -1 : Rem Une corne de brume 
      Y=X mod 14 : Rem y ne dépassera pas 13
      Ink(14-Y)+1 : Rem Changement de couleur
      X1=(Cos(X)*120)+320
      Y1=(Sin(X)*50)+120
      Bar X1,Y1 To X1+X/8,Y1+X/8
   Next X
End Proc
Procedure DEVOTION
   Rem j'écris
   Gr Writing 0 : Rem Ne dessine que les lettres 
   Ink 0 : Rem Sélectionne la N° 1 de la palette
   Text 206,27," PLASMA AMOS Pierre Philippe Launay "
   Gr Writing 1 : Rem Dessine tout 
End Proc
Procedure DISPLAY_ON
   '   Screen Show 0
End Proc
Procedure DISPLAY_OFF
   '   Screen Hide 0
End Proc
Procedure EFFLORESCENCE
   Rem Je teint 
   Colour 0,$F0F : Rem La couleur des lettres N°0 sera rose 
   Colour 1,$0 : Rem La couleur du fond N°1 sera noire
   For X=3 To 15 : Rem Nos propres couleurs 
      TEINTE=TEINTE+$12 : Rem Seront jaune sombre à jaune vif
      COULEUR(X)=TEINTE : Rem Et seront stocké dans la liste appelé couleur
      Colour X,TEINTE : Rem Prise en compte de chaque nouvelle couleur 
   Next X
   COULEUR(2)=$F0F : Rem La couleur N°2 sera comme la couleur N°1 
End Proc
Procedure FACILE
   Rem Plasma 
   Repeat 
      Shift Down 0,2,15,1
      SON=((SON+12) mod 96)+1 : Rem+Rnd(6)*12
      Play 2,SON,2 : Rem Joue une note sur le canal 1 pendant 2 cycle 
   Until Mouse Key
End Proc
Procedure GLYPHE
   Rem Gravons nous la fin dans nos mémoires
   Show : Rem Lutin de nouveau visible 
   Wind Close : Rem Fermeture de la fenêtre
   Screen Close 0 : Rem Fermeture de l'écran 
   Edit 
End Proc