echo "*N CDTV-CR Final Test -- DEVELOPMENT COPY -- V0.1, 14-Apr-1992*N"

;----------------
; Initialization
;----------------

path sys:pa_c add

;-------------------------------------
; Flash-ROM Test, 
; verify checksum of correct firmware
;-------------------------------------

echo "*N Verifying ROM Firmware (V0.11)... *N"

failat 21
checksum f00000 f20000 7bc8a23b
if warn
   ask "*N Press ENTER or RETURN to Continue"
else
   wait 2
endif

;-------------------------------------
; AmigaDOS-ROM Test, 
; verify checksum of correct firmware
;-------------------------------------

echo "*N Verifying AmigaDOS 2.05 Kickstart ROM Firmware... *N"

failat 21
checksum f80000 fc0000 b2786c06
if warn
   ask "*N Press ENTER or RETURN to Continue"
else
   wait 2
endif

;----------------------
; Screen Display Tests
;----------------------

;skip keychk

echo "*N Loading NTSC Color Bars + Grey Scales + HALF-BRITE Display Mode Test...*N"
echo " 6 BIT Plane 640 x 200 x 64 colors"
echo " Press the RETURN or ENTER key to EXIT*N"

screentest

echo "*N Loading High Resolution + Interlaced Display Mode Test...*N"
echo " 4 BIT Plane 640 x 400 x 16 colors"
echo " Press Spacebar or ESCAPE to EXIT*N"

show df0:pics/hires.test

echo "*N Loading HOLD AND MODIFY Display Mode Test from Floppy...*N"
echo " 6 BIT Plane 320 x 200 x 4096 colors"
echo " Press Spacebar or ESCAPE to EXIT*N"

show df0:pics/balloon

lab fromcd
echo "*N Loading HOLD AND MODIFY Display Mode Test from CD-ROM...*N"
echo " 6 BIT Plane 352 x 200 x 4096 colors"
echo " Press Spacebar or ESCAPE to EXIT*N"

if exists cd0:bin/show
  CD0:BIN/SHOW  "CD0:SCANNED/LOBSTER.SHOW"
else
  cd0:show "cd0:scanned/lobster.show"
endif

;----------------------
; Keyboard Matrix Test
;----------------------

lab keychk
skip irchk

echo "*N Loading Keyboard Matrix Test...*N"
echo " Press highlighted keys in sequence as shown on the display screen"

keytest

;------------------------------------------
; Front Panel & IR Remote Controller Tests
;------------------------------------------

lab irchk
;skip cdtest

echo "*N Loading IR Remote Controller Test"
echo "*NPress remote controller keys as instructed...*N"

ircheck -quick
if warn
    ask  "*N Press ENTER or RETURN to Repeat the IR Test"
    skip irchk back
endif

lab fpchk

echo "*N Loading Front Panel Test"
echo "*NPress front panel controls as instructed...*N"

fpcheck -cdtvcr
if warn
    ask "*N Press ENTER or RETURN to Repeat the Front Panel Test"
    skip fpchk back
endif

;----------
; CDTVTEST
;----------

lab cdtest
skip atest

echo "*N Loading CDTVtest... "

cdtvtest <df0:pa_c/production.cdtv

ask "*N Press ENTER to Continue"

;--------------------------------------
; AmigaTest for CDTV with port dongles
;--------------------------------------

lab atest

echo "*N Loading Amigatest... "
echo "*n Test requires Serial & Parallel Port Dongles"

AMIGATEST 46abcf