; Charon install script 1.2 (19.4.2000)
;
; ©2000 Andrija Antonijevic
;

(set #exec (/ (getversion) 65536))
(if (< #exec 39)
	(abort "Charon needs at least OS3.0 to work.\n")
)

(if (not (exists "MUI:Libs/MUI/NList.mcc"))
	(abort "You don't seem to have NList MUI custom class installed.\n"
			"This class in necessary for Charon to work. You can "
			"get this class from Aminet "
			"(currently dev/mui/MCC_NList0_89.lha)"
	)
)

(complete 0)

(set #source-dir
	(if (= 1 (exists @icon))
		(pathonly (expandpath @icon))
	;else
		(expandpath @icon)
	)
)

(set @default-dest
	(askdir
		(prompt "Select the directory where you want to "
				"install Charon. A directory named Charon WILL "
				"be created and all files will be copied there."
		)
		(help @askdir-help)
		(default @default-dest)
	)
)

(set @default-dest (tackon @default-dest "Charon"))

(set #ToolbarType
	(askchoice
		(prompt "What kind of screen will you be using Charon on?")
		(help "Charon uses images for its toolbar. In order to make "
			  "images look as good as possible, there are three "
			  "versions of them for different screen resolutions."
		)
		(choices "2:1 (640x256 and similar)" "1:1 (640x512)" "1:1 higher resolutions (800x600 etc)")
	)
)

(if (= #ToolbarType 0) (set #ImageDir (tackon #source-dir "Images")))
(if (= #ToolbarType 1) (set #ImageDir (tackon #source-dir "Images_640x512")))
(if (= #ToolbarType 2) (set #ImageDir (tackon #source-dir "Images_800x600")))

(if (not (exists @default-dest))
	(makedir @default-dest (infos))
)

(complete 20)

(makedir (tackon @default-dest "Backup"))
(makedir (tackon @default-dest "Config"))
(makedir (tackon @default-dest "Images"))

(copyfiles
	(source (tackon #source-dir "Doc"))
	(dest (tackon @default-dest "Doc"))
	(infos)
	(all)
)

(complete 30)

(copyfiles
	(source (tackon #source-dir "Libs"))
	(dest (tackon @default-dest "Libs"))
	(all)
)

(complete 50)

(copyfiles
	(source (tackon #source-dir "Rexx"))
	(dest (tackon @default-dest "Rexx"))
	(all)
)

(complete 60)

(copyfiles
	(source (tackon #source-dir "Charon"))
	(dest @default-dest)
)

(if (= #ToolbarType 0)
	(copyfiles
		(source (tackon #source-dir "Charon.info"))
		(dest @default-dest)
	)
;else
	(
		(copyfiles
			(source (tackon #source-dir "CharonProp_info"))
			(dest @default-dest)
			(newname "Charon.info")
		)
		(copyfiles
			(source (tackon #source-dir "Images/About"))
			(dest (tackon @default-dest "Images"))
		)
	)
)

(complete 80)

(copyfiles
	(source #ImageDir)
	(dest (tackon @default-dest "Images"))
	(all)
)

(complete 100)

(exit "Installation finished successfully. Enjoy using Charon!")