;  $VER: InstallYGM 1.13 (12.3.2000) Copyright © 1999-2000 by Stefan Falke
;  $Revision: 1.13 $ $Date: 2000/03/12 11:04:42 $

(set prog_name "YGM")

(set destdev "DH0:")
(set destdir "YGM")
(set Install_dest destdev)

(set @default-dest "")

(set defuser @user-level)

(set vernum (getversion))
(set os_ver (/ vernum 65536))
(set os_rev (- vernum (* os_ver 65536)))

(set ivernum @installer-version)
(set iver (/ ivernum 65536))
(set irev (- ivernum (* iver 65536)))

(if (>= iver 44 ) (
	(effect "center" "horizontal" $0000FF $000000)
))

(set lang_dk 0)
(set lang_de 1)
(set lang_en 2)
(set lang_es 3)
(set lang_it 4)
(set lang_no 5)
(set lang_builtin lang_en)

(set #lch_dku "Dansk")
(set #lch_deu "Deutsch")
(set #lch_enu "English")
(set #lch_esu "Español")
(set #lch_itu "Italiano")
(set #lch_nou "Norsk")

(set #lch_dkl "dansk")
(set #lch_del "deutsch")
(set #lch_enl "english")
(set #lch_esl "español")
(set #lch_itl "italiano")
(set #lch_nol "norsk")

(set #language lang_builtin)
(if (= #lch_dkl @language) (set #language lang_dk))
(if (= #lch_del @language) (set #language lang_de))
(if (= #lch_enl @language) (set #language lang_en))
(if (= #lch_esl @language) (set #language lang_es))
(if (= #lch_itl @language) (set #language lang_it))
(if (= #lch_nol @language) (set #language lang_no))


; English strings
(set #chdir "Please select a destination directory\nfor the installation.\n\nNo drawer will be created by default.")
(set #chdirhelp "You have to specify now the path of the drawer in which all files shall be copied.\nNon existant drawers can be created from within this install script including their accompanying icons.")

(set #asklibdir "In which drawer do you want the support libraries to be installed?")

(set #lchelp "Please select the language catalog to be installed")
(set #askcatdir "In which drawer do you want the catalog to be installed?")

(set #iconnew "\nDo you want the existing YGM Icon to be copied over by the new icon from the installation archive?\nChoose 'No' if you have modified any tooltypes of the existing icon.\n(Recommended choice: 'No')")
(set #owhelp "If you respond to this requester with 'Yes', a possibly existing %sversion will be written over completely!")
(set #owhelp2 "If you respond to this requester with 'Yes', a possibly existing file will be written over completely!")

(set #askinstall1 "Do you want to install the main program again?")
(set #askinstall2 "Do you want to install the main program with version %ld.%ld?")
(set #installed1 (cat "Version %ld.%ld of the program \"%s\" presumedly has already been installed before.\n" #askinstall1))
(set #installed2 (cat "ATTENTION! Version %ld.%ld of the program \"%s\" already exists in the destination drawer.\n" #askinstall2))

(set #pr_copylibs "Copy support library ")
(set #pr_copycats "Copy language catalog")
(set #pr_copysdir "Copy script and option files")
(set #pr_copyguide "Copy user guide")
(set #pr_copymain "Copy main program")

(set #newer "newer ")
(set #older "older ")
(set #no "No")
(set #yes "Yes")

; German strings
(if (= #language lang_de) (
	(set #chdir "Bitte Ziel-Verzeichnis für\nInstallation auswählen.\n\nEin eigenes Verzeichnis wird nicht\nautomatisch erzeugt.")
	(set #chdirhelp "Sie müssen jetzt den Pfad des Verzeichnisses angeben, in das die Dateien kopiert werden sollen.\nNoch nicht vorhandene Verzeichnisse können von diesem Installationprogramm aus angelegt werden und mit einem Schubladen-Icon versehen werden.")

	(set #asklibdir "In welchem Verzeichnis sollen die Support-Libraries installiert werden?")

	(set #lchelp "Wählen Sie den Sprachen-Katalog der installiert werden soll.")
	(set #askcatdir "In welchem Verzeichnis soll der Sprachen-Katalog installiert werden?")

	(set #iconnew "\nWollen Sie das bereits vorhandene YGM-Icon mit dem Icon aus dem Installations-Archiv überschreiben?\nWenn Sie in dem vorhandenen Icon ToolTypes verändert haben, sollten Sie 'Nein' wählen.\n(Empfohlene Wahl: 'Nein')")
	(set #owhelp "Wenn Sie diesen Requester mit 'Ja' beantworten, wird eine eventuell schon vorhandene %sVersion komplett überschrieben!")
	(set #owhelp2 "Wenn Sie diesen Requester mit 'Ja' beantworten, wird eine eventuell schon vorhandene Datei komplett überschrieben!")

	(set #askinstall1 "Wollen sie das Hauptprogramm erneut installieren?")
	(set #askinstall2 "Wollen sie das Hauptprogramm mit der Version %ld.%ld installieren?")
	(set #installed1 (cat "Die Version %ld.%ld des Programmes \"%s\" wurde vermutlich schon zuvor in dem angegebenen Zielverzeichnis installiert.\n" #askinstall1))
	(set #installed2 (cat "ACHTUNG! In dem angegebenen Zielverzeichnis befindet sich bereits die Version %ld.%ld des Programmes \"%s\".\n" #askinstall2))

	(set #pr_copylibs "Kopieren der Support-Library ")
	(set #pr_copycats "Kopieren des Sprachen-Katalogs")
	(set #pr_copysdir "Kopieren der Script- und Einstellungs-Dateien")
	(set #pr_copyguide "Kopieren der Bedienungsanleitung")
	(set #pr_copymain "Kopieren des Hauptprogrammes")

	(set #newer "neuere ")
	(set #older "ältere ")
	(set #no "Nein")
	(set #yes "Ja")
))

; Spanish strings 1.2.0 (19.2.00) by Dámaso D. Estévez <amidde@arrakis.es>
(if (= #language lang_es) (
	(set #chdir "Por favor, elija un directorio de destino\npara la instalación.\n\nNo se creará ningún cajón adicional por defecto.")
	(set #chdirhelp "Debe especificar el camino de acceso al cajón en el que todos los ficheros serán copiados.\nLos cajones que no existan (y sus correspondientes iconos) serán creados desde este guión instalador.")

	(set #asklibdir "¿En qué cajón desea que sea instalada la biblioteca de soporte?")

	(set #lchelp "Por favor, elija el catálogo del idioma que desea instalar")
	(set #askcatdir "En qué cajón desea instalar el catálogo?")

	(set #iconnew "\n¿Desea que el icono de YGM sea sobreescrito por el nuevo icono incluido en el paquete de instalación?\nResponda negativamente si ha modificado algún tipo de herramienta del icono preexistente en su equipo.\n(Opción recomendada: `No')")
	(set #owhelp "Si responde positivamente a esta petición, una posible versión preexistente %s será sobreescrita completamente.")
	(set #owhelp2 "Si responde positivamente a esta petición, un posible fichero preexistente será sobreescrito completamente.")

	(set #askinstall1 "¿Desea instalar el programa principal de nuevo?")
	(set #askinstall2 "¿Desea instalar el programa principal con la versión %ld.%ld?")
	(set #installed1 (cat "La versión %ld.%ld del programa \"%s\" presumiblemente ya ha sido instalada de forma completa.\n" #askinstall1))
	(set #installed2 (cat "¡ATENCIÓN! La versión %ld.%ld del programa \"%s\" ya existe en el cajón de destino.\n" #askinstall2))

	(set #pr_copylibs "Copiando biblioteca de soporte")
	(set #pr_copycats "Copiando catálogo de idioma")
	(set #pr_copysdir "Copiando guión y ficheros de opciones")
	(set #pr_copyguide "Copiando guía del usuario")
	(set #pr_copymain "Copiando programa principal")

	(set #newer "más reciente ")
	(set #older "más antigua ")
	(set #no "No")
	(set #yes "Sí")
))

; Italian strings (12.3.00) by Rosario D'Angelo <mystical@mystical.ontheweb.nu>
(if (= #language lang_it) (
	(set #chdir "Seleziona una directory per l'installazione\n\nUn cassetto NON verrà creato.")
	(set #chdirhelp "Devi specificare una directory dove i file debbano essere copiati.\nNuovi cassetti possono essere creati da questa installazione assieme alle rispettive icone.")

	(set #asklibdir "In quale cassetto vuoi che le librerie di supporto vengano installate?")

	(set #lchelp "Seleziona quali linguaggi debbano essere installati")
	(set #askcatdir "In quale cassetto vuoi che i file di catalog vengano installati?")

	(set #iconnew "\nVuoi che l'icona già presente di YGM venga sovrascritta da quella copiata dall'installazione?\nScegli 'No' se hai modificato i parametri dell'icona esistente.\n(Scelta raccomandata: 'No')")
	(set #owhelp "Se rispondi di 'Si' a questo requester, un'icona possibilmente %sversion già esistente verrà sovrascritta completamente!")
	(set #owhelp2 "Se rispondi di 'Si' a questo requester, un file possibilmente esistente verrà sovrascritto completamente!")

	(set #askinstall1 "Vuoi installare il programma principale un'altra volta?")
	(set #askinstall2 "Vuoi installare il programma con la versione %ld.%ld?")
	(set #installed1 (cat "La versione %ld.%ld del programma \"%s\" è già stata installata precedentemente.\n" #askinstall1))
	(set #installed2 (cat "ATTENZIONE! La versione %ld.%ld del programma \"%s\" esiste già nel cassetto destinazione.\n" #askinstall2))

	(set #pr_copylibs "Copia libreria di supporto ")
	(set #pr_copycats "Copia file di catalogo")
	(set #pr_copysdir "Copia script e file con le opzioni")
	(set #pr_copyguide "Copia manuale utente")
	(set #pr_copymain "Copia programma principale")

	(set #newer "più nuova ")
	(set #older "più vecchia ")
	(set #no "No")
	(set #yes "Si")
))

(procedure startcopy
	(working)

	(set file prog_name)
	(set Install_src "")

	(set ddir @default-dest)
	(set dfile (tackon ddir prog_name))
	(checkMain)

	(if (= docopy 1) (
		(docopyMain)

		(set file "fgui.library")
		(docopyLibs)
		(set file "ygm_fgui.gui")
		(docopyLibs)
		(set file "ygm_ra.gui")
		(docopyLibs)
		(docopyCats)

		(set dfile "YGM.guide")
		(set file (tackon Install_src dfile))
		(docopyGuides)

		(set sdir "rexx")
		(set ddir (tackon Install_dest "rexx"))
		(set cpattern "#?")
		(docopyDir)

		(set sdir "S")
		(set ddir (tackon Install_dest "S"))
		(set cpattern "~(#?.dat)")
		(docopyDir)

		(set sdir "S")
		(set ddir (tackon Install_dest "S"))
		(docopyDat)
	))

)

(procedure chooseLibDir
	(set libdirc (askchoice
			(choices (tackon @default-dest "libs") "LIBS:")
			(prompt #asklibdir)
			(help #asklibdir)
			(default 0)
		)  
	)

	(if (= libdirc 0) (
		(set libdir @default-dest)
	)(
		(set libdir "LIBS:")
	))
)

(procedure docopyLibs
	(if (= libdirc 0) (
		(if (< (exists (tackon libdir "libs")) 2)
			(makedir (tackon libdir "libs"))
		)
	))

	(set path (tackon Install_src (cat "libs/" file)))

	(copylib
		(prompt (cat #pr_copylibs file))
		(help @copylib-help)
		(source path)
		(dest (tackon libdir "libs"))
		(optional "nofail")
		(confirm)
	)
)

(procedure chooseCats
	(set catalog (askchoice
			(choices #lch_dku #lch_deu #lch_enu #lch_esu #lch_itu #lch_nou)
			(prompt #lchelp)
			(help #lchelp)
			(default #language)
		)
	)

	(if (= catalog lang_dk) (set #ulcat #lch_dkl))
	(if (= catalog lang_de) (set #ulcat #lch_del))
	(if (= catalog lang_en) (set #ulcat #lch_enl))
	(if (= catalog lang_es) (set #ulcat #lch_esl))
	(if (= catalog lang_it) (set #ulcat #lch_itl))
	(if (= catalog lang_no) (set #ulcat #lch_nol))

	(if (= catalog lang_builtin) (set #ulcat ""))
	(if (<> #ulcat "") (
		(set catdirc (askchoice
				(choices (tackon @default-dest (cat "Catalogs/" #ulcat)) (cat "LOCALE:Catalogs/" #ulcat) )
				(prompt #askcatdir)
				(help #askcatdir)
				(default 0)
			)  
		)

		(if (= catdirc 0) (
			(set catdir @default-dest)
		)(
			(set catdir "LOCALE:")
			(if (< (exists "LOCALE:" (noreq)) 2) (
				(makedir "sys:Locale")
				(makeassign "LOCALE" "sys:Locale")
			))
			)
		)
	))
)

(procedure docopyCats
	(if (<> #ulcat "") (
		(if (< (exists (tackon catdir "Catalogs")) 2)
			(makedir (tackon catdir "Catalogs"))
		)
		(if (< (exists (tackon catdir (cat "Catalogs/" #ulcat)) ) 2)
			(makedir (tackon catdir (cat "Catalogs/" #ulcat)) )
		)
		(copylib
			(prompt #pr_copycats)
			(help @copylib-help)
			(source (cat (tackon Install_src "Catalogs/") #ulcat "/ygm.catalog"))
			(dest (tackon catdir (cat "Catalogs/" #ulcat)) )
			(optional "nofail")
			(confirm)
		)
	))
)

(procedure docopyDir
	(if (< (exists ddir) 2)
		(makedir ddir)
	)
	(copyfiles
		(prompt #pr_copysdir)
		(help @copyfiles-help)
		(source sdir)
		(dest ddir)
		(pattern cpattern)
		(confirm)
	)
)

(procedure docopyDat
	(if (= (exists (tackon ddir "YGM.dat")) 0)
		(copyfiles
			(prompt #pr_copysdir)
			(help @copyfiles-help)
			(source (tackon sdir "YGM.dat"))
			(dest ddir)
			(confirm)
		)
	)
)

(procedure docopyGuides
	(if (= (exists file) 1)
		(copyfiles
			(prompt #pr_copyguide)
			(help @copyfiles-help)
			(source file)
			(dest Install_dest)
			(infos)
			(optional "nofail")
			(confirm)
		)
	)

	(if (>= os_ver 39)
		(tooltype
			(dest (tackon Install_dest dfile))
			(setdefaulttool "MultiView")
		)
		(tooltype
			(dest (tackon Install_dest dfile))
			(setdefaulttool "AmigaGuide")
		)
	)
)

(procedure docopyMain
	(if (exists (cat (tackon ddir prog_name) ".info"))
		(set nocopyicon (askchoice	(choices #yes #no)
											(prompt #iconnew)
											(help   #iconnew)
											(default 1)
						)
		)
		(set nocopyicon 0)
	)

	(if (= nocopyicon 1) (
		(copyfiles
			(prompt #pr_copymain)
			(help @copyfiles-help)
			(source file)
			(dest ddir)
			(optional "force")
			(confirm)
		)
	)(
		(copyfiles
			(prompt #pr_copymain)
			(help @copyfiles-help)
			(source file)
			(dest ddir)
			(infos)
			(optional "force")
			(confirm)
		)
	))
)

(procedure checkMain
	(if (= (exists dfile) 1) (
		(set ver_source (getversion file))
		(set ver_s (/ ver_source 65536))
		(set rev_s (- ver_source (* ver_s 65536)))

		(set ver_dest (getversion dfile))
		(set ver_d (/ ver_dest 65536))
		(set rev_d (- ver_dest (* ver_d 65536)))

		(if (= ver_source ver_dest) (
			(set vprompt (#installed1 ver_s rev_s prog_name))
			(set vhelp (#owhelp ""))
			(set docopy
				(askbool
					(prompt	vprompt)
					(help		vhelp)
					(choices #yes #no)
				)
			)
			(if (= @user-level 0) (set docopy 1))
		))
		(if (< ver_source ver_dest) (
			(set vprompt (#installed2 ver_d rev_d prog_name ver_s rev_s))
			(set vhelp (#owhelp #newer))
			(set docopy
				(askbool
					(prompt	vprompt)
					(help		vhelp)
					(choices #yes #no)
				)
			)
			(if (= @user-level 0) (set docopy 0))
		))
		(if (> ver_source ver_dest) (
			(set vprompt (#installed2 ver_d rev_d prog_name ver_s rev_s))
			(set vhelp (#owhelp #older))
			(set docopy
				(askbool
					(prompt	vprompt)
					(help		vhelp)
					(choices #yes #no)
				)
			)
			(if (= @user-level 0) (set docopy 1))
		))
	)(
		(set docopy 1)
	))
)

(procedure chooseDestDir
	(if (= (exists destdev (noreq)) 0) (
		(set destdev (cat (getdevice "sys:") ":"))
		(set Install_dest destdev)
	))
	(if (= @user-level 0)
		(set Install_dest (cat destdev destdir))
		(set Install_dest destdev)
	)
	(set @default-dest Install_dest)

	(set Install_dest
		(askdir
			(prompt	#chdir)
			(help		#chdirhelp)
			(default	@default-dest)
			(newpath)
			(disk)
		)
	)

	(if (= @default-dest Install_dest) (
		(if (= (exists @default-dest) 0) (
			(makedir @default-dest
					(infos)
			)
		))
	)(
		(set @default-dest Install_dest)
	))

	(user defuser)
)

;
; Start
;

(if (= iver 0) (
	(set #langhelp "Please choose your language\nBitte Sprache auswählen")
	(set #language (askchoice
			(choices #lch_dku #lch_deu #lch_enu #lch_esu #lch_itu #lch_nou)
			(prompt #langhelp)
			(help #langhelp)
			(default #language)
		)
	)
))

(chooseDestDir)
(chooseLibDir)
(chooseCats)

(startcopy)

(exit)