; Install script

;=============================================================================
(set #bad-kick "Musisz mieź Kickstart 2.05 (37),\naby uūywaź tego programu !")
(set #bad_req "Musisz mieź zainstalowanā biliotekė reqtools v38,\naby uūywaź tego programu !")
(set #where-prog "Wybierz katalog, w którym mam zainstalowaź aplikacjė")
(set #doc-install "Chcesz instalowaź dokumentacjė?")
(set #where-doc "Wybierz katalog, w którym mam zainstalowaź dokumentacjė")
(set #sources-install "Chcesz instalowaź kod ūródīowy?")
(set #where-sources "Wybierz katalog, w którym mam zainstalowaź kod ūródīowy")
(set #sel-sources "Wybierz pliki do instalacji")

(set #install-msg
	(cat "\n\nSkrypt instalacyjny programu SystemReset.\n"
	   "Ten skrypt instaluje SystemReset na Twojej Amidze.\n\n"
		 "SystemReset\n"
		 "Copyright © 1999 Tomasz <Pony> Pėczek\n"
		 "FreeWare\n\n"
	)
)

;=============================================================================
; make sure we are running under a 2.04 ROM

(if (< (/ (getversion) 65536) 37)
	(
    (abort #bad-kick)
	)
)

;=============================================================================
(set #old-level @user-level)
(user 2)
(message #install-msg)

(if (not(exists "LIBS:reqtools.library"))
  (
    (abort #bad_req)
  )
  (
    (if (< (/ (getversion "LIBS:reqtools.library") 65536) 38)
      (
        (abort #bad_req)
      )
    )
  )
)

(user #old-level)

(set destdir	(askdir
								(prompt #where-prog)
								(help @askdir-help)
								(default "SYS:Tools")
							)
)

(set @default-dest destdir)

(complete 25)

(copyfiles
	(source "SystemResetPL")
	(dest destdir)
	(infos)
	(noposition)
)


(set doc	(askbool
						(prompt #doc-install)
						(help @askbool-help)
					)
)

(complete 50)

(if (<> doc 0)
	(
		(set docdir	(askdir
									(prompt #where-doc)
									(help @askdir-help)
									(default "HELP:")
								)
		)
		(copyfiles
			(source "Docs/SystemResetPL.guide")
			(dest docdir)
			(infos)
			(noposition)
		)
	)
)

(set sources	(askbool
						(prompt #sources-install)
						(help @askbool-help)
					)
)

(complete 75)

(if (<> sources 0)
	(
		(set sourcesdir	(askdir
									(prompt #where-sources)
									(help @askdir-help)
									(default "DH1:Sources")
								)
		)
		(copyfiles
			(prompt #sel-sources)
			(help @copyfiles-help)
			(source "Sources")
			(dest sourcesdir)
			(noposition)
			(all)
			(confirm)
		)
	)
)

(complete 100)
(exit)