;$VER:jpeg.datatype Install 43.5

(set #dt-dir
	(askdir
		(prompt "Where do you store your datatypes ?")
		(help @askdir-help)
		(default "SYS:Classes/DataTypes")
	)
)

(set #dc-dir
	(askdir
		(prompt "Where do you store your descriptor files ?")
		(help @askdir-help)
		(default "DEVS:DataTypes")
	)
)

(set #prefs-dir
	(askdir
		(prompt "Where do you store your preferences for datatypes ?")
		(help @askdir-help)
		(default "SYS:Prefs/DataTypes")
	)
)

(if (exists "LIBS:powerpc.library" (noreq))
	(message "\
Note: Because of problems with the WarpOS-version \
of the jpeg.library, this version will not be \
installed, only 68k-version. WarpOS-version crashes \
badly, when IPrefs wants to open a jpeg image as \
backdrop pattern.\n\
If you want to install the WarpOS version anyway, \
please do this manually!")
)

(if (patmatch "(NOFPU)" (database "fpu"))
	(
		(if (patmatch "(68020|68030)" (database "cpu"))
			(set #jpegname "jpeg.library_020std")
		)
		(if (patmatch "(68040)" (database "cpu"))
			(set #jpegname "jpeg.library_040std")
		)
		(if (patmatch "(68060)" (database "cpu"))
			(set #jpegname "jpeg.library_060std")
		)
	)
	(
		(if (patmatch "(68020|68030)" (database "cpu"))
			(set #jpegname "jpeg.library_020881")
		)
		(if (patmatch "(68040)" (database "cpu"))
			(set #jpegname "jpeg.library_040881")
		)
		(if (patmatch "(68060)" (database "cpu"))
			(set #jpegname "jpeg.library_060881")
		)
	)
)

(set #rendername "render.library")
(if (not (patmatch "(68881|68882|FPU040)" (database "fpu")))
	(
	(if (patmatch "(68020|68030|68040)" (database "cpu"))
		(
		(set #rendername "render.library_68040")
		)
	)
	(if (patmatch "(68060)" (database "cpu"))
		(
		(set #rendername "render.library_68060")
		)
	)
	)
)

(copylib
	(prompt "jpeg.datatype")
	(help @copylib-help)
	(source "Classes/DataTypes/jpeg.datatype")
	(dest #dt-dir)
	(confirm)
)

(copylib
	(prompt "jpeg.library")
	(help @copylib-help)
	(source (tackon "Libs" #jpegname))
	(dest "LIBS:")
	(newname "jpeg.library")
	(confirm)
)

(copylib
	(prompt "render.library")
	(source (tackon "Libs" #rendername))
	(dest "LIBS:")
	(newname "render.library")
	(help @copylib-help)
	(confirm)
)

(copyfiles
	(source "Devs/DataTypes/JPEG")
	(dest #dc-dir)
)

(copyfiles
	(source "Env/DataTypes/jpeg.prefs")
	(dest "ENVARC:DataTypes")
)

(copyfiles
	(source "Env/DataTypes/jpeg.prefs")
	(dest "ENV:DataTypes")
)

(copyfiles
	(source "Prefs/JPEGPrefs")
	(dest #prefs-dir)
	(infos)
)