;------------------------------------------------------------------------
; Script d'installation du programme QuickFile
;
; $VER: QuickFile-Install 1.1 (29.04.01)
;
; (C) 2000 R.Florac

(if (= @language "français") (set catalogue 1) (set catalogue 0))

(if (= catalogue 1)
    (
	(set rep_string "Un répertoire QuickFile sera créé à l'endroit que vous aurez choisi, s'il n'existait pas déjà.")
	(set where_rep_string "Où voulez vous créer le répertoire QuickFile ?")
	(set dest_rep_string "Le répertoire destination pour QuickFile\nsera ")
	(set continue_string "Continuer")
	(set stop_string "Arrêter")
	(set help_rep_string "Si le répertoire spécifié ne vous convient pas, choisissez 'Arrêter': vous devrez relancer le programme d'installation et choisir une autre destination.")
	(set choose_file_string "Choisissez les fichiers à copier")
	(set select_files_string (cat "Sélectionnez les fichiers que vous voulez copier, seuls ceux qui sont marqués le seront.\nQuickFile est le fichier programme.\nQuickFile.keys est le fichier contenant des définitions de touches programmables.\nQuickFile.guide est le fichier comprenant la documentation (en anglais), il a été complètement réécrit.\n"
	    "QuickFile.config est le fichier définissant les options de fonctionnement du programme (préférences).\nSi vous effectuez une mise à jour, copiez uniquement le fichier QuickFile (programme) et le guide."))
	(set choose_examples_string "Choisissez les fichiers\n d'exemples à copier")
	(set help_examples_string "Sélectionnez les fichiers que vous voulez copier, seuls ceux qui sont marqués le seront.")
	(set choose_arexx_string "Choisissez les scripts ARexx à copier\nTous les scripts ont été réécrits.")
	(set help_arexx_string "Sélectionnez les fichiers que vous voulez copier, seuls ceux qui sont marqués le seront.\nIl est vivement conseillé de copier TOUS les fichiers, tous ont été modifiés pour correspondre aux nouvelles commandes ARexx, les anciens scripts ne fonctionneront plus.")
	(set copy_icons_string "Voulez-vous copier les icones au format NewIcons ?")
	(set help_icons_string "Ces fichiers ne doivent être copiés que si vous utilisez NewIcons.")
	(set copying_icons_string "Copie des icones NewIcons")
	(set copying_drawer_icon_string "Copie de l'icone du répertoire")
	(set ask_copy_os35icons_string "Voulez-vous copier les icones au format 3.5 ?")
	(set help_os35icons_string "Ces fichiers ne doivent être copiés que si vous utilisez l'OS 3.5 ou 3.9.\nLe répertoire OS3.5Icons contient des icones qui ne sont pas copiées par ce script, utilisez le Workbench pour les copier si vous les aimez.")
	(set copying_progicon_string "Copie de l'icone du programme")
	(set copying_guide_icon_string "Copie de l'icone du guide")
	(set copying_rexxdrawer_string "Copie de l'icone du tiroir ARexx")
	(set copying_examples_icon_string "Copie de l'icone du tiroir d'exemples")
	(set ask_copy_commands_string "Voulez-vous copier les fichiers de commandes du répertoire c ?")
	(set help_copy_commands_string (cat "Ces commandes sont utilisées par certaines bases de données:\n  - Mostra est un afficheur d'images\n  - Muchmore est un afficheur de texte.\n  - CDAudioList est un utilitaire permettant la lecture des données des CD audios\n"
	    "Ces fichiers seront copiés dans un répertoire c du répertoire QuickFile, elles doivent être copiées pour pouvoir utiliser les exemples de façon complète.\nSi vous désirez utiliser la commande CDAudioList, il vous faudra la copier dans le répertoire c:"))
	(set ask_copy_examples_string "Voulez-vous copier les exemples ?")
	(set help_copy_examples_string "Ces exemples sont des répertoires contenant chacun une petite base de données.\nIl est conseillé de les copier si vous êtes débutant, afin de prendre connaissance du logiciel.\nCertains d'entre eux ont été réécrits afin de prendre en compte les nouvelles macros.")
	(set copying_drawer_icon_string "Copie de l'icone du répertoire")
	(set select_catalog_string "Sélectionnez les catalogues que vous voulez copier")
	(set help_catalog_string "Seul le catalogue correspondant à votre pays est nécessaire.\nLe logiciel utilise l'anglais par défaut.")
	(set copying_catalog_string "Copie du catalogue français")
	(set ask_copy_source_string "Voulez-vous copier les sources du catalogue?")
	(set help_source_string "Les fichiers sources sont nécessaires uniquement si vous voulez créer un nouveau catalogue, pour un pays pour lequel il n'existe pas, ou bien pour modifier un catalogue existant.")
	(set copying_source_string "Copie des sources du catalogue...")
	(set select_catalog_string "Sélectionnez les catalogues que vous voulez copier\nLe catalogue a été modifié sur cette version, il est vivement conseillé de le copier si vous utilisez la locale 'français'.")
	(set copying_catalog_string "Copie du catalogue français")
    )
    (
	(set rep_string "A QuickFile drawer will be created at the selected place, if it doesn't already exist.")
	(set where_rep_string "Where do you want to create the QuickFile drawer ?")
	(set dest_rep_string "The destination drawer for QuickFile\nwill be ")
	(set continue_string "Continue")
	(set stop_string "Stop")
	(set help_rep_string "If the selected drawer is not correct, choose 'Stop': you will have to run again the installation program and choose another destination.")
	(set choose_file_string "Select the files to copy")
	(set select_files_string (cat "Select the files you want to copy, only the selected ones will be copied.\nQuickFile is the program file.\nQuickFile.keys is the file where definitions of keys are stored.\nQuickFile.guide includes the documentations (it has been completely rewritten).\n"
	    "QuickFile.config is the file defining the options of the program (preferences).\nIf you do an upgrade, only copy the QuickFile program and the guide."))
	(set choose_examples_string "Select the examples files\nto copy")
	(set help_examples_string "Select the files you want to copy, only the selected names will be copied.")
	(set choose_arexx_string "Select the ARexx scripts to copy\nAll the scripts have been modified.")
	(set help_arexx_string "Select the script files to copy, only the selected names will be copied.\nIt's good to copy ALL of the files, ALL of them have been greatly modified to suit the new ARexx interface (old scripts will not work anymore).")
	(set copy_icons_string "Do you want to copy the NewIcons icons files ?")
	(set help_icons_string "These files don't have to be copied if you don't use NewIcons.")
	(set copying_icons_string "Copying NewIcons icons files")
	(set copying_drawer_icon_string "Copying the drawer icon")
	(set ask_copy_os35icons_string "Do you want to copy the icons for the 3.5 system ?")
	(set help_os35icons_string "These files can be copied only if you are using OS 3.5 or 3.9.\nThe OS3.5Icons drawer contains some icons that will not be copied by this script, use the Workbench to copy them if you like them.")
	(set copying_progicon_string "Copying the program icon")
	(set copying_guide_icon_string "Copying the guide icon")
	(set copying_rexxdrawer_string "Copying the ARexx drawer icon")
	(set copying_examples_icon_string "Copying the examples drawer icon")
	(set ask_copy_commands_string "Do you want to copy the command files of the c drawer ?")
	(set help_copy_commands_string (cat "This commands are used by some databases:\n  - Mostra is an image viewer\n  - Muchmore is a text viewer.\n  - CDAudioList is an audio CD utility\n"
	    "This files will be copied in a c drawer of the QuickFile drawer, they have to be copied if you want to use the examples efficiently.\nIf you want to use the CDAudioList command, you'll have to copy it your c: drawer."))
	(set ask_copy_examples_string "Do you want to copy the examples ?")
	(set help_copy_examples_string "This examples are drawers that contain a little database.\nCopy them if you don't know QuickFile, to learn the program.\nSome of them have been updated or even rewritten to take the new macros in count.")
	(set copying_drawer_icon_string "Copying the QuickFile drawer icon")
	(set select_catalog_string "Select the catalogs to copy. The french catalog has been enhanced, copy it if you want to use the french language.")
	(set help_catalog_string "Only the catalog used for your country is necessary.\nQuickFile uses built-in english strings.")
	(set copying_catalog_string "Copying the french catalog")
	(set ask_copy_source_string "Do-you want to copy the sources of the catalog ?")
	(set help_source_string "The sources files are necessary only if you want to create a new catalog, for a new country or to modify an existing catalog.")
	(set copying_source_string "Copying sources of catalog...")
	(set select_catalog_string "Select the catalogs to copy\nThe catalogs have been updated in version 3.25.")
	(set copying_catalog_string "Copying the french catalog")
    )
)

(set #QuickFiledestdir-help rep_string)

;****************************************************************************
; Choix du répertoire destination *******************************************
;****************************************************************************

(set #destination
    (expandpath
	(askdir
	    (prompt where_rep_string)
	    (help #QuickFiledestdir-help)
	    (default @default-dest)
	    (disk)
	)
    )
)

(set @default-dest (tackon #destination "QuickFile"))

(if (= 0 (askbool
	(prompt (cat dest_rep_string @default-dest))
	(choices continue_string stop_string)
	(help help_rep_string)
    ))
    (exit (quiet))
)

;****************************************************************************
; Création des répertoires destination **************************************
;****************************************************************************

(if (= (exists @default-dest (noreq)) 0) (makedir @default-dest (infos)))

;****************************************************************************
; Copie des fichiers du répertoire QuickFile ********************************
;****************************************************************************

(copyfiles
    (source "")
    (dest @default-dest)
    (pattern "(QuickFile#?)")
    (prompt choose_file_string)
    (help select_files_string)
    (confirm)
    (infos)
)

;****************************************************************************
; Copie des fichiers d'exemples *********************************************
;****************************************************************************

(set examples
	(askbool
		(prompt ask_copy_examples_string)
		(help help_copy_examples_string)
		(default 0)
	)
)
(if (= examples 1)
    (
	(copyfiles
	    (source "Examples")
	    (dest (tackon @default-dest "Examples"))
	    (pattern "#?")
	    (prompt choose_examples_string)
	    (help help_examples_string)
	    (confirm)
	    (infos)
	)
	(set commands
	    (askbool
		(prompt ask_copy_commands_string)
		(help help_copy_commands_string)
		(default 0)
	    )
	)
	(if (= commands 1)
	    (copyfiles
		(source "c")
		(dest (tackon @default-dest "c"))
		(pattern "#?")
		(files)
	    )
	)
    )
)

;****************************************************************************
; Copie des scripts ARexx ***************************************************
;****************************************************************************

(copyfiles
    (source "ARexx")
    (dest (tackon @default-dest "ARexx"))
    (pattern "#?")
    (prompt choose_arexx_string)
    (help help_arexx_string)
    (confirm)
    (infos)
)

;****************************************************************************
; Copie des icones au format NewIcons ***************************************
;****************************************************************************
(set newicons
	(askbool
		(prompt copy_icons_string)
		(help help_icons_string)
		(default 0)
	)
)
(if (= newicons 1)
	(
	    (copyfiles
		    (prompt copying_icons_string)
		    (source ("NewIcons/QuickFile.info"))
		    (dest @default-dest)
	    )
	    (copyfiles
		    (prompt copying_drawer_icon_string)
		    (source ("NewIcons/QuickFile3.info"))
		    (dest #destination)
		    (newname (cat @default-dest ".info"))
	    )
	)
)

;****************************************************************************
; Copie des icones du système 3.5 *******************************************
;****************************************************************************
(set icons3.5
	(askbool
		(prompt ask_copy_os35icons_string)
		(help help_os35icons_string)
		(default 0)
	)
)
(if (= icons3.5 1)
	(
	    (copyfiles
		    (prompt copying_progicon_string)
		    (source ("OS3.5Icons/QuickFile.info"))
		    (dest @default-dest)
	    )
	    (copyfiles
		    (prompt copying_guide_icon_string)
		    (source ("OS3.5Icons/QuickFile.guide.info"))
		    (dest @default-dest)
	    )
	    (copyfiles
		    (prompt copying_rexxdrawer_string)
		    (source ("OS3.5Icons/ARexx.info"))
		    (dest @default-dest)
	    )
	    (copyfiles
		    (prompt copying_examples_icon_string)
		    (source ("OS3.5Icons/Examples.info"))
		    (dest @default-dest)
	    )
	    (copyfiles
		    (prompt copying drawer_icon_string)
		    (source ("NewIcons/QuickFile3.info"))
		    (dest #destination)
		    (newname (cat @default-dest ".info"))
	    )
	)
)

;****************************************************************************
; Copie des catalogues ******************************************************
;****************************************************************************

(set catalogues
	(askoptions
		(prompt select_catalog_string)
		(help help_catalog_string)
		(choices "Français")
		(default catalogue)
	)
)

(if (= (BITAND catalogues 1) 1)
    (   (makedir (tackon @default-dest "Catalogs"))
	(copyfiles
	    (prompt copying_catalog_string)
	    (source ("Catalogs/français"))
	    (dest   (tackon @default-dest "catalogs/français"))
	    (all)
	)
    )
)

;****************************************************************************
; Copie des sources des catalogues ******************************************
;****************************************************************************
(set sources
	(askbool
		(prompt ask_copy_source_string)
		(help help_source_string)
		(default 0)
	)
)


(if (= sources 1)
    (
	(copyfiles
	    (prompt copying_source_string)
	    (source "Catalogs")
	    (dest (tackon @default-dest "catalogs"))
	    (pattern "#?.cd")
	    (files)
	)
	(if (= (BITAND catalogues 1) 1)
	    (   (makedir (tackon @default-dest "Catalogs"))
		(copyfiles
		    (prompt copying_catalog_string)
		    (source ("Catalogs"))
		    (pattern ("#?.français.ct"))
		    (dest   (tackon @default-dest "catalogs"))
		    (files)
		)
	    )
	)
    )
)

(exit)