;------------------------------------------
; Installer Script für Siegfried Antivirus-
;------------------------------------------

(set #Begruessung
(cat "\nMit diesem Installationsprogramm können Sie\n\n\nSiegfried Antivirus\n\n\n auf Ihre "
     "Festplatte installieren. Die komplette Installation läuft vollständig "
     "automatisch ab.\n"
     "Auf Ihrer Festplatte müssen 1,0 MB Platz frei sein!\n\n\n"
     "Drücken Sie \"Proceed\", um fortzufahren.\n"
     "Drücken Sie \"Abbruch\", um abzubrechen. "))
(set #Platten-Hilfe
(cat "\nWählen Sie die Partition Ihrer Festplatte aus, auf der "
     "Sie gerne Siegfried Antivirus installieren möchten. Das Installationsprogramm "
     "legt dann in dem ausgewählten Pfad ein Unterverzeichnis mit dem "
     "Namen \"SF_Tools\" an."))

(set #Soundhelp
(cat "Hier können Sie festlegen welche Soundtracker Module "
     "auf Ihre Festplatte installiert werden sollen. Die Module "
     "können während der Benutzung von Siegfried Antivirus Professional "
     "im Hintergrund abgespielt werden."))

(set #Sampleshelp
(cat "Hier können Sie festlegen welche Samples auf Ihre Festplatte "
     "installiert werden sollen. Die Samples dienen Siegfried "
     "Antivirus Professional als aktustische Unterstützung zu "
     "bestimmten Aktionen (z.B. Virus gefunden)."))
	
(set #Plattenverz  
(cat "In welches Verzeichnis soll Siegfried Antivirus kopiert werden? "
     "ACHTUNG: Es wird automatisch ein Unterverzeichnis \"SF_Tools\" erzeugt!!!"))

(set #Delprefs
(cat "\n\nVoreinstellungsdatei Siegfried.Prefs im S: Verszeichnis "
     "gefunden! Soll die Datei gelöscht werden? (Für nähere Infos "
     "siehe \"Hilfe\".)\n"))

(set #Delprefshelp
(cat "\nWenn Sie eine Version kleiner 1.3 von Siegfried Antivirus "
     "oder eine Version kleiner 1.6 von Siegfried Copy auf Ihrer Festplatte "
     "installiert haben, muss die vorhandene Voreinstellungsdatei "
     "S:Siegfried.Prefs gelöscht werden! In der aktuellen Version "
     "werden mehr Daten in den Voreinstellungen gesichert. "
     "Aus programmtechnischen Gründen ist es nicht möglich die "
     "Voreinstellungsdatei automatisch zu vergrößern. Daher muss "
     "die alte Datei gelöscht werden, ansonsten werden die alten "
     "Einstellungen fehlerhaft geladen! "))

(message #Begruessung)
(welcome)

(
   (set @default-destdir
      (askdir
         (prompt #Plattenverz)
         (help   #Platten-Hilfe)
         (default "Work:")
      )
   )
)

(set @default-dest (tackon @default-destdir "SF_Tools"))

(if						; Verzeichnis erzeugen
	(= (exists @default-dest) 0)
		(makedir @default-dest
			 (infos)
			 (prompt "Schubladen werden eingerichtet")
		)
)


(makeassign "SF_Tools" @default-dest)

(onerror (cleanUp))

(if (= (exists "SF_Tools:Samples") 0)

	(makedir "SF_Tools:Samples"
		(prompt "Schubladen werden eingerichtet")
		(infos)
	)
)

(if (= (exists "SF_Tools:Modules") 0)
	(makedir "SF_Tools:Modules"
		(prompt "Schubladen werden eingerichtet")
		(infos)
	)
)

(askdisk
	(prompt "\n\n\nBitte legen Sie die Diskette \"Siegfried Antivirus\" ein!")
	(help #Plattenverz)
	(dest "SiegfriedAntivirus")
)

(complete 10)

(if                                      	; veraltete Prefs löschen
	(= (exists "s:Siegfried.Prefs" (noreq)) 1)
	(if
		(= (askbool
			(prompt #Delprefs)
			(help #Delprefshelp)
			(default 1)
			(choices "Ja" "Nein")) 1)
		(delete "s:Siegfried.Prefs")
	)
)

(complete 20)

(copyfiles
        (prompt "Kopiere das Hauptprogramm SFAP")
        (help "Jetzt wird das Hauptprogramm kopiert")
        (source "SiegfriedAntivirus:SFAP")
        (dest   "SF_Tools:")
	(infos)
)

(complete 40)

(copyfiles
	 (prompt "Bitte Soundtracker Module auswählen")
	 (help #Soundhelp)
	 (source "SiegfriedAntivirus:Modules")
	 (dest "SF_Tools:Modules")
	 (pattern "mod.#?")
	 (files)
	 (confirm)
)   

(complete 50)

(copyfiles
	 (prompt "Bitte RAW-Samples auswählen")
	 (help #Sampleshelp)
	 (source "SiegfriedAntivirus:Samples")
	 (dest "SF_Tools:Samples")
	 (pattern "#?.raw")
	 (files)
	 (confirm)
)   

(complete 60)

(copylib
        (prompt "Kopiere die siegfried.library")
        (help " ")
        (source "SiegfriedAntivirus:Libs/siegfried.library")
        (dest   "Libs:")
)

(complete 80)

(copylib
        (prompt "Kopiere Virenerkennungsdatei siegfried.data")
        (help " ")
        (source "SiegfriedAntivirus:S/siegfried.data")
        (dest   "S:")
)

(complete 100)

(message (cat 
   "Installation von Siegfried Antivirus beendet.\n\n"
   "Entfernen Sie nun die Diskette aus Ihrem Laufwerk\n "
   "und starten Sie Siegfried Antivirus.\n\nViel Spass beim Arbeiten!")
)

(exit)