;
; Skrypt instalujācy Izviestiė #11 na dysku twardym
;
; Autor: LeMUr/blabla
;
; Bardzo pomocny byī skrypt instalujācy Konwersjė autorstwa Kamila Iskry.


(welcome)

(set ustawiony_poziom @user-level)


; Ustawmy na chwilė EXPERT
(user 2)

; Wybór katalogu do zainstalowania
(set katalogpom
	(askdir
		(prompt "Gdzie ma zostaź utworzony katalog \"Izviestia_11\"?")
		(help "W katalogu, który wybierzesz, zostanie utworzony podkatalog "
			"\"Izviestia_11\", do którego zostanie skopiowany magazyn.\n\n"
			@askdir-help
		)
		(default @default-dest)
	)
)


; Wprowadziīem pomocniczā zmiennā katalogpom, gdyū pojawiaīy siė problemy, gdy
; klikniėto "Abort Install" przy wyborze katalogu.
(set @default-dest katalogpom)


; Przywróźmy ustawiony poziom instalacji.
(user ustawiony_poziom)


; Sprawdzam czy istniejā odpowiednie pliki w katalogu aktualnym
; (pakiet instalowany z archiwum lub dyskietek)
(if (= (exists "Izviestia11.txt" (noreq)) 1)
   (
; jest - w katalogu
      (set adir "")
      (set bdir "")
   )
   (
; nie ma - na dyskach
      (set adir "IZV11_A:")
      (set bdir "IZV11_B:")
   )
)


; Skopiujmy ikonė katalogu
(copyfiles
	(source (tackon adir "Izviestia_11.info"))
	(dest @default-dest)
)


(set @default-dest (tackon @default-dest "Izviestia_11"))


; Proōba o potwierdzenie, utworzenie katalogu.
(makedir @default-dest
	(prompt ("Izviestia #11 zostanie zainstalowana w katalogu \"%s\""
		@default-dest)
   )
	(help @makedir-help)
	(confirm)
)


; Skopiujmy program gīówny...
; ...wersja 34/OCS
(set blad
	(trap 4 ; Trzeba wziāź pod uwagė, ūe tych plików moūe nie byź.
		(copyfiles
			(source (tackon adir "Izviestia11_34OCS.exe"))
			(dest @default-dest)
			(infos)
		)
	)
)
(if (> blad 0)
	(if (= @ioerr 205) ; Nie znaleziono pliku
		(message
			"Nie zostaī zainstalowany \"Program gīówny\", gdyū nie byīo "
			"go w katalogu śródīowym"
		)
		; inny bīād
		(abort "Bīād instalacji \"Programu gīównego\"!")
	)
)
; ...wersja 39/AGA
(set blad
	(trap 4 ; Trzeba wziāź pod uwagė, ūe tych plików moūe nie byź.
		(copyfiles
			(source (tackon adir "Izviestia11_39AGA.exe"))
			(dest @default-dest)
			(infos)
		)
	)
)
(if (> blad 0)
	(if (= @ioerr 205) ; Nie znaleziono pliku
		(message
			"Nie zostaī zainstalowany \"Program gīówny\", gdyū nie byīo "
			"go w katalogu śródīowym"
		)
		; inny bīād
		(abort "Bīād instalacji \"Programu gīównego\"!")
	)
)


; Skopiujmy biblioteki - jeōli trzeba (nie ma ich na LIBS:)
(copylib
	(source (tackon adir "Libs/reqtools.library"))
	(dest "LIBS:")
	(prompt "Zamierzam skopiowaź bibliotekė \"reqtools.library\"")
	(help @copylib-help)
	(confirm)
)
(copylib
	(source (tackon adir "Libs/xpkmaster.library"))
	(dest "LIBS:")
	(prompt "Zamierzam skopiowaź bibliotekė \"xpkmaster.library\"")
	(help @copylib-help)
	(confirm)
)
(copylib
	(source (tackon adir "Libs/xfdmaster.library"))
	(dest "LIBS:")
	(prompt "Zamierzam skopiowaź bibliotekė \"xfdmaster.library\"")
	(help @copylib-help)
	(confirm)
)
; Skopiujmy kompresory XPK
(copyfiles
	(source (tackon adir "Libs/compressors"))
	(dest "LIBS:compressors")
	(all)
)


; Skopiujmy czcionki
(copyfiles
	(source (tackon adir "Fonts"))
	(dest "FONTS:")
	(all)
)


; Skopiujmy pliki z danymi
(copyfiles
	(source (tackon adir "Izviestia11.sps"))
	(dest @default-dest)
)
(copyfiles
	(source (tackon adir "Izviestia11.gfx"))
	(dest @default-dest)
)
(copyfiles
	(source (tackon adir "Izviestia11.msx"))
	(dest @default-dest)
)
(copyfiles
	(source (tackon bdir "Izviestia11.txt"))
	(dest @default-dest)
)
(copyfiles
	(source (tackon bdir "Izviestia11.clp"))
	(dest @default-dest)
)