; $VER: StarAm Plan Install Version 1.00 (04 Apr 94)
; Script zum Installieren von StarAm Plan
; 
;============================
;=== Deutsche Erklärungen ===
;============================
(set #introduction
(cat "\nMit diesem Installationsprogramm können Sie StarAm Plan "
       "installieren.\n\nVorhandene Dateien (außer StarAm Plan selbst) "
       "werden nur nach Nachfrage über bereits vorhandene kopiert.\n\n"
       "Im EXPERT-Mode erfolgt KEINE Sicherheitsabfrage!\n\n"
       "Drücken Sie \"Proceed\", um mit dem Installieren fortzufahren.\n\n"
       "Drücken Sie \"Abbruch\", um das Installieren abzubrechen."))
(set #Ja "Ja")
(set #Nein "Nein")
(set @askbool-help "Diese Frage sollten Sie normalerweise mit \"Nein\" beantworten!")
(set #TMP "RAM:SAP")

(set @abort-button "Abbruch")
(set @language "Deutsch")

(complete 0)

(message #introduction)
(welcome)

(set @default-dest
        (askdir
                (prompt "Geben Sie das Verzeichnis, in dem StarAm Plan installiert werden soll, an:")
                (help   @askdir-help)
                (default "WORK:")
        )
)

(complete 2)

(if (= @user-level 2)
    (set @Entpacken (askbool
                     (prompt "Soll das Programm entpackt werden?")
                     (help "Ohne geht's nicht!") (choices #Ja #Nein)
                     )
    )
)
(if (OR @Entpacken (< @user-level 2))
    (
    (working "Entpacke das Hauptprogramm...")
    (run ("Lha e sap.lha ram:"))
    )
)

(complete 14)

(if (= @user-level 2)
    (set @Mask (askoptions (prompt "Wählen Sie die zu kopierenden Dateien:")
                          (help "Diese Dateien sind das Hauptprogramm,\ndie Piktogramm-Daten und Voreinstellungen.\n \"SAP.s\" ist für AmigaOS 3.0 und\n \"SAP.s2.x\" für 2.x.\n Sie brauchen nur eine davon!")
                          (choices "StarAm Plan" "StarAm Plan020" "SAP.s" "SAP.s2.x" "SAP.fkt" "InfoData") ) ) )

(if (OR (IN @Mask 0) (< @user-level 2))
    (copyfiles
              (source "RAM:SAP/StarAm Plan")
              (dest @default-dest)
              (infos)
    )
)

(if (OR (IN @Mask 1) (< @user-level 2))
    (copyfiles
              (source "RAM:SAP/StarAm Plan020")
              (dest @default-dest)
              (infos)
    )
)
(complete 25)

(if (OR (IN @Mask 4) (< @user-level 2))
    (if (exists (tackon @default-dest "SAP.fkt") (noreq))
        (if (askbool (prompt "Sollen ihre benutzerdefinierten Funktionen überschrieben werden?")
                     (help @askbool-help)
                     (choices #Ja #Nein))
            (copyfiles (source "RAM:SAP/SAP.fkt") (dest @default-dest))
        )
        (copyfiles (source "RAM:SAP/SAP.fkt") (dest @default-dest))
    )
)

(complete 27)

(if (OR (IN @Mask 5) (< @user-level 2))
    (if (exists (tackon @default-dest "InfoData") (noreq))
        (if (askbool (prompt "Soll das Standard-Piktogramm überschrieben werden?")
                     (help @askbool-help)
                     (choices #Ja #Nein))
            (copyfiles (source "RAM:SAP/InfoData") (dest @default-dest))
        )
        (copyfiles (source "RAM:SAP/InfoData") (dest @default-dest))
    )
)

(complete 29)

(set @Ver (/ (getversion "exec.library" (resident)) 65536))

(if (< @user-level 2)
    (if (>= @Ver 39)
        (if (exists (tackon @default-dest "SAP.s") (noreq))
            (if (askbool (prompt "Sollen Ihre Voreinstellungen überschrieben werden?")
                         (help @askbool-help)
                         (choices #Ja #Nein))
                (copyfiles (source "RAM:SAP/SAP.s") (dest @default-dest) (infos))
            )
            (copyfiles (source "RAM:SAP/SAP.s") (dest @default-dest) (infos))
        )
        (if (exists (tackon @default-dest "SAP.s") (noreq))
            (if (askbool (prompt "Sollen Ihre Voreinstellungen überschrieben werden?")
                         (help @askbool-help)
                         (choices #Ja #Nein))
                (copyfiles (source "RAM:SAP/SAP.s2.x") (dest @default-dest) (newname "SAP.s") (infos))
            )
            (copyfiles (source "RAM:SAP/SAP.s2.x") (dest @default-dest) (newname "SAP.s") (infos))
        )
    )
    (
    (if (IN @Mask 2)
        (if (>= @Ver 39)
            (copyfiles (source "RAM:SAP/SAP.s") (dest @default-dest) (infos))
            (copyfiles (source "RAM:SAP/SAP.s") (dest @default-dest) (newname "SAP.s3.0") (infos))
        )
    )
    (if (IN @Mask 3)
        (if (>= @Ver 39)
            (copyfiles (source "RAM:SAP/SAP.s2.x") (dest @default-dest) (infos))
            (copyfiles (source "RAM:SAP/SAP.s2.x") (dest @default-dest) (newname "SAP.s") (infos))
        )
    )
    )
)

(complete 32)

(if (= @user-level 2)
    (copyfiles (prompt "Kopiere \"reqtools.library\" V38, © Nico François, nach \"LIBS:\"")
               (help "Ohne die reqtools.library V38 ist StarAm Plan nicht lauffähig!\nAchtung: KEINE Versions-Überprüfung!")
               (source "RAM:SAP/reqtools.library")
               (dest "LIBS:")
               (confirm))
    (copylib (prompt "Kopiere \"reqtools.library\", © Nico François, nach \"LIBS:\"")
             (help "Ohne die reqtools.library V38 ist StarAm Plan nicht lauffähig!")
             (source "RAM:SAP/reqtools.library")
             (dest "LIBS:"))
)

(complete 38)

(if (= @user-level 2)
    (set @Loeschen (askbool
                   (prompt "Sollen die temporären Dateien gelöscht werden?")
                   (help "Sehr zu empfehlen!") (choices #Ja #Nein)
                   )
    )
)
(if (OR @Loeschen (< @user-level 2))
    (foreach #TMP "#?" (delete (tackon #TMP @each-name)))
)

(complete 39)

(if (= @user-level 2)
    (set @Entpacken (askbool
                    (prompt "Soll die Dokumentation entpackt werden?")
                    (help "Nur wenn Sie keine Dokumentation brauchen, dürfen Sie \"Nein\" sagen!")
                    (choices #Ja #Nein)
                    )
    )
)
(if (OR @Entpacken (< @user-level 2))
    (
    (working "Entpacke die Dokumentation...")
    (run ("Lha e sapdoks.lha ram:"))
    )
)

(complete 56)

(copyfiles (prompt "Welche Teile der Dokumentation sollen kopiert werden?")
           (help "Bitte Lesen - Einige Vorinformationen, bekannte Fehler und Geschichte des Programms\n\nStarAm Plan.dok - Handbuch im ASCII-Format mit ANSI-Steuercodes\n\nStarAm Plan.guide - Handbuch als AmigaGuide\n\nStarAm Plan.dvi - Handbuch zum Ausdruck mit TeX\n\nDateien - Beispiele zu StarAm Plan")
           (source #TMP)
           (dest @default-dest)
           (choices "Bitte Lesen" "StarAm Plan.dok" "StarAm Plan.guide" "StarAm Plan.dvi" "Dateien")
           (infos)
           (confirm 1))

(complete 96)

(if (= @user-level 2)
    (set @Loeschen (askbool
                   (prompt "Sollen die temporären Dateien gelöscht werden?")
                   (help "Sehr zu empfehlen!") (choices #Ja #Nein)
                   )
    )
)
(if (OR @Loeschen (< @user-level 2))
    (
    (foreach #TMP "#?" (delete (tackon #TMP @each-name)))
    (foreach "RAM:SAP/Dateien" "#?" (delete (tackon "RAM:SAP/Dateien" @each-name)))
    (delete "RAM:SAP/Dateien")
    (delete "RAM:SAP.info")
    (delete #TMP)
    )
)

(complete 98)

(if (= (exists (tackon @default-dest "Dateien")) 0)
    (makedir (tackon @default-dest "Dateien")
             (prompt "Soll das Verzeichnis \"Dateien\" erzeugt werden?")
             (help "Dieses Verzeichnis verwendet StarAm Plan standardmäßig für die Daten")
             (infos)
             (confirm 2))
)

(complete 100)