; Installation script for TurboPrint Professional 7
; (C) 1997,98 IrseeSoft
;
;
; $VER: TurboPrint Professional 7 (04.11.98) 
;
;
;   "Install TurboPrint"         operationMode = 0
;   "Update TurboPrint"          operationMode = 1
;   "Remove TurboPrint"          operationMode = 2
;   "Install on Disk"            operationMode = 3
;   "Query TurboPrint Version"   operationMode = 4
;

; String constants section. All messages and strings appear in this section
; for easier translation into foreign languages.

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; LANGUAGE SECTION
;

   (set #language "deutsch")
   (set #graphics-publisher "GrafikPublisher")
   (set #print-manager "DruckManager")
   (set #read-me "LiesMich")
;  (set #extra-personalization "personalisierung")

   (set #tp-version "TurboPrint Professional 7 (04.11.98) " )

   (set #wrongversion
      (cat "Achtung! Es ist eine alte Version des Programmes 'Installer' "
           "auf Ihrem Amiga!\n\nDie Installation benötigt mindestens Installer V43.3. "
           "Dieser befindet sich auf der Diskette.\n\n"
           "Falls Sie das Utility MCP installiert haben, müssen Sie den Installer von Diskette "
           "auf Ihren Amiga kopieren oder MCP abschalten."
      )
   )

   (set #introduction
      (cat "\nInstallation von TurboPrint Professional 7 \n"
             "        Cracked by LemArt 1998        \n\n"
           "Bitte wählen Sie:\n\n"
      )
   )

   (set #introduction-help
      (cat "Neu installieren von TurboPrint:\n"
           "Die TurboPrint Software wird auf Ihre Festplatte kopiert. "
           "Wählen Sie diese Option, falls noch keine ältere Version "
           "von TurboPrint auf Ihrer Festplatte installiert war.\n\n"
           "Update installieren:\n"
           "Eine bereits auf der Platte befindliche alte Version von "
           "TurboPrint wird durch TurboPrint Professional 7 ersetzt. "
           "Dazu werden nicht mehr benötigte Dateien der alten Version "
           "gelöscht.\n\n"
           "Entfernen von der Platte:\n"
           "Das TurboPrint Verzeichnis wird von der Platte gelöscht, "
           "Einträge in der user-startup und im WBStartup-Verzeichnis "
           "werden entfernt.\n\n"
           "Auf Diskette installieren:\n"
           "Es wird eine Diskette erstellt, von der Turboprint direkt "
           "gestartet werden kann. Bitte beachten Sie, daß bei der "
           "Diskettenversion der Druckerspooler nicht zur Verfügung "
           "steht!\n\n"
           "Version:\n"
           "Die Versionsnummern von Kickstart, Workbench und TurboPrint "
           "werden angezeigt.\n\n"
      )
   )

   (set #need-os2
      (cat "\nTurboPrint Professional 7 benötigt Kickstart 2.04 oder höher\n"
           "Um TurboPrint Professional 7 zu verwenden, müssen Sie Ihren "
           "Amiga auf Betriebssystem 2.04 (oder 3.1) umrüsten.\n"
           "Umrüstkits (Kickstart-ROM + Workbench-Disketten) "
           "sind im Fachhandel oder Versandhandel erhältlich.\n"
           "Als Übergangslösung empfehlen wir die Verwendung von "
           "TurboPrint 3.0.\n"
      )
   )

   (set #install "Neu installieren von TurboPrint")
   (set #update  "Update installieren")
   (set #remove  "Entfernen von der Platte")
   (set #instdisk "Auf Diskette installieren")
   (set #version "Versionsnummer anzeigen")

; additional help to the built-in one
   (set #generic-help
      (cat "Bitte lesen Sie auch die LiesMich-Datei auf dieser Diskette!\n"
      )
   )

   (set #path-prompt0 (cat "In welchem Verzeichnis soll das TurboPrint-Verzeichnis "
                          "erstellt werden?")
   )

   (set #path-prompt1 (cat "Wo befindet sich das TurboPrint-Verzeichnis, "
                          "in welches das Update installiert werden soll?")
   )

   (set #path-prompt2 (cat "Wo befindet sich das TurboPrint-Verzeichnis, "
                          "das entfernt werden soll?")
   )

   (set #askfordisk (cat "Bitte legen Sie eine leere Diskette ein, auf der "
                         "Turboprint installiert werden soll. Geben Sie an, "
                         "in welchem Laufwerk die Diskette eingelegt wurde.")
   )

   (set #format-disk (cat "Die Diskette wird nun formatiert. Eventuell darauf "
                         "vorhandene Daten werden unwiederbringlich gelöscht.\n\n"
                         "Sie werden eventuell aufgefordert die Workbench- "
                         "Diskette einzulegen. Legen Sie diese bitte in ein anderes "
                         "Laufwerk oder schreibgeschützt ein. Bei der folgenden "
                         "Meldung \"Diskette ist schreibgeschützt\" legen Sie "
                         "bitte wieder die leere Diskette ein. "
                     )
   )

   (set #formating-disk (cat "Die Diskette wird formatiert...")
   )

   (set #unpacking-files (cat "Die Turboprint-Dateien "
                         "werden entpackt...")
   )

   (set #disk-ready (cat "Die Turboprint-Diskette wurde fertiggestellt.")
   )

   (set #which-printer
      (cat "Bitte wählen Sie Ihren Drucker aus\n(oder wählen Sie"
           "'Hilfe', falls Ihr Drucker nicht aufgelistet ist)\n")
   )
   (set #help-printer
      (cat "Falls Ihr Drucker nicht namentlich aufgelistet ist, "
           "sehen Sie bitte in Ihrem Drucker-Handbuch nach, welche "
           "Emulationen Ihr Drucker unterstützt und wählen den "
           "entsprechenden TurboPrint-Treiber "
           "(z.B. Epson LQ850 -> Epson_LQ,SQxx50 in TurboPrint) "
           "oder wählen Sie einen der folgenden Einträge: \n"
           "'.24-Nadel', '.9-Nadel', '.Laser', "
           "'.Tinte-HP-kompatibel', '.Tinte-Epson-kompatibel'\n\n"
           "Sie können auch nach der Installation jederzeit weitere "
           "Treiber auswählen.\n\n" )
   )

   (set #another-printer
      (cat "Wollen Sie einen weiteren Drucker installieren?\n"
           "Bisher installierte Drucker:\n\n" )
   )

   (set #ask-priyes "Ja")
   (set #ask-prino "Nein")

   (set #remove-drivers
      (cat "\nSie haben 'TurboPrint von der Platte entfernen' gewählt.\n"
           "Dabei wird die TurboPrint-Schublade komplett von der Festplatte "
           "gelöscht. Bitte vergewissern Sie sich, ob sich darin noch "
           "von Ihnen benötigte Programme oder Dateien befinden!\n"
      )
   )

   (set #update-drivers
      (cat "\nBeim Update werden alle Dateien gelöscht, die "
           "sich momentan in den Verzeichnissen "
           "'Printers' und 'Turbo' innerhalb der TurboPrint "
           "Schublade befinden.\n"
           "z.B. auch alte Druckertreiber.\n" 
           "Falls Sie das nicht wollen, wählen Sie bitte "
           "'Installation abbrechen'."
      )
   )

   (set #removing-drivers
      (cat "\nTurboPrint wird von Ihrer Festplatte entfernt..."
      )
   )
   (set #removing-TurboPrefs
      (cat "Falls die startup-sequence/user-startup durch das TurboPrint "
           "Installationsprogramm geändert wurde, wird dies nun "
           "automatisch rückgängig gemacht."
      )
   )
   (set #adding-TurboPrefs
      (cat "Die user-startup Datei wird um den Befehl \n"
           "'Assign TurboPrint: <pfad>:TurboPrint' \n"
           "erweitert."
      )
   )

   (set #ask-wbstart20
    (cat "Sie können TurboPrint beim Rechnerstart automatisch installieren "
         "lassen. Dazu wird ein Startprogramm in die WBStartup-Schublade "
         "kopiert.\n"
         "Sie können den Autostart jederzeit wieder entfernen, indem Sie "
         "das Icon 'TurboStart' aus der WBStartup-Schublade herausnehmen.\n"
    )
   )
   (set #wbstart-help
    (cat "Autostart installieren:\n"
         "Beim Einschalten des Rechners oder nach einem Reset wird "
         "TurboPrint automatisch geladen. Dies ist sinnvoll, wenn "
         "Sie meistens TurboPrint-Treiber anstelle der Workbench-Druckertreiber "
         "verwenden wollen. Um wieder auf die Workbench-Treiber "
         "zurückzuschalten, verwenden Sie das Programm 'NoTurbo'.\n\n"
         "Kein Autostart:\n"
         "TurboPrint muß nach dem Einschalten mit Hilfe von TurboPrefs "
         "geladen werden. Diese Option ist sinnvoll, wenn Sie "
         "in der Regel mit den Workbench-Treibern arbeiten und nur "
         "bei Bedarf auf die TurboPrint-Treiber umschalten wollen.\n\n"
    )
   )

   (set #ask-wbyes "Autostart installieren" )

   (set #ask-wbno "Kein Autostart" )

   (set #ask-printmanager 
    (cat "Wollen Sie das Grafik Anzeige- und Druckprogramm "
         "Grafik-Publisher installieren?" 
    )
   )

   (set #ask-pmyes "Grafik-Publisher installieren" )

   (set #ask-pmno "Nicht installieren" )

   (set #ask-turbospool
    (cat "Wollen Sie den Druckerspooler automatisch "
         "beim Rechnerstart aktivieren?" 
    )
   )

   (set #ask-tsyes "Druckerspooler aktivieren" )

   (set #ask-tsno "Nicht aktivieren" )

   (set #ask-pictures 
    (cat "Wollen Sie die Demo-Bilder auf die Festplatte kopieren?" )
   )

   (set #ask-piyes "Bilder kopieren" )

   (set #ask-pino "Nicht kopieren" )

   (set #version-info "\nInformation über Ihr System:\n")
   (set #system-version-info "Kickstart %ld.%ld, Workbench %ld.%ld\n")


   (set #installation-done
      (cat "Die Installation von TurboPrint ist abgeschlossen.\n"
        "Entfernen Sie nun bitte Ihre TurboPrint-Diskette und Starten "
        "Sie Ihren Amiga neu."
        )
   )

;Strings for installation of GNU Ghostscript

   (set #ask-ghostscript
    (cat "Wollen Sie GNU Ghostscript installieren?" )
   )

   (set #ghostscript-help
    (cat "Mit GNU Ghostscript können Sie Postscript Dokumente drucken "
    "oder direkt aus Postscript-fähigen Programmen über den 'PS:' Handler "
    "ausdrucken.\n\n"
    )
   )

   (set #ask-gsyes "Ja, GNU Ghostscript installieren" )

   (set #ask-gsno "Nein, GNU Ghostscript nicht installieren" )

   (set #ask-gsdrawer
    (cat "Bitte wählen Sie, auf welcher Platte oder in welchem Verzeichnis Sie GNU Ghostscript installieren wollen. " 
         "Eine Schublade namens 'Ghostscript' wird automatisch angelegt. "
    )
   )

   (set #ask-gsdisk
    (cat "Bitte legen Sie die Diskette mit der Aufschrift 'GNU Ghostscript 4.03' in ein beliebiges Laufwerk." )
   )

   (set #adding-gsassign
      (cat "Die folgende Zeile wird zur Startup-Datei "
           "'s:user-startup' hinzugefügt: \n"
           "'Assign Ghostscript: <path>:Ghostscript'\n"
      )
   )

   (set #adding-pshandler
      (cat "Der 'PS:' Handler wird ins Verzeichnis 'Devs:DosDrivers' kopiert. "
           "Er ermöglicht, Postscript direkt aus Anwendungen zu drucken."
      )
   )


;Strings for installation of MWB Icons

   (set #ask-mwb
    (cat "Wollen Sie 16-Farb Icons für MagicWB installieren? "
         "(Vielen Dank an Mario Cattaneo, welcher die Icons gezeichnet hat!)" )
   )

   (set #mwb-help
    (cat "Die 16-Farb Icons machen die TurboPrint-Schublade und deren Inhalt farbenfroher, "
    "falls MagicWB installiert ist oder die entsprechende Farbpalette verwendet wird. "
    "Bei falscher Farbpalette sehen die Icons etwas merkwürdig aus.\n\n"
    )
   )

   (set #ask-mwbno "Nein, bitte die normalen Icons verwenden" )

   (set #ask-mwbyes "Ja, Icons für MagicWB installieren" )



; General initialisation of internal states, options and pre-defined
; variables go here.

(delopts askuser)

; Check whether this system is operating with at least Workbench 2.04 (V37).
; This is needed for the WBStartup feature and the Printmanager

(set kickVersion (shiftright (getversion) 16))

(set wbVersion (shiftright (getversion "LIBS:version.library") 16))

; set source directory

(set sourcedir (pathonly @icon))

;
(if (< kickVersion 37)
  (
   (message #need-os2)
   (exit (quiet))
  )
)
;

;Installer-Version prüfen...

(if (< @installer-version 2818051)
 (
  (user 2)
  (message #wrongversion)
  (exit (quiet))
 )
)

(welcome)

; remember current user level

(set old-level @user-level)

; Introduce ourself to the user. Query whether the software shall be
; installed/updated or removed altogether.

(set operationMode
   (askchoice
      (prompt #introduction)
      (choices #install #update #remove #instdisk #version)
      (help #generic-help #introduction-help @askchoice-help)
   )
)

; Install on Disk

(if (= operationMode 3)
   (
     ;Personalisierung

     ;(run (cat (tackon sourcedir #extra-personalization) " -q"))
        
     (set diskNumber
      (askchoice
       (prompt #askfordisk)
       (choices "DF0:" "DF1:" "DF2:" "DF3:" )
       (help #generic-help #introduction-help @askchoice-help)
      )
     )

     (message #format-disk)

     (set format-command (cat "sys:system/format drive df" diskNumber ": name TurboPrint ffs noicons"))
     (working (#formating-disk))
     (run format-command)

     (set lha-command (cat "\""  (tackon sourcedir "UNLZX") "\" x Turboprint7.lzx TurboPrint:"))
     (working (#unpacking-files))
     (run lha-command)

     ;copy turboprefs from disk to hd

     (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon sourcedir "Turboprefs"))
              (dest   "TurboPrint:")
     )

   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon sourcedir #read-me))
              (dest   "TurboPrint:")
              (infos)
   )
     
     (message #disk-ready)
     (exit (quiet))
   )
)

; Show version number

(if (= operationMode 4)
   (
   ; Find out the version of the Kickstart and Workbench and append it to the
   ; version information string.

   (set #version-info 
     (cat #version-info 
      (#system-version-info 

        (shiftright (getversion) 16)
        (bitand (getversion) 65535)
        (shiftright (getversion "LIBS:version.library") 16)
        (bitand (getversion "LIBS:version.library") 65535)
      )
     )
   )
     

   ; Get the version string from this installer script itself!

   (set #version-info (cat #version-info #tp-version))

   (message #version-info)
   (exit (quiet))
   )
)

; Get path of TurboPrint
; Set the prompt depending on operationMode

(if (= operationMode 0)

   (set #path-prompt #path-prompt0)
)

(if (= operationMode 1)

   (set #path-prompt #path-prompt1)
)

(if (= operationMode 2)

   (set #path-prompt #path-prompt2)
)


; ask for the destination directory

(if (not (exists "Work:"))
   (user 1)
)

(set target
   (askdir (prompt #path-prompt)
   (help #generic-help @askdir-help)
   (default "Work:") )
)

(user old-level)

; Update TurboPrint => remove contents of Printers and Turbo drawers

(if (= operationMode 1)
 (
; remove "Turboprint" from pathname if it is the last part

   (if (patmatch "turboprint" (fileonly target))
     (
      (set target (pathonly target))
     )
   )

   (message #update-drivers)
   
      (delete (tackon target (cat "TurboPrint/" #print-manager)))
      (delete (tackon target (cat "TurboPrint/" #print-manager ".info")))
      (delete (tackon target "TurboPrint/TurboPrefs"))
      (delete (tackon target "TurboPrint/TurboPrefs.info"))
      (delete (tackon target "TurboPrint/NoTurbo"))
      (delete (tackon target "TurboPrint/NoTurbo.info"))

      (delete (tackon target "TurboPrint/Printers") (all))
;;;      (delete (tackon target "TurboPrint/Configs") (all))
      (delete (tackon target "TurboPrint/Turbo") (all))
      (delete (tackon target "TurboPrint/Colors") (all))
      (delete (tackon target "TurboPrint/Drivers") (all))

      ;Delete the Turbospool icon from Turboprint and WBStartup
      ;- to make sure the stacksize is set correctly
      ;- to prevent automatic installation if user updates with different options

      (delete "sys:WBStartup/Turbospool.info" )
      (delete (tackon target "TurboPrint/TurboSpool.info"))
      (delete (tackon target "TurboPrint/TurboSpool"))
 )
)

; Remove TurboPrint => remove TurboPrint drawer completely

(if (= operationMode 2)
 (
   (message #remove-drivers)
   (working #removing-drivers)

   (run (cat (tackon target "Turboprint/NoTurbo") " -q"))

   (delete (tackon target "TurboPrint") (all) )

   ;Remove TurboStart in WBStartup

   (delete "sys:WBStartup/TurboStart.info")

   ;Remove TurboSpool in WBStartup

   (delete "sys:WBStartup/TurboSpool.info")

   ;Remove TurboPrefs in Prefs

   (delete "sys:Prefs/TurboPrefs.info")

   ;Inform user

   (startup "TurboPrint"
         (prompt #removing-TurboPrefs)
         (help #generic-help @startup-help)
   )
 )
)

;if install or update

(if (or (= operationMode 0) (= operationMode 1) )
  (

;delete tpspool.device if copied by user - it MUST NOT be in the devs drawer
   (delete (tackon target "devs:tpspool.device") (optional "force"))


;Personalisierung

   ;(run (cat (tackon sourcedir #extra-personalization) " -q"))
        

;Make TurboPrint drawer
   (makedir   (tackon target "TurboPrint") (infos))

;expand the whole Turboprint archive to the Turboprint drawer

   (set lha-command (cat "\""  (tackon sourcedir "UNLZX") "\" x Turboprint7.lzx \"" (tackon target "TurboPrint") "/\""))
   (run lha-command)

   (set lha-command (cat "\""  (tackon sourcedir "UNLZX") "\" x Turboprint7HD.lzx \"" (tackon target "TurboPrint") "/\""))
   (run lha-command)

   (run (cat (tackon target "Turboprint/NoTurbo") " -q"))

;Choose default printer(s)

(set printer-copy 1)

(user 1)

(while (= 1 printer-copy)
 (

  (set printer-name
   (askfile (prompt #which-printer)
   (help #help-printer @askfile-help)
   (default (tackon target "TurboPrint/Printers"))
   )
  )

  (if ( = (tackon target "TurboPrint/Printers") (pathonly printer-name) )
(
  (set printer-name (fileonly printer-name))

  (set printer-name (substr printer-name 0 ( - (strlen printer-name) 4) ))

  (copyfiles
   (help   #generic-help @copyfiles-help)
   (source (tackon target "Turboprint/Configs/_Dummy_"))
   (dest   (tackon target "TurboPrint/Configs" ))
   (newname (cat printer-name ".tpc") )
  )

  (set printer-list (cat printer-list printer-name "\n"))

  (set printer-copy (askbool (prompt (cat #another-printer printer-list) )
             (help @askchoice-help)
))
   )
  )

 )
)

(user old-level)

;user-startup
;the installer creates a user-startup if it doesn't already exist
;dont ask user

 ;Add assign to user-startup

      (startup "TurboPrint"
         (command 
            (cat "Assign TurboPrint: \"" (tackon target "TurboPrint") "\"")
         )
         (prompt #adding-tpassign)
         (help #generic-help @startup-help)
      )

;Execute assign NOW

(makeassign ("TurboPrint") (tackon target "TurboPrint") )


;install one of the two autostart options

   ;OS 2.x/3.0 => wbstartup drawer
   ;ask user if he/she wants to have the autostart option installed

(if (= 0 (askchoice (prompt #ask-wbstart20)
             (help #wbstart-help @askchoice-help)
             (choices #ask-wbyes #ask-wbno)
             (default 0)
       )    )
 (
 ;Copy TurboStart icon to WBStartup-drawer

   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon target "Turboprint/extra/TurboStart.info"))
              (dest   "sys:WBStartup" )
   )

   ;Put correct paths into TurboStart icon

   (tooltype
          (dest "sys:WBStartup/TurboStart")
          (setdefaulttool "TurboPrint:TurboPrefs" )
          (settooltype "QUICK" "")
          (settooltype "DONOTWAIT" "")
          (noposition)
   )

 )
)

;Put the Turbospool icon into the WBStartup-drawer if desired

(if (= 0 (askchoice (prompt #ask-turbospool)
             (help #wbstart-help @askchoice-help)
             (choices #ask-tsyes #ask-tsno)
             (default 0)
       )    )
 (
 ;Copy TurboStart icon to WBStartup-drawer

   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon target "Turboprint/extra/TurboSpool.info"))
              (dest   "sys:WBStartup" )
   )

   ;Put correct paths into TurboSpool icon

   (tooltype
          (dest "sys:WBStartup/TurboSpool")
          (setdefaulttool "TurboPrint:TurboSpool")
          (settooltype "DONOTWAIT" "")
          (noposition)
   )

 )
)

;install the necessary libraries

(copylib
      (source (tackon target "Turboprint/libs/multipic.library"))
      (dest   "LIBS:")
)

(copylib
      (source (tackon target "Turboprint/libs/wizard.library"))
      (dest   "LIBS:")
)

;Do the other stuff

 ;Copy TurboPrefs icon to sys:prefs

   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon target "Turboprint/extra/TurboStart.info"))
              (dest   "sys:Prefs" )
              (newname "TurboPrefs.info" )
   )

   ;Put correct paths into TurboStart icon

   (tooltype
          (dest "sys:Prefs/TurboPrefs")
          (setdefaulttool "TurboPrint:TurboPrefs" )
          (settooltype "(QUICK)" "" )
          (noposition)
   )

 ;make a copy of the GraphicsPublisher named Printmanager

   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon target (cat "Turboprint/" #graphics-publisher)))
              (dest   (tackon target "TurboPrint") )
              (newname #print-manager)
   )

 ;copy turboprefs from disk to hd

   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon sourcedir "TurboPrefs"))
              (dest   (tackon target "TurboPrint"))
   )

;  (copyfiles
;             (help   #generic-help @copyfiles-help)
;             (source (tackon sourcedir #extra-personalization))
;             (dest   (tackon target "TurboPrint/extra"))
;             (infos)
;  )

   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon sourcedir #read-me))
              (dest   (tackon target "TurboPrint"))
              (infos)
   )


   (if (exists (tackon "locale:catalogs" #language))
     (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon target "Turboprint/locale"))
              (dest   (tackon "locale:catalogs" #language) )
              (all)
     )
   )

   (delete (tackon target "TurboPrint/Configs/24-Pin.tpc") )

;Install MWB Icons if desired

(if (= 1 (askchoice (prompt #ask-mwb)
             (help #mwb-help @askchoice-help)
             (choices #ask-mwbno #ask-mwbyes)
             (default 0)
       )    )
 (
   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon target "TurboPrint/MWBIcons") )
              (dest   (target) )
              (infos)
              (all)
   )
 )
)

;Delete MWB Drawer

(delete (tackon target "TurboPrint/MWBIcons") (all))

;Install GNU Ghostscript if desired

(if (= 0 (askchoice (prompt #ask-ghostscript)
             (help #ghostscript-help @askchoice-help)
             (choices #ask-gsyes #ask-gsno)
             (default 0)
       )    )
 (
   ;Ask for the Ghostscript drawer

   (if (not (exists "Work:"))
      (user 1)
   )

   (set gstarget
      (askdir (prompt #ask-gspath)
         (help #generic-help @askdir-help)
         (default "Work:") 
      )
   )

   (user old-level)

   ;Unpack Ghostscript files from first installation disk

   (set lha-command (cat "\"" (tackon sourcedir "UNLZX") "\" x Turboprint7GS.lzx \"" (tackon gstarget "Ghostscript") "/\""))
   (run lha-command)

   ;Copy UNLZX to harddisk

   (copyfiles
              (help   #generic-help @copyfiles-help)
              (source (tackon sourcedir "UNLZX") )
              (dest   (tackon gstarget "Ghostscript") )
   )

   ;Prompt for second installation disk

   (askdisk 
     (prompt #ask-gsdisk)
     (help @askdisk-help)
     (dest "gnugs403")
     (assigns)
   )

   ;Unpack gnugs installation disk

   (set lha-command (cat "\"" (tackon gstarget "Ghostscript/UNLZX") 
                         "\" x gnugs403:gnugs403.lzx \"" (tackon gstarget "Ghostscript") "/\""
                    )
   )
   (run lha-command)

   ;Extract fonts

   (set t1-command (cat "\"" (tackon gstarget "Ghostscript/T1") 
                        "\" \"" (tackon gstarget "Ghostscript/fonts") "\""
                   )
   )
   (run t1-command)

   ;Make an assign to the ghostscript directory

   ;Add assign to user-startup

   (startup "GNU Ghostscript 4.03"
      (command 
         (cat "Assign Ghostscript: \"" (tackon gstarget "Ghostscript") "\"")
      )
      (prompt #adding-gsassign)
      (help #generic-help @startup-help)
   )

   ;Execute assign NOW

   (makeassign "Ghostscript" (tackon gstarget "Ghostscript") )

   ;Copy PS: handler to Devs:Dosdrivers

   (copyfiles
              (prompt #adding-pshandler)
              (help   #generic-help @copyfiles-help)
              (source (tackon gstarget "Ghostscript/l/PS") )
              (dest   "Devs:Dosdrivers" )
              (infos)
   )
 )
)


))
(user 1)
(message #installation-done)
(exit (quiet))