* This code shows how to set-up two boopsi gadgets (a Number gadget and a
 * Prop gadget). And how to use GetAttr() and SetGadgetAttrsA(). It also
 * shows how to set up IDCMP_IDCMPUPDATE.

	INCDIR	WORK:Include/

	INCLUDE	exec/exec_lib.i
	INCLUDE	exec/memory.i
	INCLUDE	intuition/intuition_lib.i
	INCLUDE	intuition/intuition.i
	INCLUDE	intuition/gadgetclass.i
	INCLUDE	intuition/icclass.i
	INCLUDE	graphics/graphics_lib.i
	INCLUDE	graphics/text.i
	INCLUDE dos/dos_lib.i
	INCLUDE dos/dos.i
	INCLUDE dos/dosextens.i
	INCLUDE workbench/workbench_lib.i
	INCLUDE	workbench/workbench.i
	INCLUDE	workbench/icon_lib.i
	INCLUDE	workbench/startup.i
	INCLUDE	utility/utility_lib.i
	INCLUDE	utility/utility.i
	INCLUDE	utility/tagitem.i

LIB_VER		EQU	39
TRUE		EQU	-1
FALSE		EQU	0

	lea	membuf(pc),a4

 * membuf (Memory Buffer) is set-up so that this code can be
 * position-independant. The memory buffer contains the following
 * addresses and their data:
 *
 *   0  Startup Return Message
 *   4  _DOSBase
 *   8  _IntuitionBase
 *  12 _IconBase
 *  16 Old Directory from CurrentDir()
 *  20 Disk Object from GetDiskObject()
 *  24 Argument addresses (30*4)
 * 144 ReadArgs() return value
 * 148 Task address
 * 152 _GfxBase
 * 156 Long Storage
 * 160
 * 164
 * 165
 * 166 Memory Buffer (12 bytes)
 * 178
 * 182 value 1 (for ToolType/CLI result)
 * 183 value 2 (for ToolType/CLI result)
 * 184 boopsi prop
 * 188 boopsi num0
 * 192 iclass
 * 196 icode
 * 198 iqualifier
 * 200 window
 * 204 window rastport
 * 208 screen rastport
 * 212 viewport
 * 216 iaddress
 * 220 mousex
 * 222 mousey
 * 224 _UtilityBase
 * 228 boopsi num1
 * 232

 * The Startup code below reads two CLI Arguments/WB ToolTypes as an example
 * of how to programme CLI Arguments/WB ToolTypes.
 *
 * Note: The CLI Arguments/WB ToolTypes are done after Startup and Library
 *       opening, so there is no use for the A0 pointer (which contains
 *       pr_CLI).

	suba.l	a1,a1
	move.l	4.w,a6
	jsr	_LVOFindTask(a6)
	tst.l	d0
	beq	exit
	move.l	d0,a5
	move.l	a5,148(a4)
	tst.l	pr_CLI(a5)		; Was this task started from CLI?
	bne.s	_main			; Yes.
	lea	pr_MsgPort(a5),a0	; No. From Workbench.
	jsr	_LVOWaitPort(a6)
	lea	pr_MsgPort(a5),a0
	jsr	_LVOGetMsg(a6)
	move.l	d0,(a4)			; D0 = A WBStartup Message.

_main
	moveq	#LIB_VER,d0
        lea     dos_name(pc),a1
	move.l	4.w,a6
        jsr	_LVOOpenLibrary(a6)
        move.l  d0,4(a4)
        beq     quit

        moveq	#LIB_VER,d0
        lea     int_name(pc),a1
        jsr	_LVOOpenLibrary(a6)
        move.l  d0,8(a4)
        beq     cl_dos

        moveq	#LIB_VER,d0
        lea     gfx_name(pc),a1
        jsr	_LVOOpenLibrary(a6)
        move.l  d0,152(a4)
        beq     cl_int

        moveq	#LIB_VER,d0
        lea     util_name(pc),a1
        jsr	_LVOOpenLibrary(a6)
        move.l  d0,224(a4)
        beq     cl_gfx

	moveq	#LIB_VER,d0
        lea     icon_name(pc),a1
        jsr	_LVOOpenLibrary(a6)
        move.l  d0,12(a4)
        beq     cl_util

 * Check the ToolTypes/CLI Arguments.

        move.l	(a4),a0
        tst.l   a0
        beq	fromcli
	move.l	sm_ArgList(a0),a5
        move.l  (a5),d1
	beq	zero_args
	move.l	4(a4),a6
	jsr	_LVOCurrentDir(a6)
        move.l  d0,16(a4)
        move.l	wa_Name(a5),a0
	move.l	12(a4),a6
	jsr	_LVOGetDiskObject(a6)
        move.l  d0,20(a4)
        beq     zero_args
        move.l	d0,a5
        move.l  do_ToolTypes(a5),a5

	move.l	a5,a0
        lea	ftstg0(pc),a1
        jsr	_LVOFindToolType(a6)
	tst.l	d0
        beq.s	tt1
	move.l	d0,a3
	move.l	a3,a0
	lea	mtstg0(pc),a1
	jsr	_LVOMatchToolValue(a6)
	tst.l	d0
	beq.s	tto1
	clr.b	182(a4)
	bra.s	tt1
tto1	move.l	a3,a0
	lea	mtstg1(pc),a1
	jsr	_LVOMatchToolValue(a6)
	tst.l	d0
	beq.s	tt1
	move.b	#1,182(a4)
tt1	move.l	a5,a0
        lea	ftstg1(pc),a1
        jsr	_LVOFindToolType(a6)
	tst.l	d0
        beq.s	tt2
	move.l	d0,a3
	move.l	a3,a0
	lea	mtstg2(pc),a1
	jsr	_LVOMatchToolValue(a6)
	tst.l	d0
	beq.s	tto2
	clr.b	183(a4)
	bra.s	tt2
tto2	move.l	a3,a0
	lea	mtstg3(pc),a1
	jsr	_LVOMatchToolValue(a6)
	tst.l	d0
	beq.s	tto3
	move.b	#1,183(a4)
	bra.s	tt2
tto3	move.l	a3,a0
	lea	mtstg4(pc),a1
	jsr	_LVOMatchToolValue(a6)
	tst.l	d0
	beq.s	tto4
	move.b	#2,183(a4)
	bra.s	tt2
tto4	move.l	a3,a0
	lea	mtstg5(pc),a1
	jsr	_LVOMatchToolValue(a6)
	tst.l	d0
	beq.s	tt2
	move.b	#3,183(a4)
tt2
	nop


free_diskobj
        move.l	20(a4),a0
        jsr	_LVOFreeDiskObject(a6)
	bra	zero_args

fromcli	lea	template(pc),a0
	move.l  a0,d1
        lea	24(a4),a5
        move.l  a5,d2
        moveq	#0,d3
	move.l	4(a4),a6
        jsr	_LVOReadArgs(a6)
        move.l  d0,144(a4)
        beq	zero_args

	move.l	(a5),a0
	lea	mtstg0(pc),a1
	bsr	cmpbyte
	tst.l	d0
	bne.s	cao1
	clr.b	182(a4)
	bra.s	ca1
cao1	move.l	(a5),a0
	lea	mtstg1(pc),a1
	bsr	cmpbyte
	tst.l	d0
	bne.s	ca1
	move.b	#1,182(a4)
ca1	move.l	4(a5),a0
	lea	mtstg2(pc),a1
	bsr	cmpbyte
	tst.l	d0
	bne.s	cao2
	clr.b	183(a4)
	bra.s	ca2
cao2	move.l	4(a5),a0
	lea	mtstg3(pc),a1
	bsr	cmpbyte
	tst.l	d0
	bne.s	cao3
	move.b	#1,183(a4)
	bra.s	ca2
cao3	move.l	4(a5),a0
	lea	mtstg4(pc),a1
	bsr	cmpbyte
	tst.l	d0
	bne.s	cao4
	move.b	#2,183(a4)
	bra.s	ca2
cao4	move.l	4(a5),a0
	lea	mtstg5(pc),a1
	bsr	cmpbyte
	tst.l	d0
	bne.s	ca2
	move.b	#3,183(a4)
ca2
	nop


free_cliargs
        move.l	144(a4),d1
        jsr	_LVOFreeArgs(a6)

zero_args

	suba.l	a0,a0
	move.l	8(a4),a6
	jsr	_LVOLockPubScreen(a6)
	move.l	d0,200(a4)
	move.l	d0,wndwscrn
	beq	cl_icon

	suba.l	a0,a0
	move.l	200(a4),a1
	jsr	_LVOUnlockPubScreen(a6)

	suba.l	a0,a0
	lea	wndwtags(pc),a1
	jsr	_LVOOpenWindowTagList(a6)
	move.l	d0,200(a4)
	beq	cl_icon

	move.l	d0,a0
	move.l	wd_RPort(a0),204(a4)

	move.l	wndwscrn(pc),a0
	lea	sc_RastPort(a0),a1
	move.l	a1,208(a4)
	lea	sc_ViewPort(a0),a2
	move.l	a2,212(a4)

	suba.l	a0,a0
	lea	prop_stg(pc),a1
	lea	prop_tags(pc),a2
	move.l	8(a4),a6
	jsr	_LVONewObjectA(a6)
	move.l	d0,184(a4)
	beq	cl_wndw
	move.l	d0,prop0
	move.l	d0,prop1

	suba.l	a0,a0
	lea	number_stg(pc),a1
	lea	number_tags(pc),a2
	jsr	_LVONewObjectA(a6)
	move.l	d0,188(a4)
	beq	fr_prop
	move.l	d0,number0
	move.l	d0,num0

	suba.l	a0,a0
	lea	number_stg(pc),a1
	lea	number1_tags(pc),a2
	jsr	_LVONewObjectA(a6)
	move.l	d0,228(a4)
	beq	fr_num0

	move.l	184(a4),a0
	move.l	200(a4),a1
	suba.l	a2,a2
	lea	attr_tags(pc),a3
	jsr	_LVOSetGadgetAttrsA(a6)

	move.l	200(a4),a0
	move.l	184(a4),a1
	moveq	#-1,d0
	moveq	#-1,d1
	suba.l	a2,a2
	jsr	_LVOAddGList(a6)

	move.l	184(a4),a0
	move.l	200(a4),a1
	suba.l	a2,a2
	moveq	#-1,d0
	jsr	_LVORefreshGList(a6)

msg_l	move.l	200(a4),a0
	move.l	wd_UserPort(a0),a0
	move.l	4.w,a6
	jsr	_LVOWaitPort(a6)
	move.l	200(a4),a0
	move.l	wd_UserPort(a0),a0
	jsr	_LVOGetMsg(a6)
	move.l	d0,a1
	move.l	im_Class(a1),192(a4)
	move.w	im_Code(a1),196(a4)
	move.w	im_Qualifier(a1),198(a4)
	move.l	im_IAddress(a1),216(a4)
	move.w	im_MouseX(a1),220(a4)
	move.w	im_MouseY(a1),222(a4)
	jsr	_LVOReplyMsg(a6)

	cmp.l	#IDCMP_IDCMPUPDATE,192(a4)
	beq.s	idcmp_update

	cmp.l	#IDCMP_GADGETUP,192(a4)
	beq.s	which_gadgetup

	cmp.l	#IDCMP_GADGETDOWN,192(a4)
	beq	which_gadgetdown

	cmp.l	#IDCMP_VANILLAKEY,192(a4)
	beq	which_vanillakey

	cmp.l	#IDCMP_RAWKEY,192(a4)
	beq	which_rawkey

	cmp.l	#IDCMP_MOUSEBUTTONS,192(a4)
	beq	which_mousebutton

	cmp.l	#IDCMP_CLOSEWINDOW,192(a4)
	beq	remove_glist

	bra	msg_l

idcmp_update

 * Note: After sorting out this message you may get a IDCMP_GADGETUP message
 *       aswell. Also. im_Code may be 0 depending on the gadget - hence the
 *       reason for using FindTagItem() as you get the the Long Val any way
 *       instead of the word limits of im_Code.

	move.l	216(a4),a3
	move.l	#GA_ID,d0
	move.l	a3,a0
	move.l	224(a4),a6
	jsr	_LVOFindTagItem(a6)
	tst.l	d0
	beq.s	iud_end
	move.l	d0,a0
	cmp.l	#3,ti_Data(a0)
	bne.s	iud_end
	move.l	#STRINGA_LongVal,d0
	move.l	a3,a0
	jsr	_LVOFindTagItem(a6)
	tst.l	d0
	beq.s	iud_end
	move.l	d0,a0
	move.l	ti_Data(a0),d0
iud_end	bra	msg_l

which_gadgetup

 * This next piece of code gets the value of the Number gadget using
 * GetAttr() and if successful it then sets the Number gadget's value
 * and the Prop gadget's value to 66. This is to show how to get a value
 * from a Boopsi gadget and also to show how to update the two gadgets to
 * represent the same value.

	move.l	#STRINGA_LongVal,d0
	move.l	188(a4),a0
	lea	156(a4),a1
	move.l	8(a4),a6
	jsr	_LVOGetAttr(a6)
	tst.l	d0				; Should return 1 if ok.
	bne.s	change
	suba.l	a0,a0
	jsr	_LVODisplayBeep(a6)
	bra.s	wg_end
change	cmp.l	#1,d0
	bne.s	wg_end
	move.l	188(a4),a0
	move.l	200(a4),a1
	suba.l	a2,a2
	lea	new_tags(pc),a3
	move.l	#STRINGA_LongVal,(a3)
	move.l	#66,4(a3)
	move.l	#TAG_END,8(a3)
	jsr	_LVOSetGadgetAttrsA(a6)
	move.l	184(a4),a0
	move.l	200(a4),a1
	suba.l	a2,a2
	lea	new_tags(pc),a3
	move.l	#PGA_Top,(a3)
	move.l	#66,4(a3)
	move.l	#TAG_END,8(a3)
	jsr	_LVOSetGadgetAttrsA(a6)
wg_end	bra	msg_l

which_gadgetdown

	bra	msg_l

which_vanillakey

	bra	msg_l

which_rawkey

	bra	msg_l

which_mousebutton

	bra	msg_l


remove_glist
	move.l	200(a4),a0
	move.l	184(a4),a1
	moveq	#-1,d0
	move.l	8(a4),a6
	jsr	_LVORemoveGList(a6)

fr_num1	move.l	228(a4),a0
	move.l	8(a4),a6
	jsr	_LVODisposeObject(a6)

fr_num0	move.l	188(a4),a0
	move.l	8(a4),a6
	jsr	_LVODisposeObject(a6)

fr_prop	move.l	184(a4),a0
	move.l	8(a4),a6
	jsr	_LVODisposeObject(a6)

cl_wndw	move.l	200(a4),a0
	move.l	8(a4),a6
	jsr	_LVOCloseWindow(a6)

cl_icon	move.l  12(a4),a1
	move.l	4.w,a6
        jsr	_LVOCloseLibrary(a6)

cl_util	move.l  224(a4),a1
	move.l	4.w,a6
        jsr	_LVOCloseLibrary(a6)

cl_gfx	move.l  152(a4),a1
	move.l	4.w,a6
        jsr	_LVOCloseLibrary(a6)

cl_int	move.l  8(a4),a1
	move.l	4.w,a6
        jsr	_LVOCloseLibrary(a6)

cl_dos	move.l  4(a4),a1
	move.l	4.w,a6
        jsr	_LVOCloseLibrary(a6)

quit	move.l  #8000000,d0
        moveq	#MEMF_CHIP,d1
	move.l	4.w,a6
	jsr	_LVOAllocMem(a6)
	tst.l	d0
	beq.s	cleanup
	move.l	d0,a1
	move.l	#8000000,d0
	jsr	_LVOFreeMem(a6)
cleanup	tst.l	(a4)
	beq.s	exit			; Exit - Task was started from CLI.
	move.l	4.w,a6
	jsr	_LVOForbid(a6)
	move.l	(a4),a1			; Reply to the WB Startup Message and
	jsr	_LVOReplyMsg(a6)	; Exit - Task was started from WB.
exit	moveq	#0,d0
	rts


 * Sub-Routines.

cmpbyte	move.b  (a0)+,d0
        move.b  (a1)+,d1
        tst.b   d0
        beq.s   byte0
        cmp.b   d1,d0
        beq.s   cmpbyte
byte0	sub.b   d1,d0
        ext.w   d0
        ext.l   d0
        rts

findlen	move.l	a0,a1
	moveq	#0,d0
not_nil	tst.b	(a1)+
	beq.s	gotlen
	addq.l	#1,d0
	bra.s	not_nil
gotlen	rts

convert_number
	lea	166(a4),a0
	move.l	d1,d7
	bsr.s	word_to_ascii
	clr.l	(a0)
	rts

word_to_ascii
	move.b	#48,(a0)
	moveq	#0,d1
	move.w	d7,d1
	divu	#1000,d1
	and.l	#$0000FFFF,d1
	divu	#10,d1
	bsr.s	do_val
	bsr.s	do_val
	moveq	#0,d1
	move.w	d7,d1
	divu	#1000,d1
	clr.w	d1
	swap	d1
	divu	#100,d1
	bsr.s	do_val
	divu	#10,d1
	bsr.s	do_val
	bsr.s	do_val
	rts

do_val	add.w	#$30,d1
	move.b	d1,(a0)+
	clr.w	d1
	swap	d1
	rts


 * Structure Definitions.

topaz9
	dc.l	font_name
	dc.w	9
	dc.b	FS_NORMAL,FPF_ROMFONT

wndwtags
	dc.l	WA_Top,0
	dc.l	WA_Left,0
	dc.l	WA_Width,320
	dc.l	WA_Height,200
	dc.l	WA_DetailPen,0
	dc.l	WA_BlockPen,1
	dc.l	WA_Title,wndw_title
	dc.l	WA_IDCMP,IDCMP_GADGETUP!IDCMP_GADGETDOWN!IDCMP_VANILLAKEY!IDCMP_RAWKEY!IDCMP_MOUSEBUTTONS!IDCMP_CLOSEWINDOW!IDCMP_IDCMPUPDATE
	dc.l	WA_Activate,TRUE
	dc.l	WA_CloseGadget,TRUE
	dc.l	WA_DepthGadget,TRUE
	dc.l	WA_DragBar,TRUE
	dc.l	WA_NoCareRefresh,TRUE
	dc.l	WA_SmartRefresh,TRUE
	dc.l	WA_PubScreen
wndwscrn
	dc.l	0
	dc.l	TAG_DONE

prop2intmap
	dc.l	PGA_Top,STRINGA_LongVal
	dc.l	TAG_END

int2propmap
	dc.l	STRINGA_LongVal,PGA_Top
	dc.l	TAG_END

attr_tags
	dc.l	ICA_TARGET
number0
	dc.l	0
	dc.l	TAG_END

prop_tags
	dc.l	GA_ID,1
	dc.l	GA_Top,16
	dc.l	GA_Left,16
	dc.l	GA_Width,10
	dc.l	GA_Height,80
	dc.l	GA_RelVerify,TRUE
	dc.l	ICA_MAP,prop2intmap
	dc.l	PGA_Total,100
	dc.l	PGA_Top,25
	dc.l	PGA_Visible,10
	dc.l	PGA_NewLook,TRUE
	dc.l	TAG_END

number_tags
	dc.l	GA_ID,2
	dc.l	GA_Top,16
	dc.l	GA_Left,36
	dc.l	GA_Width,80
	dc.l	GA_Height,18
	dc.l	GA_RelVerify,TRUE
	dc.l	ICA_MAP,int2propmap
	dc.l	ICA_TARGET
prop0
	dc.l	0
	dc.l	GA_Previous
prop1
	dc.l	0
	dc.l	STRINGA_LongVal,25
	dc.l	STRINGA_MaxChars,3
	dc.l	TAG_END

number1_tags
	dc.l	GA_ID,3
	dc.l	GA_Top,16
	dc.l	GA_Left,136
	dc.l	GA_Width,80
	dc.l	GA_Height,18
	dc.l	GA_RelVerify,TRUE
	dc.l	ICA_MAP,ICSPECIAL_CODE
	dc.l	ICA_TARGET,ICTARGET_IDCMP
	dc.l	GA_Previous
num0
	dc.l	0
	dc.l	STRINGA_LongVal,16
	dc.l	STRINGA_MaxChars,3
	dc.l	TAG_END


 * String Variables.

int_name	dc.b	'intuition.library',0
dos_name	dc.b	'dos.library',0
icon_name       dc.b    'icon.library',0,0
gfx_name	dc.b	'graphics.library',0
util_name	dc.b	'utility.library',0
mtstg0		dc.b	'ARG_ONE',0
mtstg1		dc.b	'ARG_TWO',0
mtstg2		dc.b	'ARG_THREE',0
mtstg3		dc.b	'ARG_FOUR',0,0
mtstg4		dc.b	'ARG_FIVE',0,0
mtstg5		dc.b	'ARG_SIX',0
ftstg0          dc.b    'TOOLTYPE_ONE',0,0
ftstg1          dc.b    'TOOLTYPE_TWO',0,0
template	dc.b	'KEYWORD_ONE/K,KEYWORD_TWO/K',0
wndw_title	dc.b	'Talk2Intuition.s',0,0
font_name	dc.b	'topaz.font',0,0
prop_stg	dc.b	'propgclass',0,0
number_stg	dc.b	'strgclass',0


 * Buffer Variables.

membuf		dcb.b	300,0
new_tags	dcb.b	40


	SECTION	VERSION,DATA

	dc.b	'$VER: Talk2Intuition.s V1.01 (22.4.2001)',0


	END