; Installationsskript für EasySpell1.0
; erstellt für Installer V1.24, 17.4.93, Autor: Andreas Regul

;   Copyright-Hinweise für Installer:

;     Installer and Installer project icon
;     (c) Copyright 1991-93 Commodore-Amiga, Inc.  All Rights Reserved.
;     Reproduced and distributed under license from Commodore.

;     INSTALLER SOFTWARE IS PROVIDED "AS-IS" AND SUBJECT TO CHANGE;
;     NO WARRANTIES ARE MADE.  ALL USE IS AT YOUR OWN RISK.  NO LIABILITY
;     OR RESPONSIBILITY IS ASSUMED.

(set @default-dest "SYS:")
(set @user-level 2)

(set @error-msg (cat "EasySpell wurde nicht komplett installiert. Bitte wiederholen Sie die Installation, "
                     "um eine lauffähige Version auf Ihrer Festplatte zu erhalten."))

(complete 0)

(welcome "Willkommen zur Festplatten-Installation von EasySpell.\n")

(set mydir
	      (askdir
            (prompt "Bitte wählen Sie das Laufwerk für EasySpell")
            (help "Für EasySpell wird ein eigenes Verzeichnis "
                  "auf der Festplatte benötigt. Um dieses Verzeichnis "
                  "anlegen zu können, müssen Sie hier die Festplatte "
                  "angeben, auf der installiert werden soll (z.B. Work:, DH0:, etc).\n"
            )
            (newpath)
            (default @default-dest)
            (disk)
	      )
)

(set @default-dest (tackon mydir "EasySpell"))
(set icondir (tackon @default-dest "Icons"))

(if (NOT (exists @default-dest))
         (makedir @default-dest
            (prompt "Das Verzeichnis \'" @default-dest "\' wird erzeugt.")
            (confirm)
            (help "Auf dem von Ihnen ausgewählten Laufwerk wird das Unterverzeichnis "
                  "für EasySpell angelegt. Sollten Sie doch einen anderen Pfad als "
                  "\'" @default-dest "\' verwenden wollen, können Sie das Installations- "
                  "programm an dieser Stelle abbrechen. Beim Neustart geben Sie dann den "
                  "von Ihnen gewünschten Pfad an.\n\n"
                  "Als Verzeichnisname wird jedoch in jedem Fall 'EasySpell' verwendet.\n")
            (infos)
         )
)

(complete 2)

(if (NOT (exists icondir))
         (makedir icondir
            (infos)
         )
)

(complete 4)

(message "Als nächstes werden die Programmdateien kopiert. Bitte \'Proceed\' anklicken, um fortzufahren.")

(set n 0)
(while (set thisfile (select n "EasySpell1.0:EasySpell" "EasySpell1.0:EasySpell.info" ""))
         ((set n (+ n 1))
            (copyfiles
               (prompt "Kopiere Datei \'"thisfile"\'")
               (help "")
               (source thisfile)
               (dest @default-dest)
               (optional force askuser)
            )
         )
)

(complete 15)

(set n 0)
(while (set thisfile (select n "EasySpell1.0:Icons/Drawer.info" "EasySpell1.0:Icons/Project.info"
                               "EasySpell1.0:Icons/SpellAppIcon.info" "EasySpell1.0:Icons/SpellAppIconBusy.info" ""))
         ((set n (+ n 1))
            (copyfiles
               (prompt "Kopiere Datei \'"thisfile"\'")
               (help "")
               (source thisfile)
               (dest icondir)
               (optional force askuser)
            )
         )
)

(complete 18)

(set osversion (/ (getversion) 65536))

(if (< osversion 36)
        (copyfiles
                (prompt "Kopiere Datei \'EasySpell.prefs\'")
                (help "")
                (source "EasySpell1.0:EasySpell.prefs")
                (dest @default-dest)
        )
        (if (exists "ENVARC:")
                (copyfiles
                        (prompt "Kopiere Datei \'EasySpell.prefs\'")
                        (help "")
                        (source "EasySpell1.0:EasySpell.prefs")
                        (dest "ENVARC:")
                )
                       (copyfiles
                               (prompt "Kopiere Datei \'EasySpell.prefs\'")
                               (help "")
                               (source "EasySpell1.0:EasySpell.prefs")
                               (dest @default-dest)
                       )
        )
)

(complete 20)

(askdisk 
        (dest "EasySpell")
        (prompt "Bitte legen Sie nun die Diskette \'EasySpell\' ein. Dies ist die zweite der beiden Disketten.\n")
        (help "Entfernen Sie die erste Diskette aus dem Laufwerk "
              "und legen Sie stattdessen die zweite Diskette ein.\n"
              "Wenn Sie mehr als ein Diskettenlaufwerk besitzen, "
              "können Sie die zweite Diskette in ein beliebiges "
              "anderes Laufwerk legen.\n")
)

(message "Jetzt wird das Wörterbuch kopiert. Bitte \'Proceed\' anklicken, um fortzufahren.")

(set n 0)
(while (set thisfile (select n "EasySpell:Dictionary.lex" "EasySpell:Dictionary.lex.info"
                               "EasySpell:Dictionary.tbl" "EasySpell:Dictionary.tbl.info"
                               "EasySpell:Dictionary.tre" "EasySpell:Dictionary.tre.info"
                               "EasySpell:Dictionary.ext" "EasySpell:Dictionary.ext.info"
                               "EasySpell:Dictionary.usr" "EasySpell:Dictionary.usr.info" ""))
      ((set n (+ n 1))
         (copyfiles
            (prompt "Kopiere Datei \'"thisfile"\'")
            (help "")
            (source thisfile)
            (dest @default-dest)
            (optional force askuser)
         )
      )
)

(complete 90)

(set assign (cat "Assign EASYSPELL: \"" @default-dest "\""))

(startup "EasySpell"
         (prompt "Es wird ein Assign in der user-startup benötigt. "
                 "Bitte \'Proceed\' anklicken, um hiermit fortzufahren.\n")
         (help "EasySpell wird über das logische Laufwerk \"EASYSPELL:\" "
               "angesprochen und benötigt deshalb einen Verweis auf "
               "das entsprechende Festplattenverzeichnis. Dieser Verweis "
               "wird beim Amiga in der Datei 'user-startup' durch einen "
               "Assign-Befehl hergestellt. Diese Installation fügt den "
               "benötigten Befehl selbständig ein.\n")
         (command assign)
)

(complete 100)