;$VER: Cinema4D 2.1 (26.11.95)
;Cinema4D  Installation script - Richard
;*catch any errors and pass dos errors to a message screen
;*if a dos problem occured
(onerror

(set REMOVE_FILES
	(Askchoice
	(Help @askchoice-help)
	(Prompt "An error has occured or you have aborted the installation do you want to remove any installed files?")
	(Choices "Remove Installed files" "Do not remove files")
	(Default 0))
)

(IF (= REMOVE_FILES 0)
(
(IF (= (exists "C4D:C4DTEMP_TEMP") 2)
(run "ram:delete C4D:C4DTEMP_TEMP all force")
)

(IF (= (exists "C4D:Cinema4D") 2)
(run "ram:delete C4D:Cinema4D/#? all force")
)

(IF (= (exists "C4D:/C4DTEMP_TEMP") 2)
(run "ram:delete C4D:/C4DTEMP_TEMP all force")
)

(IF (= (exists "C4D:/Cinema4D") 2)
(run "ram:delete C4D:/Cinema4D/#? all force")
)
)
)

(DELETE "RAM:delete")
(IF (> @ioerr 0)
(Message ("\n\nA Dos Error %ld has occured" @ioerr)
"\n\n\n\nPlease consult your Workbench manual"
(" for further details, or type Fault %ld from a shell." @ioerr))
)
)
(SET DEFAULT-USER @user-level)
;*set version - true if greater than version 37
(SET WBVer (< 2424832 (getversion "exec.library" (resident))))

(user 2)

(set processor
(database "cpu")
)

(copyfiles
(source "C4D1:Delete")
(dest "RAM:")
(nogauge)
)


(SET C4D_DEST
(askdir
(prompt "Select the location for the Cinema4D Drawer")
(help @askdir-help)
(default @default-dest))
)

(MAKEASSIGN "C4D" C4D_DEST)

(IF (= (exists "C4D:Cinema4D") 2)
	(

	(set REMOVEOLD_FILES
		(Askchoice
		(Help @askchoice-help)
		(Prompt "A previous installation has been found. Do you want the installation to remove the files or install over the current files?")
		(Choices "Remove Installed files" "Install over current files")
		(Default 0))
	)

	(IF (= REMOVEOLD_FILES 0)
	(run "ram:delete C4D:Cinema4D all force")
	)

	)
)

(IF (<> (exists "C4D:C4DTEMP_TEMP") 2)
(MAKEDIR "C4D:C4DTEMP_TEMP")
)

(IF (<> (exists "ENVARC:Cinema") 2)
(MAKEDIR "ENVARC:Cinema")
)

(IF (= (Run "C4D1:CPU check 68881") 0)
;881
	(SET CPUTYPE 2)

	(

		(IF (OR (= processor "68020") (= processor "68030"))
			(SET CPUTYPE 1)
			(SET CPUTYPE 0)
		)

	)
)

(set APP_VER
	(Askchoice
	(Help @askchoice-help)
	(Prompt "Select the version to install?\n\nIf you are not sure select proceed!")
	(Choices "68000 (Unexpanded A500/A600 etc.)" "68020 (Unexpanded A1200/A4000-030 No FPU)" "68881 (A3000/A4000-040 or FPU expansion board)")
	(Default CPUTYPE))
)

(set VIDEO_LIB
	(Askchoice
	(Help @askchoice-help)
	(Prompt "If you have a video card, select,\nfrom the list,the library to install.")
	(Choices "No Video Card (Unexpanded Amiga)" "EGS" "Merlin" "Picasso" "Retina")
	(Default 0))
)



(SET n 1)

(while (< n 7)
	(

	(SET DISKNAME ("C4D%ld" n))

	(askdisk
	(Prompt ("\n\nPlease insert Cinema4D installation disk %ld in any drive" n))
	(help @askdisk-help)
	(DEST DISKNAME)
	)

	(copyfiles
	(source ("%s:" DISKNAME))
	(dest "C4D:C4DTEMP_TEMP")
	(all)
	)

	(SET n (+ n 1))

	)
)

(COMPLETE 1)

(Working "Joining common chunks...")
(Run "C4D:C4DTEMP_TEMP/Join C4D:C4DTEMP_TEMP/C4DChunkaa C4D:C4DTEMP_TEMP/C4DChunkab C4D:C4DTEMP_TEMP/C4DChunkac C4D:C4DTEMP_TEMP/C4DChunkad C4D:C4DTEMP_TEMP/C4DChunkae C4D:C4DTEMP_TEMP/C4DChunkaf AS C4D:C4DTEMP_TEMP/Cinema4D.lha")

(COMPLETE 5)

(Working "Joining localised chunks...")
(Run "C4D:C4DTEMP_TEMP/Join C4D:C4DTEMP_TEMP/C4DChunk-2aa C4D:C4DTEMP_TEMP/C4DChunk-2ab C4D:C4DTEMP_TEMP/C4DChunk-2ac AS C4D:C4DTEMP_TEMP/Cinema4D-2.lha")

(COMPLETE 10)

(run "C4D:C4DTEMP_TEMP/Delete C4D:C4DTEMP_TEMP/C4DChunk#?")
(DELETE "C4D:C4DTEMP_TEMP/CPU")
(DELETE "C4D:C4DTEMP_TEMP/Join")
(DELETE "C4D:C4DTEMP_TEMP/installer")
(DELETE "C4D:C4DTEMP_TEMP/Install-Cinema4D" (infos))

(SET COMMONSTRING "Extracting common archive...\n\n.")
(Working COMMONSTRING)

(SET COMPLETE_VALUE 10)

(COMPLETE COMPLETE_VALUE)

(Run "run C4D:C4DTEMP_TEMP/lhex -afFw=C4D: x C4D:C4DTEMP_TEMP/Cinema4D.lha *")

(set n 0)
(SET WORKING_STRING ".")
(While (SET FILETOTEST (select n "Fonts/Diamond/52" "Fonts/Helvetica/116" "Fonts/Helvetica/85" "Materials/Marble" "Scenes/ColourText" "Textures/Pine" "Tools/MagicLink-Lite" "Tools/Viewtek/VT_Retina.info" ""))

	(
	(until (= (exists ("C4D:Cinema4D/%s" FILETOTEST)) 1)
	(
	(run "C4D:C4DTEMP_TEMP/wait 5")
	)
	)

	(set n (+ n 1))
	(SET COMPLETE_VALUE (+ COMPLETE_VALUE 5))
	(COMPLETE COMPLETE_VALUE)
	(SET COMMONSTRING ("%s.." COMMONSTRING))
	(Working COMMONSTRING)
	)

)

(SET LOCALESTRING "Extracting localised archive...\n\n.")

(Working LOCALESTRING)

(Run "run C4D:C4DTEMP_TEMP/lhex -afFw=C4D: x C4D:C4DTEMP_TEMP/Cinema4D-2.lha *")

(set n 0)
(While (SET FILETOTEST (select n "Cinema4D.000.info" "Cinema4D.020.info" "Cinema4D.881.info" "Raytracer.000.info" "Raytracer.020.info" "Raytracer.881.info" "Scanline.000.info" "Scanline.020.info" "Scanline.881.info" ""))

	(
	(until (= (exists ("C4D:Cinema4D/%s" FILETOTEST)) 1)
	(
	(debug FILETOTEST)
	(run "C4D:C4DTEMP_TEMP/wait 5")
	)
	)

	(set n (+ n 1))
	(SET COMPLETE_VALUE (+ COMPLETE_VALUE 5))
	(COMPLETE COMPLETE_VALUE)
	(SET LOCALESTRING ("%s.." LOCALESTRING))
	(Working LOCALESTRING)
	)

)


(run "ram:delete C4D:C4DTEMP_TEMP/#?.lha")
(DELETE "C4D:C4DTEMP_TEMP/lhex")
(DELETE "C4D:C4DTEMP_TEMP/wait")
(run "ram:delete C4D:C4DTEMP_TEMP all")
 
(IF (OR (= (substr C4D_DEST (- (strlen C4D_DEST) 1) ) ":")
      (= (substr C4D_DEST (- (strlen C4D_DEST) 1) ) "/"))
(set C4D_DEST ("%sCinema4D" C4D_DEST))
(set C4D_DEST ("%s/Cinema4D" C4D_DEST))
)

(MAKEASSIGN "C4D" C4D_DEST)

(IF (= APP_VER 0)
(
(RENAME "C4D:Cinema4D.000" "C4D:Cinema4D") 
(RENAME "C4D:Cinema4D.000.info" "C4D:Cinema4D.info") 
(RENAME "C4D:RayTracer.000" "C4D:RayTracer") 
(RENAME "C4D:RayTracer.000.info" "C4D:RayTracer.info") 
(RENAME "C4D:Scanline.000" "C4D:Scanline") 
(RENAME "C4D:Scanline.000.info" "C4D:Scanline.info") 
)
)

(IF (= APP_VER 1)
(
(RENAME "C4D:Cinema4D.020" "C4D:Cinema4D") 
(RENAME "C4D:Cinema4D.020.info" "C4D:Cinema4D.info") 
(RENAME "C4D:RayTracer.020" "C4D:RayTracer") 
(RENAME "C4D:RayTracer.020.info" "C4D:RayTracer.info") 
(RENAME "C4D:Scanline.020" "C4D:Scanline") 
(RENAME "C4D:Scanline.020.info" "C4D:Scanline.info") 
)
)

(IF (= APP_VER 2)
(
(RENAME "C4D:Cinema4D.881" "C4D:Cinema4D") 
(RENAME "C4D:Cinema4D.881.info" "C4D:Cinema4D.info") 
(RENAME "C4D:RayTracer.881" "C4D:RayTracer") 
(RENAME "C4D:RayTracer.881.info" "C4D:RayTracer.info") 
(RENAME "C4D:Scanline.881" "C4D:Scanline") 
(RENAME "C4D:Scanline.881.info" "C4D:Scanline.info") 
)
)

(IF (<> (exists "Fonts:helvetica") 2)
(copyfiles
(source "C4D:Helvetica/")
(dest "Fonts:")
(all)
)
)

(run "ram:delete C4D:#?.000")
(run "ram:delete C4D:#?.020")
(run "ram:delete C4D:#?.881")
(run "ram:delete C4D:#?.000#?")
(run "ram:delete C4D:#?.020#?")
(run "ram:delete C4D:#?.881#?")
(run "ram:delete C4D:Helvetica#? all")

(IF (= VIDEO_LIB 1)
(copyfiles
(source "C4D:MonitorLibs/EGS/cinemaausgabe.library")
(dest "libs:")
)
)
(IF (= VIDEO_LIB 2)
(copyfiles
(source "C4D:MonitorLibs/Merlin/cinemaausgabe.library")
(dest "libs:")
)
)
(IF (= VIDEO_LIB 3)
(copyfiles
(source "C4D:MonitorLibs/Picasso/cinemaausgabe.library")
(dest "libs:")
)
)
(IF (= VIDEO_LIB 4)
(copyfiles
(source "C4D:MonitorLibs/Retina/cinemaausgabe.library")
(dest "libs:")
)
)

(run "ram:delete C4D:Monitor#? all")

(startup "Cinema4D"
(Prompt "Place Cinema4D assigns in the user-startup?")
(help @startup-help)
(Command
("Assign C4D: %s" C4D_DEST)
)
)

(DELETE "RAM:delete")

(COMPLETE 100)

(USER 2)
(Message "Cinema4D Installation complete."
"\nTo obtain your 30 days free technical support and notification of"
" Cinema4D updates, please complete your registration card and return"
" it to:-\n\n"
;* text starts at * and ends at *                   *
"            North America          Rest of world    \n"
"           Oregon Research            HiSoft        \n"
"     16200 S.W. Pacific Highway   The Old School    \n"
"             Suite 162              Greenfield      \n"
"               Tigard               Bedford, UK     \n"
"              OR 97224               MK45 5DE       \n"
"Phone:    +1 503 620 4919         +44 525 718181    \n"
" FAX:     +1 503 624 2940         +44 525 713716    \n")

(Message "Please remember, UK technical support is\n between 2-3p.m."
" Mon-Fri\nIf you need technical support, please remember to have when you"
" phone, your:-\nSerial Number\nSoftware version number\nMachine"
" configuration (RAM,Processor,Hard disk etc.)\n\n Please also have a"
" clear and concise description of the problem you are having to ensure"
" that we can deal with your problem as quickly as possible.\n\n"
" Select Proceed to quit to Workbench")

(IF (AND (= WBVer 1) (= (exists "SYS:Utilities/Multiview") 1))
   (Run "Run SYS:Utilities/Multiview C4D:ReadMe" (safe))
   (Run "Run more C4D:ReadMe" (safe))
)
(Exit (quiet))