echo "*Ec*NInstalación del disco duro para Monkey2"
echo "    ©1992 LucasArts Entertainment Corporation"

FailAt 21
assign mic: "Monkey2 disk 1:c"

echo "*NAhora instalaremos los ficheros para hacer funcionar Monkey Island 2"
mic:ask "en su disco duro.  Es eso lo que quieres hacer? (Pulsa 'Y' para Sí)"
If NOT WARN
  echo "*N Abortando..."
  Skip Exit
EndIf

echo "*N Si estás jugando de un sistema de memoria de 1 MB, re-enciende cuando "
echo "hayas completado la instalación, para obtener más espacio libre de juego."
echo "*N Primero tenemos que saber donde instalar el programa.  Asegurate que "
echo "haya 9 MB de espacio libre en el disco que escojas. Escribe el nombre "
mic:echo "del disco y/o el directorio donde lo quieres instalar: " NOLINE

assign > NIL: MItmp: ?
assign > NIL: MItmp: exists
If WARN
  Skip usage
EndIf

cd MItmp:
mic:echo "*NSelecionaste el directorio: " NOLINE
cd
echo "*NPodemos crear una caja par los ficheros de Monkey Island 2, o ponerlos"
echo "directamente en el directorio.  Te gustaria poner todos los"
mic:ask "ficheros en el directorio selecionado? (y/N) "
If NOT WARN
  echo "*NEstamos creando un directorio llamado Monkey-Island2"
  Makedir > nil: Monkey-Island2
  If WARN
    echo "*NMonkey-Island2 ya existe, quieres cancelar "
    mic:ask "los ficheros viejos y continuar la instalación? (y/N)"
    If WARN
      echo "   Cancelando ficheros viejos..."
      delete > NIL: MItmp:Monkey-Island2/#? all
    Else
      mic:ask "    (Pulsa RETURN para abortar)"
      Skip exit
   EndIf
  EndIf
  copy mic:Monkey-Island2.info ""
  cd MItmp:Monkey-Island2
endIf

echo "Estamos copiando ficheros del disco 1"

copy "Monkey2 Disk 1:(Monkey2|Monkey2.info|Monkey2.000|Monkey2.001|Amiga1.ims)" ""

echo "Estamos copiando ficheros del disco 2"

copy "Monkey2 Disk 2:(Amiga2.ims|Monkey2.002)" ""

echo "Estamos copiando ficheros del disco 3"

copy "Monkey2 Disk 3:(Amiga3.ims|Monkey2.003)" ""

echo "Estamos copiando ficheros del disco 4"

copy "Monkey2 Disk 4:(Amiga4.ims|Monkey2.004)" ""

echo "Estamos copiando ficheros del disco 5"

copy "Monkey2 Disk 5:(Amiga5.ims|Monkey2.005)" ""

echo "Estamos copiando ficheros del disco 6"

copy "Monkey2 Disk 6:(Amiga6.ims|Monkey2.006)" ""

echo "Estamos copiando ficheros del disco 7"

copy "Monkey2 Disk 7:(Amiga7.ims|Monkey2.007)" ""

echo "Estamos copiando ficheros del disco 8"

copy "Monkey2 Disk 8:(Amiga8.ims|Monkey2.008)" ""

echo "Estamos copiando ficheros del disco 9"

copy "Monkey2 Disk 9:(Amiga9.ims|Monkey2.009)" ""

echo "Estamos copiando ficheros del disco 10"

copy "Monkey2 Disk 10:(Amiga10.ims|Monkey2.010)" ""

echo "Estamos copiando ficheros del disco 11"

copy "Monkey2 Disk 11:(Amiga11.ims|Monkey2.011)" ""

mic:ask "*NInstalación completada. (Pulsa RETURN para abortar)"
SKIP exit

LAB usage
echo "*NEse disco duro no es válido, revisa el nombre"
mic:ask " y corre la instalación otra vez...    (Pulsa RETURN para abortar)"

LAB exit
assign mic:
assign MItmp:
EndCLI > NIL: