; Installer script for the NetPC program

(welcome)

(if (= @user-level 0) 
  (abort "This script cannot be run in the Novice mode.")
)

(makedir "SYS:Storage"
   (infos)
)

(makedir "SYS:Storage/DosDrivers"
   (infos)
)

(makedir "SYS:NetworkPC"                     ;Begin Makedir
   (prompt "\n\n\n\nHit PROCEED to create SYS:NetworkPC\n\n(For Addtional Information on this step hit HELP.)")         ;
   (help "\n  Network PC relies on there being a Drawer called SYS:NetworkPC in order for it to install properly. This drawer must exist in order for the remainder of this script to function.")
   (infos)                       ;
   (confirm)                     ;
)                          ;End Makedir

(copyfiles                    
   (Prompt "For Additional Information on these files hit HELP.")              
   (source "NetworkPC:NetworkPC/")          
   (dest "SYS:NetworkPC/")             
   (files)                    
   (infos)                    
   (all)
)                          

(copyfiles
  (prompt "Copying Default Icon")
  (source "NetworkPC:Prefs/Env-Archive/Sys/def_pc.info")
  (dest "SYS:Prefs/Env-Archive/Sys/")
  (help "This is a default icon that is used by NetworkPC.")
)

(copyfiles
  (source "NetworkPC:Prefs/Env-Archive/Sys/def_pc.info")
  (dest "ENV:Sys/")
)

(copyfiles
  (source "NetworkPC:c/XIcon")
  (dest "c:")
)

(if (> (getversion (resident)) (* 39 65536))
  (
    (copyfiles
      (prompt "Copying mount receipt")
      (source "Storage/DOSDrivers")
      (all)
      (dest "Sys:Storage/DOSDrivers")
      (confirm)
      (help 
        "This will copy the device definition also containing configuration to a directory. "
        "If you copy it to the SYS:Storage/DOSDrivers directory, it will not be mounted automatically "
        "and you will have to use the \"mount PC\" command to run it.\nPlacing in the DEVS:DOSDrivers "
        "dir will mount it automatically after every startup. However, it is a good idea to not allow "
        "automatic loading of handler (by adding the \"ACTIVATE = 0\" toooltype) and setting the "
        "\"Activate\" entry in the file to 0. It can be also done by configuration program."
      )
    )
  )
  (
    (textfile
      (prompt "Program is to insert some lines at the beginning of your DEVS:Mountlist. If you have already installed PC2Am, remove the old specification after installing.")
      (dest "Devs:Mountlist")
      (include "Devs/PCEntry")
      (include "Devs:Mountlist")
      (confirm)
      (help "You have system V 2.0, that does not allow use of separate device definitions, so it is necessary to modify the DEVS:Mountlist file.")
    )
  )
)

(copylib
  (prompt "Copying igs.library")
  (source "NetworkPC:libs/igs.library")
  (dest "libs:")
  (help "\"igs.library\" is my own GUI support library, that is used by NetworkPC commodity. It must be installed.")
)


(copylib
  (prompt "Copying NetPcParallel.device")
  (source "NetworkPC:Devs/NetPcParallel.device")
  (dest "devs:")
  (help "\"NetPcParallel.device\" is used for parallel transfer with NetworkPC. You don't need it when you will use just transfer via serial port.")
)

(copyfiles
  (prompt "Copying Installer")
  (source "NetworkPC:c/Installer")
  (dest "c:")
  (help "\"Installer\" is required for the Configuration program.")
  (confirm)
)

(copyfiles 
  (prompt "Copying the handler.")
  (source "NetworkPC:L/netpc-handler")
  (dest "l:")
  (help "The filesystem. Must be installed.")
  (confirm)
)

(copyfiles 
  (prompt "Copying configuration script.")
  (source "ConfigNetworkPC")
  (dest "C:")
  (help "This is an Installer script for configuring Amiga side of NetworkPC.")
  (confirm)
)

(copyfiles 
  (prompt "Copying utility commands.")
  (source "C/")
  (all)
  (dest "C:")
  (help 
     "GetPCSpecs and SetPCSpecs are required by configuration program. You should"
     "copy them to 'C:'\n\n"
     "NetPCSpeed is an utility to approximately test speed of your connection. "
     "It will run test and tell you read and write speed. If you don't want to "
     "know the speed, you don't need this one."
  )
  (confirm)
)

(run ":c/Installer ConfigNetworkPC"
  (prompt "Do you want to run configuration script ?\n(Installer must be in the path)")
  (confirm)
  (help
    "If you confirm this requester, the configuration script will be run and "
    "you will be able to setup NetworkPC by an easy way."
  )
)

(exit
  "Installation of Amiga part done. Now ensure that you have installed the PC part.  This is described in the PC Installation part of NetPC.guide."
)