AC_PREREQ(2.14)dnl
AC_REVISION($Revision: 1.4 $)

SHTOOL="etc/shtool"
AC_SUBST(SHTOOL)
BOLD="`$SHTOOL echo -n -e %B`"
NORM="`$SHTOOL echo -n -e %b`"
VERS="`$SHTOOL version -l perl -d long smake_version.pl`"
echo "Configuring for ${BOLD}SMake${NORM}, Version ${BOLD}$VERS${NORM}"
echo "Copyright (c) 1994-1999 Ralf S. Engelschall, All Rights Reserved."
echo ""

AC_INIT(README)
AC_PREFIX_DEFAULT(/usr/local)

test "x$prefix" = xNONE && prefix=$ac_default_prefix
eval "dir=$prefix"
case $dir in
    *smake* ) libdirsub=""       ;;
          * ) libdirsub="/smake" ;;
esac
AC_SUBST(libdirsub)

AC_SET_MAKE

AC_MSG_CHECKING(for perl interpreter)
PERL=`$SHTOOL path -m perl`
AC_SUBST(PERL)
AC_MSG_RESULT($PERL)
if test ".$PERL" = .; then
    echo "$0:Error: no perl interpreter found" 1>&2
    exit 1
fi

AC_MSG_CHECKING(for pod2man conversion tool)
perldir=`$SHTOOL path -d $PERL`
POD2MAN=`$SHTOOL path -m -p "${perldir}:${PATH}" pod2man`
AC_SUBST(POD2MAN)
AC_MSG_RESULT($POD2MAN)
if test ".$POD2MAN" = .; then
    echo "$0:Error: no pod2man tool found" 1>&2
    exit 1
fi

AC_OUTPUT(dnl
Makefile dnl
)dnl