/*
** ScanFolderYAM.rexx
** © 1999, Yves Grabowsky
**
** THIS SCRIPT IS PART OF THE AMINETFILEREQUESTER PACKAGE
** DO NOT MODIFY!
** scan the yam folder
*/

if ~show("P", "YAM") then exit(20)

OPTIONS RESULTS
OPTIONS FAILAT 20

parse arg datesfile" "namesfile

ADDRESS YAM
'APPBUSY "AminetFileRequester: Scanning for recent mails..."'

MAILINFO STEM "res."
FOLDERINFO STEM 'folder.'

DO i=0 to folder.total-1
    SETMAIL i
    MAILINFO STEM 'mailinfo.'
    if POS("Aminet uploads on", mailinfo.subject) >0 then do
        'MAILSTATUS O'
        if ~EXISTS(datesfile) then call Open('dates', datesfile, WRITE)
        else call Open('dates', datesfile, APPEND)
        if ~EXISTS(namesfile) then call Open('names', namesfile, WRITE)
        else call Open('names', namesfile, APPEND)

        call WRITELN('names', mailinfo.filename)

        if POS('week''s', mailinfo.subject) >0 then
            date = SUBWORD(mailinfo.subject, 6, 1)
        else date = SUBWORD(mailinfo.subject, 5, 1)

        call WRITELN('dates', date)

        call Close('names')
        call Close('dates')
        end
    end

SETMAIL res.index

APPNOBUSY