/**
*** Assembly/Compilation macro, A68k style, this was made for A68k 2.42, don't
*** know what the newest version's like.
***
*** (c)John Harper 27-Jun-92
**/

Options Results

ErrorFlag = 0
Asm       = "A68k"

"GetVar(filename)"
CurrFile = result

"TypeFile(t:source.s)"
If(RC=0) Then
Do

	"DisplayLock(ON)SetTitle( Assembling...)"

	"Execute("Asm" >t:a68k.output t:source.s -ot:test.o)"

	If(Open("ERRORS","t:errors.jed","w")) Then
	Do
		If(Open("OUTPUT","t:a68k.output","r")) Then
		Do
			Do While ~EOF("OUTPUT")

				line = ReadLn("OUTPUT")
				Parse VAR line filename check linenum
				If(check = "line") Then
				Do
					ErrorFlag = 1
					If(filename = "t:source.s") Then filename = CurrFile

					Call ReadLn("OUTPUT")
					line = ReadLn("OUTPUT")
					descr = SubStr(line,Index(line,"^")+2)

					Call WriteLn("ERRORS","<<"filename">> <<"linenum">> <<"descr">>")
				End
			End
			Call Close("OUTPUT")
		End
	End
	Call Close("ERRORS")

	Address COMMAND "Delete t:source.s t:a68k.output"
	"RestoreTitle()"
	Call SetClip("JED.ERR",0)

	If(errorflag) Then "ExecRexxMacro(MoveError)"

	"DisplayLock(OFF)"
End